Question

bat 想操作的文件拖到运行窗口就执行的代码

bat嘛。我想打开一个bat后，对拖进窗口的文件执行bat中的命令。怎么写
具体操作就是想对cpp反汇编

cl /fa *.cpp

对拖进来的*.cpp反汇编

Answer 1

_______________________WKDXZ的方案_______________________
@ECHO OFF
ECHO %1
ECHO 将其扩展到一个完全合格的路径名 : %~f1
ECHO 仅将其扩展到一个路径 : %~p1
ECHO 仅将其扩展到一个盘符 : %~d1
ECHO 仅将其扩展到一个文件名 : %~n1
ECHO 仅将其扩展到一个文件扩展名 : %~x1
ECHO 扩展的路径只含有短名 : %~s1
ECHO 将其扩展到文件的文件属性 : %~a1
ECHO 将其扩展到文件的日期/时间 : %~t1
ECHO 将其扩展到文件的大小 : %~z1
PAUSE
_______________________solone的方案______________________
@echo off
set /p a=拖一个文件进来：
echo 拖进来的是 %a%
pause
_______________________asdf最终整理______________________

wkdxz的方案可以直接将文件拖放在BAT图标上执行，不需要预先开启批处理文件
solone的方案需要先开启批处理文件，然后拖放文件至bat窗口，然后回车运行。
两种方法各有优势，可根据你的实际情况选用。

Answer 2

团长漏了setlocal enabledelayedexpansion 哈！

@echo off
setlocal enabledelayedexpansion
if "%~1"=="" goto kong
set "wkdxz=%*"
for %%a in (!wkdxz!) do cl /fa %%a
pause&exit
:kong
echo.无需打开程序。选中多个cpp文件，拖到批处理图标上即可 #可处理多个文件&pause

Answer 3

@echo off
if "%~1"=="" goto kong
set "wkdxz=%*"
for %%a in (%wkdxz%) do cl /fa %%a
pause&exit
:kong
echo.无需打开程序。选中多个cpp文件，拖到批处理图标上即可 #可处理多个文件&pause

保存后，选中多个cpp文件，拖到批处理图标上即可

变量延迟可以不用。。。疏忽

Answer 4

给你个例子吧。。
@echo off
set /p a=拖一个文件进来：
echo 拖进来的是 %a%
pause