win7系统, .cdx的文件选择用word打开时怎么还原成原来的
2个回答
展开全部
打开记事本(开始-程序-附件-记事本,或者新建文本文档然后打开),复制以下内容进去,文件-另存为,名称:"改回选错的打开方式.bat",保存类型:"所有文件",编码:"ANSI",保存后双击运行保存的批处理文件即可.
@echo off
setlocal enabledelayedexpansion
set "ext=%~x1"
:loop
if defined ext set "ext=!ext:"=!"
if defined ext goto ok
echo 如果你不知道文件的扩展名，关闭批处理然后把文件拖到批处理文件的图标上。
set /p "v=请输入扩展名（如txt）然后回车："
for /f "delims=" %%i in (".!v!") do set "ext=%%~xi"
goto loop
:ok
echo 扩展名：!ext!
pause
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\!ext!" /f
reg query "HKCR\!ext!" /ve|find /i "!ext:~1!_auto_file">nul
if not errorlevel 1 (
reg delete "HKCR\!ext!" /ve /f
reg delete "HKCR\!ext:~1!_auto_file" /f
)
taskkill /im explorer.exe /f
start %windir%\explorer.exe
pause
goto :eof
@echo off
setlocal enabledelayedexpansion
set "ext=%~x1"
:loop
if defined ext set "ext=!ext:"=!"
if defined ext goto ok
echo 如果你不知道文件的扩展名，关闭批处理然后把文件拖到批处理文件的图标上。
set /p "v=请输入扩展名（如txt）然后回车："
for /f "delims=" %%i in (".!v!") do set "ext=%%~xi"
goto loop
:ok
echo 扩展名：!ext!
pause
reg delete "HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\FileExts\!ext!" /f
reg query "HKCR\!ext!" /ve|find /i "!ext:~1!_auto_file">nul
if not errorlevel 1 (
reg delete "HKCR\!ext!" /ve /f
reg delete "HKCR\!ext:~1!_auto_file" /f
)
taskkill /im explorer.exe /f
start %windir%\explorer.exe
pause
goto :eof
已赞过
已踩过<
评论
收起
你对这个回答的评价是？
推荐律师服务：
若未解决您的问题，请您详细描述您的问题，通过百度律临进行免费专业咨询
