ANSYS命令流 帮忙解释下
/PREP7
ET,1,BEAM4
KEYOPT,1,2,0
KEYOPT,1,6,0
KEYOPT,1,7,1
KEYOPT,1,9,0
KEYOPT,1,10,0
*SET,p,acos(-1)
*SET,R1,5
*SET,R2,60
R,1,p*R1**2,p*R1**4/4,p*R1**4/4,2*R1,2*R1, ,
RMORE, ,p*R1**4/2, , ,2175, ,
R,2,p*R2**2,p*R2**4/4,p*R2**4/4,2*R2,2*R2, ,
RMORE, ,p*R2**4/2, , ,2175, ,
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,2e5
MPDATA,PRXY,1,,.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,1e-10
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,2,,2E5
MPDATA,PRXY,2,,.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,2,,8E-8
K, ,,,,
K, ,100,,,
TYPE, 1
MAT, 1
REAL, 1
ESYS, 0
LSTR, 1, 2
LESIZE,ALL, , ,200, ,1, , ,1,
LMESH, 1
D,1,UX
D,1,UY
D,1,UZ
D,102,UY
D,102,UZ
FLST,2,1,2,ORDE,1
FITEM,2,200 展开
下面的所有东西，希望楼主拷贝到记事本里面查看，不要选择自动换行！
/PREP7 ! 进入前处理器
ET,1,BEAM4 ! 定义单元beam4,是个三维梁单元
KEYOPT,1,2,0 ! 定义单元的关键选项，如果后面是0，代表默认的，可以先不用理解，
KEYOPT,1,6,0
KEYOPT,1,7,1 ! 这里定义第七个关键选项，定义为编号1，也就是计算陀螺阻尼矩阵方程，要求
! IYY 等于 IZZ，也就是两个转动惯量要相等，这两个量要在实常数中定义
! 也就是下面的命令R
KEYOPT,1,9,0
KEYOPT,1,10,0
*SET,p,acos(-1) ! 定义三个参数，分别是派（4.1315）、第一个半径R1，第二个半径r2
*SET,R1,5
*SET,R2,60 ! 半径的单位
! 定义单元的实常数，有两个，因为有两个半径，分别就是下面的R,1
! 和r,2
! r命令的定义中需要根据使用单元beam4来一一对应，不同的单元R命令
! 定义的意思是不一样的,具体每个意思，下图看，一定要一一对应
! 这里就先是截面积，Z向转动惯量，Y像转动惯量，是一样的，从上面的
! 关键选项定义中可以看的出来，KEYOPT,1,7,1
R,1,p*R1**2,p*R1**4/4,p*R1**4/4,2*R1,2*R1, ,
RMORE, ,p*R1**4/2, , ,2175, , ! 这个也是定义实常数，因为命令只能定义6个数，从第七个
! 就要使用这个命令，编号可以从下图中对应下
R,2,p*R2**2,p*R2**4/4,p*R2**4/4,2*R2,2*R2, , ! 定义第二个实常数R，2
RMORE, ,p*R2**4/2, , ,2175, ,
MPTEMP,,,,,,,, ! 这里来定义材料属性，目前楼主提供的是GUI操作以后的
! ，这个需要相应简化,因为GUi操作中一般包括了温度的考虑，所以使用了几个温度的命令
! 目前看来只是有一个温度，所以不用考虑温度，简化后的，在后面的注释中，注释开始是!（感叹号）
MPTEMP,1,0
MPDATA,EX,1,,2e5
MPDATA,PRXY,1,,.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,1,,1e-10
! 简化后的材料属性
! mp,ex,1,2e5 ! 分别定义弹性模量，泊松比，密度，其中的1代表第一个材料属性
! mp,PRXY,1,0.3
! mp,DENS,1,1e-10
MPTEMP,,,,,,,, ! 这里就是定义第二个材料属性了！同样包括弹性模量，泊松比，密度
MPTEMP,1,0
MPDATA,EX,2,,2E5
MPDATA,PRXY,2,,.3
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,DENS,2,,8E-8
K, ,,,, ! 定义两个关键点，第一个是0，第二个坐标是：(100,0,0)
K, ,100,,,
TYPE, 1 ! 选择第一个单元，也就是beam4
MAT, 1 ! 选择第一个材料属性
REAL, 1 ! 选择第一个实常数
ESYS, 0 ! 选择默认的单元坐标系统
LSTR, 1, 2 ! 用刚才生成的两个关键点，建立一条直线
LESIZE,ALL, , ,200, ,1, , ,1, ! 把建立的这条直线划分为200个
LMESH, 1 ! 根据划分的线的段数，网格这条线，从而生成有限元模型
D,1,UX ! 对于第一个节点（也就是原点位置的那个节点）进行约束，三个平移方向都约束，但是转动方向不约束，
! 因为单元beam4是有六个自由度的
D,1,UY
D,1,UZ
D,102,UY ! 对于第102个节点，这样来算他的位置，总共长度是100，划分为200分，那么102是那个位置，楼主应该知道了吧
! 选择了Y方向和Z方向的平移约束
D,102,UZ
FLST,2,1,2,ORDE,1 ! 后面的两个命令结合起来就是选择了第200个节点，但是没有具体操作，
! 只是有了拾取选择这个点的操作，这两个命令一般是GUI直接生成的，写命令流的一般不使用这两个操作
! 所以这两个命令其实什么任务都没有做目前
FITEM,2,200
对上面的命令一一般是需要简化的，简化后的就是：
/PREP7
ET,1,BEAM4
KEYOPT,1,7,1
*SET,p,acos(-1)
*SET,R1,5
*SET,R2,60
R,1,p*R1**2,p*R1**4/4,p*R1**4/4,2*R1,2*R1, ,
RMORE, ,p*R1**4/2, , ,2175, ,
R,2,p*R2**2,p*R2**4/4,p*R2**4/4,2*R2,2*R2, ,
RMORE, ,p*R2**4/2, , ,2175, ,
mp,ex,1,2e5
mp,PRXY,1,0.3
mp,DENS,1,1e-10
mp,ex,2,2e5
mp,PRXY,2,0.3
mp,DENS,2,8e-8
K,1,,,,
K,2,100,,,
MAT, 1
REAL, 1
LSTR, 1, 2
LESIZE,ALL, , ,200
LMESH, 1
D,1,UX
D,1,UY
D,1,UZ
D,102,UY
D,102,UZ
FLST,2,1,2,ORDE,1
FITEM,2,200
简化后的命令楼主结合本人说的，可以理解下
这段话因为只是在建模，所以没有执行什么计算的，思路其实我已经说的很明确了：
首先定义单元，指定一个关键选项包括了陀螺阻尼效果，然后再定义两个实常数，然后定义了两个材料属性，然后建立一个一个线，使用第一个实常数，和第一个材料属性对这个线进行了网格！其次再对这个线进行了约束的施加，原点位置三个平移方向全约束，对102个节点位置，进行了两个方向的约束
