Question

求助大神翻译ansys焊接命令流！

/units,si

/prep7
et,1,solid70
mptemp,1,0,100,300,500,700,900,1100,1300,1500
mpdata,kxx,1,1,19,18,17,15,12,10,10,6,1
mpdata,c,1,1,460,470,500,550,700,720,700,720,730
mpdata,dens,1,1,7890,7890,7890,7890,7890,7890,7890,7890,7890
pi=3.1415926
I=260
U=60
efficient=0.95
r=0.001
Qm=3*I*U*efficient/(pi*r**2)
kk=0.65
Qmax=Qm*kk
ly=0.01
lx=0.02
lz=0.002
lsize=0.001
v=0.134/50
tm=1+lx/v
tinc=lsize/v
max_time=1+tm/tinc
max_x=1+lx/lsize
max_y=1+ly/lsize
/view,1,1,1,1
block,0,lx,0,ly,0,lz
save
lesize,11,lsize
lesize,1,lsize
lesize,5,lsize
mshkey,1
vatt,1,1,1
vmesh,all
/pnum,line,off
/pnum,defa
eplot
finish

*dim, flux2,table,max_x,max_y,max_time,x,y,time
*do, k,1,max_time,1
*do, i,1,max_x,1
flux2(i,0,k)=(i-1)*lsize
*enddo
*do,j,1,max_y,1
flux2(0,j,k)=(j-1)*lsize
*enddo
*do,i,1,max_x,1
*do,j,1,max_y,1
xcenter=v*(k-1)*tinc
ycenter=0
distance=sqrt(((i-1)*lsize-xcenter)**2+((j-1)*lsize-ycenter)**2)
*if,mod(k,12),eq,1,then
*if, distance, le,r, then
flux2(i,j,k)=Qmax*exp(-3*kk*distance**2/(r**2))
*else
flux2(i,j,k)=0
*endif
*else
flux2(i,j,k)=0
*endif
*enddo
*enddo
flux2(0,0,k)=(k-1)*tinc
*enddo

/solu
antype,trans
antype,trans
tunif,20
kbc,1
*SET,delt,1
timint,on
autots,off
*do,tm,1e-6,tm,tinc
/VIEW, 1 ,1,1,1
/ANG, 1
/REP,FAST
FLST, 2,1,5,ORDE,1
FITEM,2,2
/GO
TIME,tm
AUTOTS,0
DELTIM, , , ,1
KBC,0
TSRES,ERASE
FLST,2,1,5,ORDE,1
FITEM,2,2
/GO
SFA,P51X,1,HFLUX,%flux2%
/STATUS,SOLU
SOLVE
OUTRES,ALL,ALL,
/PSF,hflux,,2
*enddo

OUTRES,ALL,ALL,

Answer 1

命令里面定义很多参数，定义以后即可以在后面直接使用定义的变量名

/units,si 国际单位制

/prep7 !进入前处理器
et,1,solid70 ！定义3d温度单元
mptemp,1,0,100,300,500,700,900,1100,1300,1500 ！定义材料属性横坐标温度值
mpdata,kxx,1,1,19,18,17,15,12,10,10,6,1 ！定义对应上述温度的导热系数
mpdata,c,1,1,460,470,500,550,700,720,700,720,730 ！定义对应温度的比热
mpdata,dens,1,1,7890,7890,7890,7890,7890,7890,7890,7890,7890 ！定义对应温度的密度
pi=3.1415926 ！定义π值
I=260 ！定义i=260
U=60！u=60
efficient=0.95 ！参数变量efficient=0.95
r=0.001！参数变量r=0.001
Qm=3*I*U*efficient/(pi*r**2)！定义计算qm关于上述几个变量的计算公式
kk=0.65！u=60
Qmax=Qm*kk ！定义qmax等于qm与kk的乘积
ly=0.01！定义ly等于0.01
lx=0.02 ！定义lx等于0.02
lz=0.002！定义lz等于0.002
lsize=0.001！定义lsize等于0.001
v=0.134/50！定义计算公式v=0.134/50
tm=1+lx/v ！定义tm=1+lx/v
tinc=lsize/v！定义tinc=lsize/v
max_time=1+tm/tinc！定义max_time=1+tm/tinc
max_x=1+lx/lsize！定义max_x=1+lx/lsize
max_y=1+ly/lsize！定义max_x=1+ly/size
/view,1,1,1,1！设置显示视角
block,0,lx,0,ly,0,lz ！定义长方体，根据上述定义的lx，ly，lz值分别为长宽高
save！保存项目
lesize,11,lsize！定义11号线的单元数目等于lsize个
lesize,1,lsize！定义1号线的单元数目等于lsize个
lesize,5,lsize！定义5号线的单元数目等于lsize个
mshkey,1 ！映射网格划分
vatt,1,1,1 ！赋予体的单元类型、材料属性、实常数均为1号
vmesh,all ！给长方体划分单元
/pnum,line,off ！关闭线束线编号
/pnum,defa！打开编号显示缺省设置
eplot ！显示所有单元
finish！结束前处理

*dim, flux2,table,max_x,max_y,max_time,x,y,time ！定义数组flux2，table型，行、列、页数分别为max_x,max_y,max_time，相应的变量名缺省设置为x，y，time
*do, k,1,max_time,1 ！定义一个从1到max_time的循环，每次循环k值加1
*do, i,1,max_x,1！定义一个从1到max_x的循环，每次循环i值加1
flux2(i,0,k)=(i-1)*lsize！根据i和k值定义数组的行、列、页的数值，数值大小根据(i-1)*lsize公式确定
*enddo ！结束关于i的循环
*do,j,1,max_y,1！定义从1到max_y的循环，每次j加1
flux2(0,j,k)=(j-1)*lsize！继续给数组赋值，公式按照(j-1)*lsize计算
*enddo ！结束j的循环
*do,i,1,max_x,1 ！重新定义i循环
*do,j,1,max_y,1！重新定义j循环
xcenter=v*(k-1)*tinc ！根据k的变化计算xcenter的数值，公式为v*(k-1)*tinc
ycenter=0 ！定义ycenter始终等于0
distance=sqrt(((i-1)*lsize-xcenter)**2+((j-1)*lsize-ycenter)**2)！根据公式计算distance的数值，公式为sqrt(((i-1)*lsize-xcenter)**2+((j-1)*lsize-ycenter)**2)
*if,mod(k,12),eq,1,then ！判断执行条件，mod（k，12）是否等于1
*if, distance, le,r, then！如上述成立，且distance比r小
flux2(i,j,k)=Qmax*exp(-3*kk*distance**2/(r**2))！根据上述两条件均成立条件下，定义flux2(i,j,k)，公式为Qmax*exp(-3*kk*distance**2/(r**2))
*else！不满足上述条件，则
flux2(i,j,k)=0！数组种i行，j列，k页值即为0
flux2(i,j,k)=0
*endif结束判断条件
*else 不满足上述条件，则
flux2(i,j,k)=0数组种i行，j列，k页值即为0
*endif 结束判定条件
*enddo结束j循环
*enddo结束i循环
flux2(0,0,k)=(k-1)*tinc定义初始行列，k页值为(k-1)*tinc
*enddo 结束k循环

/solu ！进入求解器
antype,trans！定义瞬态分析模式
antype,trans
tunif,20 ！均布温度为20
kbc,1！跃阶方式递增荷载，比较适于瞬态分析
*SET,delt,1！定义delt=1
timint,on！瞬态效应打开
autots,off！自动荷载步关闭
*do,tm,1e-6,tm,tinc！关于tm的循环，从1e-6按照每次增加tinc，一直增加到tm为止
/VIEW, 1 ,1,1,1！视角设置
/ANG, 1！绕轴旋转显示方向，应用于当前窗口
/REP,FAST！刷新显示窗口，每次视角变化都快速刷新
FLST, 2,1,5,ORDE,1
FITEM,2,2
/GO
TIME,tm！时间数tm
AUTOTS,0！自动荷载步关闭
DELTIM, , , ,1！荷载步大小将继承时间步长值
KBC,0 ！递增荷载增加方式
TSRES,ERASE ！
FLST,2,1,5,ORDE,1
FITEM,2,2
/GO
SFA,P51X,1,HFLUX,%flux2% ！施加面荷载，大小上述定义过的数组中的数值
/STATUS,SOLU
SOLVE！求解
OUTRES,ALL,ALL,！全部写入输出文件
/PSF,hflux,,2 ！显示温度荷载
*enddo ！结束循环

OUTRES,ALL,ALL