Question

易语言怎样取出一些文本与一些文本中间的文字？

37bqwyi*****98236273uiqwfb
要知取出37bqwyi与98236273uiqwfb中间的文字，用易语言代码怎么写？

Answer 1

可以这样写：

.版本 2

.子程序 文本_取出中间文本, 文本型, 公开, 比如：欲取全文本为“12345”,现在要取出“3”，<3>的前面为“2”，<3>的后面为“4”。
.参数 欲取全文本, 文本型, , 比如：欲取全文本为 12345
.参数 前面文本, 文本型, , 3的前面为“2”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 后面文本, 文本型, , 3的后面为“4”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 起始搜寻位置, 整数型, 可空, 可空。1为首位置，2为第2个位置，如此类推，如果被省略，则“寻找字节集”命令默认从首部开始，“倒找字节集”命令默认从尾部开始。
.参数 是否区分大小写, 逻辑型, 可空, 可空。初始值为“假”。假 = 不区分    真 = 区分大小写。
.局部变量 局_位置, 整数型
.局部变量 局_位置1, 整数型
.局部变量 局_前面文本, 文本型
.局部变量 局_后面文本, 文本型

局_前面文本 ＝ 子文本替换 (前面文本, “#引号”, #引号, , , 真)
局_后面文本 ＝ 子文本替换 (后面文本, “#引号”, #引号, , , 真)
是否区分大小写 ＝ 取反 (是否区分大小写)
局_位置 ＝ 寻找文本 (欲取全文本, 局_前面文本, 起始搜寻位置, 是否区分大小写)
.如果真 (局_位置 ≠ -1)
    局_位置 ＝ 局_位置 ＋ 取文本长度 (局_前面文本)
.如果真结束
局_位置1 ＝ 寻找文本 (欲取全文本, 局_后面文本, 局_位置, 是否区分大小写)
.如果真 (局_位置 ＝ -1 或 局_位置1 ＝ -1)
    返回 (“”)
.如果真结束
返回 (取文本中间 (欲取全文本, 局_位置, 局_位置1 － 局_位置))

追问

ybwqyeb
wyeuq
ewgquf
wefgiq
那如果要取出
“ybwqyeb”
与
“eb
wefgiq”（多行）
这样的代码是否可行？

Answer 2

正则和取文本中间（）都行，取文本中间比较麻烦