Question

魔兽法师的基本宏是什么？还有那些宏我看不懂啊，乱七八槽的0.0

Answer 1

　　双深结+急速冷却宏
　　示例：你身携冰指，连按两下宏，将焦点深结，然后你又按其他键位将目标深结，高端啊！
　　说明：如果深度冻结可用且焦点被视为冰冻状态目标，则深结焦点并使用急速冷却。如果无法深结焦点，则尝试使用寒冰护体再急速冷却。如果冰脉可用，则开冰脉再急速冷却，避免浪费CD。
　　#showtooltips Cold Snap
　　/use Icy Veins
　　/use [@focus,exists,harm] Deep Freeze
　　/use Ice Barrier
　　/use Cold Snap

　　Icy Vein-冰脉
　　Deep Freeze-深结
　　Ice Barrier-寒冰护体
　　Cold Snap-急速冷却

　　biubiu宏
　　说明：按照鼠标指向-目标的顺序扔冰枪。按下alt则释放冰火箭，按下shift键则尝试对竞技场框体第三目标(一般是潜行目标)放冰枪。
　　/use [mod:alt]Frostfire Bolt;[mod:shift,@arena3][@mouseover,exists,harm][]Ice Lance

　　Frostfire Bolt-冰火箭
　　Ice Lance-冰枪术

　　冰箭宏
　　冰箭也要宏？
　　说明：立刻解除隐身/冰箱/上马的状态，如果没有敌人目标则尝试选取一个目标，读冰箭，同时宠物帮忙攻击。如果被反制，则配合shift放灼烧或者alt放奥冲
　　/cancelAura Ice Block
　　/cancelAura Invisibility
　　/dismount
　　/targetlasttarget [noharm]
　　/targetenemyplayer [noharm]
　　/petdefensive
　　/use Waterbolt
　　/use [mod:shift]Scorch;[mod:alt]Arcane Blast;Frostbolt

　　Ice Block-寒冰屏障
　　Invisibility-隐身术
　　Waterbolt-水箭
　　Scorch-灼烧
　　Arcane Blast-奥冲
　　Frostbolt-冰箭

　　护甲宏
　　说明：按一下给自己套魔甲，再按套冰甲，之后按就是在两者间切换
　　/castsequence Mage Armor,Frost Armor

　　Mage Armor-法师甲
　　Frost Armor-冰甲

　　水元素/冰冻术宏
　　说明：解除上马状态。如果有水元素则读冰箭+使用冰冻术，可以方便的打出双暴。没有水元素则召唤水元素
　　/use [nopet,nomounted]Summon Water Elemental
　　/use [harm,pet]Frostbolt
　　/petattack [harm]
　　/use [nomod,pet]!Freeze
　　/dismount

　　Summon Water Elemental-召唤水元素
　　Frostbolt-冰箭
　　Freeze-冰冻术

　　迅速转火宏
　　说明：对需要第一时间击杀的目标读奥冲，并将其设为焦点方便观察血量。目标保持不变
　　/tar 转火目标的名字
　　/use 奥术冲击
　　/focus
　　/targetlasttarget
　　/targetenemy [noharm]

　　偷懒奥冲宏 (尚未测试)
　　不想自己转火，偷懒？
　　说明：将你信任的队友设置为焦点之后，按下alt则攻击他的目标，同时不改变目标。附带出冰箱隐身下马，没有目标选目标的功能。如果被打断，配合shift灼烧
　　/cancelAura Ice Block
　　/cancelAura Invisibility
　　/dismount
　　/targetlasttarget [noharm]
　　/assist [@focus.help]
　　/use [mod:shift]灼烧;[mod:alt,@focustarget]Arcane Blast

　　Ice Block-寒冰屏障
　　Invisibility-隐身术
　　Arcane Blast-奥冲

　　双目标转火宏：
　　示例：双目标Boss，你将一个设置为焦点，打另一个。需要转火时，按下此宏即可。
　　/tar [@focus]
　　/targetlasttarget
　　/focus
　　/targetlasttarget
　　/use 奥术冲击

　　闪现宏
　　示例：在同一个冰法的战斗中，你在读冰箭，突然身中一冰环。你按下此宏，打断了正在读的冰箭(被定身无法通过移动打断施法)，闪现了出去，并在原来的位置留下了一个灵魂图腾，成功的迷惑了对手。
　　说明：打断当前施法并闪现，配合shift组合键使用火箭腰带
　　#showtooltips Blink
　　/stopcasting
　　/use Totem of Spirits
　　/use [mod:shift]6;[nomod]Blink

　　Blink-闪现
　　Totem of Spirits-灵魂图腾
　　反制宏
　　示例：你被打进了冰箱，突然对方治疗开始读一个关键的治疗法术。你猛按此宏，立刻从冰箱出来并打断了那个治疗，并且集火另一个目标。2秒后你听到“叮”的一声，又用此宏抬手在沉默结束前把治疗变羊了。
　　说明：直接按下是解除冰箱效果，并按照鼠标指向-目标的顺序释放法术反制，并将目标变羊。此时你如果切目标打，2秒后会听到叮的提示音。此时组合键+宏是将前一个目标变羊 。
　　如果不喜欢变羊功能，留下前三行和后两行即可。
　　/stopcasting
　　/cancelAura Ice Block
　　/use [nomod,@mouseover,exists,harm][]Counterspell
　　/targetlasttarget [mod]
　　/use Polymorph
　　/targetlasttarget [mod]
　　/sw 2
　　/script Stopwatch_Play();

　　Ice Block-寒冰屏障
　　Counterspell-法术反制
　　Polymorph-变形术

　　法术偷取/驱散诅咒整合宏
　　说明：按照鼠标指向-目标的顺序，根据该目标是友军还是敌军，释放驱散诅咒/法术吸取。按下alt组合键则对自己释放驱散诅咒。
　　/stopcasting
　　/use [mod:alt,@player][nomod,@mouseover,help][nomod,@target,help]Remove Curse; [mod:shift,@focus][nomod,@mouseover,harm][]Spellsteal

　　Remove Curse-驱散诅咒
　　Spellsteal-法术吸取
　　焦点变羊/设置焦点/选取敌方玩家宏
　　示例：你在乱军丛中使用此宏，将目标指向的敌人目标变羊并设置为焦点。然后攻击另一个敌人。过程中其使用了徽章解掉了变羊，你又用此宏在没有改变目标的情况下将其变羊。战斗结束，焦点死了，目标死了，你一按此宏，清除了目标和焦点，界面清爽了。下一场战斗又要开始了，你通过此宏选定了一个敌人猎人，直接无视了扑上来的宠物。
　　说明：如果目标或者焦点死了，则清除目标/焦点；有焦点，则直接变羊焦点；否则尝试选定鼠标指向的敌人目标；如果此时还没有目标，则选定最近的敌方玩家，如果没有焦点，则将其设置为焦点并变羊。任何情况下组合键+宏是将当前目标设置为焦点并变羊。
　　/cleartarget [dead][noharm]
　　/tar [@mouseover,exists,harm]
　　/targetenemyplayer [dead][noharm][noexists]
　　/clearfocus [@focus, dead]
　　/focus [@focus, noexists]
　　/focus [mod]
　　/use [@focus] Polymorph

　　Polymorph-变形术

　　冰箱宏
　　示例：你以前总是猛按冰箱，结果秒进秒出，死了。用了这个宏再也不会了
　　说明：按一下，打断当前施法进冰箱，再怎么按也不会自己出来。如果想脱离冰箱状态，可以使用前面的攻击施法宏。
　　/stopcasting
　　/use !Ice Block

　　Ice Block-寒冰屏障

　　隐身宏
　　说明：按下打断施法隐身，再怎么按也不会主动取消隐身。如果想脱离隐身状态，可以使用前面的攻击施法宏。
　　/stopcasting
　　/cast !Invisibility

　　Invisibility-隐身术

　　变羊宏/宠物跟随宏
　　说明：按下时，宠物调为被动并停止攻击跟随你。同时将当前目标变兔子。如果没有目标则选取一个敌对玩家变兔子。配合alt组合键则冰脉变兔子
　　#showtooltip Polymorph(Rabbit)
　　/targetenemyplayer [noharm][dead]
　　/use [mod:alt,harm]Icy Veins
　　/petpassive
　　/petfollow
　　/use Polymorph(Rabbit)

　　Icy Veins-冰脉
　　Polymorph(Rabbit)-变兔子