Question

asp实现图片上传到文件夹，路径保存在access数据库中

asp实现图片上传到文件夹，路径保存在access数据库中并在首页上显示,基本上和BBS里面自定义用户头像一样,现把所有代码帖上来,希望高手帮我补充完整,谢谢.
首页代码:
<table width="854" height="224" border="1" align="center">
<tr>
<td width="28" height="40" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15">序号</h1></td>
<td width="77" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15">姓 名</h1></td>
<td width="190" height="250" rowspan="5" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15">照片</h1> </td>
<td width="106" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15"><strong>手 机</strong></h1></td>
<td width="144" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15"><strong>QQ</strong></h1></td>
<td width="129" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15"><strong>是否结婚</strong></h1></td>
<td width="134" align="center" valign="middle" bordercolor="#000000" class="STYLE15"><h1 align="center" class="STYLE15">想说些什么</h1></td>
</tr>
<tr>
<td rowspan="4" align="center" valign="middle" bordercolor="#000000"><%=rs("id")%></td>
<td rowspan="4" align="center" valign="middle" bordercolor="#000000"><%=rs("user")%></td>
<td height="30" align="center" valign="middle" bordercolor="#000000"><%=rs("mob")%></td>
<td align="center" valign="middle" bordercolor="#000000"><%=rs("qq")%></td>
<td align="center" valign="middle" bordercolor="#000000"><%=rs("hyck")%></td>
<td rowspan="4" align="left" valign="top" bordercolor="#000000"><%=rs("content")%></td>
</tr>
<tr>
<td height="31" align="center" valign="middle" bordercolor="#000000"><span class="STYLE15"><strong>电 话</strong></span></td>
<td align="center" valign="middle" bordercolor="#000000"><span class="STYLE15"><strong>电子邮箱</strong></span></td>
<td align="center" valign="middle" bordercolor="#000000"><span class="STYLE15"><strong>结婚日期</strong></span></td>
</tr>
<tr>
<td height="35" align="center" valign="middle" bordercolor="#000000"><%=rs("tel")%></td>
<td align="center" valign="middle" bordercolor="#000000"><%=rs("email")%></td>
<td align="center" valign="middle" bordercolor="#000000"><%=rs("jhrc")%></td>
</tr>
<tr>
<td height="74" align="center" valign="middle" bordercolor="#000000"><span class="STYLE15">工作地址</span></td>
<td colspan="2" align="center" valign="middle" bordercolor="#000000"> <div align="center"><%=rs("gzdd")%></div></td>
</tr>
</table>

Answer 1

你这段只是代码列表显示御旦数据库字段中的数据。
--------------------------------------------------
<form name="form" method="post" action="card-upfile_savetofile.asp" enctype="multipart/form-data" >
<table align=center style="border:1px dotted #CC0000;"><tr><td><font color=white>LOGO上传</font><br><br><input type="file" name="file1" size="40" style="border:1px lined #585858;" >
<input type="hidden" value="<%=username%>">
<input type="submit" name="Submit" value="上传" style="border:1px lined #585858;"> <br>
<font color=white>尺寸尽量限制在 100x100像素即正方形图片，大小在100K 以内,以保证浏览质量
</td></tr>
</table>
</form>
---------------
此段是上传页面，用enctype="multipart/form-data将图片路径发送到card-upfile_savetofile.asp这个文件接收。
===============

<!--#include FILE="conn.asp"-->
<!--#include FILE="card-upfile_class.asp"-->

<%
username=session("username")

set rss=server.createobject("adodb.recordset")
sql="select * from [user] where username='"&username&"'"
rss.open sql,conn,1,3
filedel=rss("touimage")
rss.close
set rss=nothing

if filedel<>"" then
Set objfso = Server.CreateObject("Scripting.FileSystemObject")
objFSO.DeleteFile(Server.MapPath("cardupload\"&filedel))
Set objfso=nothing
end if

dim upload,file,formName,formPath,nowtime,filehz
nowtime=year(now())&month(now())&day(now())&hour(now())&minute(now())&second(now())
set upload=new upload_5xSoft ''建立上传对象
formPath=upload.form("filepath") ''在目录后加(/)
if right(formPath,1)<>"/" then formPath=formPath&"/"
for each formName in upload.file ''列出所有上传了的文件
set file=upload.file(formName) ''生成一个文件对象
if file.filesize<100 then
response.write "<script language='javascript'>window.alert('错误:未选择文件!重新上传!');</script>"
response.write "<script language='javascript'>window.history.go('-1');</script>"
response.end
end if

filehz=right((file.FileName),3)
if filehz<>"jpg" and filehz<>"JPG" and filehz<>"bmp" and filehz<>"BMP" and filehz<>"gif" and filehz<>"GIF" then
response.write "<携拆培script language='javascript'>window.alert('错误:上传的文件格式不对!只能上传辩唯jpg,gif,bmp格式的文件!返回重新上传!');</script>"
response.write "<script language='javascript'>window.history.go('-1');</script>"
response.end
end if

if file.filesize>100*1000 then '设置上传文件大小为100K
response.write "<script language='javascript'>window.alert('错误:文件大小超过了限制!大小应在100K以内!返回重新上传!');</script>"
response.write "<script language='javascript'>window.history.go('-1');</script>"
response.end
end if

if file.FileSize>100 then ''如果 FileSize >100 说明有文件数据
file.SaveAs Server.mappath("cardupload/"&nowtime&"."&right((file.FileName),3)) ''文件存放目录
fileok=nowtime&"."&right((file.FileName),3)
end if

set file=nothing
next
set upload=nothing

set rs=server.createobject("adodb.recordset")
sql="update [user] set touimage='"&fileok&"' where username='"&username&"'"
rs.open sql,conn,1,3
set rs=nothing
response.write "<script language='javascript'>window.alert('上传成功!');</script>"
response.Write "<script language='javascript'>window.close();</script>"
response.End
%>
=============
这段则是接受路径的文件，里面包括
conn.asp(连接数据库文件，通用的你应该有)和card-upfile_class.asp这个class文件，下面则是class文件
===========
<SCRIPT RUNAT=SERVER LANGUAGE=VBSCRIPT>

dim upfile_5xSoft_Stream

Class upload_5xSoft

dim Form,File,Version

Private Sub Class_Initialize
dim iStart,iFileNameStart,iFileNameEnd,iEnd,vbEnter,iFormStart,iFormEnd,theFile
dim strDiv,mFormName,mFormValue,mFileName,mFileSize,mFilePath,iDivLen,mStr
Version=""
if Request.TotalBytes<1 then Exit Sub
set Form=CreateObject("Scripting.Dictionary")
set File=CreateObject("Scripting.Dictionary")
set upfile_5xSoft_Stream=CreateObject("Adodb.Stream")
upfile_5xSoft_Stream.mode=3
upfile_5xSoft_Stream.type=1
upfile_5xSoft_Stream.open
upfile_5xSoft_Stream.write Request.BinaryRead(Request.TotalBytes)

vbEnter=Chr(13)&Chr(10)
iDivLen=inString(1,vbEnter)+1
strDiv=subString(1,iDivLen)
iFormStart=iDivLen
iFormEnd=inString(iformStart,strDiv)-1
while iFormStart < iFormEnd
iStart=inString(iFormStart,"name=""")
iEnd=inString(iStart+6,"""")
mFormName=subString(iStart+6,iEnd-iStart-6)
iFileNameStart=inString(iEnd+1,"filename=""")
if iFileNameStart>0 and iFileNameStart<iFormEnd then
iFileNameEnd=inString(iFileNameStart+10,"""")
mFileName=subString(iFileNameStart+10,iFileNameEnd-iFileNameStart-10)
iStart=inString(iFileNameEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)
if iEnd>iStart then
mFileSize=iEnd-iStart-4
else
mFileSize=0
end if
set theFile=new FileInfo
theFile.FileName=getFileName(mFileName)
theFile.FilePath=getFilePath(mFileName)
theFile.FileSize=mFileSize
theFile.FileStart=iStart+4
theFile.FormName=FormName
file.add mFormName,theFile
else
iStart=inString(iEnd+1,vbEnter&vbEnter)
iEnd=inString(iStart+4,vbEnter&strDiv)

if iEnd>iStart then
mFormValue=subString(iStart+4,iEnd-iStart-4)
else
mFormValue=""
end if
form.Add mFormName,mFormValue
end if

iFormStart=iformEnd+iDivLen
iFormEnd=inString(iformStart,strDiv)-1
wend
End Sub

Private Function subString(theStart,theLen)
dim i,c,stemp
upfile_5xSoft_Stream.Position=theStart-1
stemp=""
for i=1 to theLen
if upfile_5xSoft_Stream.EOS then Exit for
c=ascB(upfile_5xSoft_Stream.Read(1))
If c > 127 Then
if upfile_5xSoft_Stream.EOS then Exit for
stemp=stemp&Chr(AscW(ChrB(AscB(upfile_5xSoft_Stream.Read(1)))&ChrB(c)))
i=i+1
else
stemp=stemp&Chr(c)
End If
Next
subString=stemp
End function

Private Function inString(theStart,varStr)
dim i,j,bt,theLen,str
InString=0
Str=toByte(varStr)
theLen=LenB(Str)
for i=theStart to upfile_5xSoft_Stream.Size-theLen
if i>upfile_5xSoft_Stream.size then exit Function
upfile_5xSoft_Stream.Position=i-1
if AscB(upfile_5xSoft_Stream.Read(1))=AscB(midB(Str,1)) then
InString=i
for j=2 to theLen
if upfile_5xSoft_Stream.EOS then
inString=0
Exit for
end if
if AscB(upfile_5xSoft_Stream.Read(1))<>AscB(MidB(Str,j,1)) then
InString=0
Exit For
end if
next
if InString<>0 then Exit Function
end if
next
End Function

Private Sub Class_Terminate
form.RemoveAll
file.RemoveAll
set form=nothing
set file=nothing
upfile_5xSoft_Stream.close
set upfile_5xSoft_Stream=nothing
End Sub

Private function GetFilePath(FullPath)
If FullPath <> "" Then
GetFilePath = left(FullPath,InStrRev(FullPath, "\"))
Else
GetFilePath = ""
End If
End function

Private function GetFileName(FullPath)
If FullPath <> "" Then
GetFileName = mid(FullPath,InStrRev(FullPath, "\")+1)
Else
GetFileName = ""
End If
End function

Private function toByte(Str)
dim i,iCode,c,iLow,iHigh
toByte=""
For i=1 To Len(Str)
c=mid(Str,i,1)
iCode =Asc(c)
If iCode<0 Then iCode = iCode + 65535
If iCode>255 Then
iLow = Left(Hex(Asc(c)),2)
iHigh =Right(Hex(Asc(c)),2)
toByte = toByte & chrB("&H"&iLow) & chrB("&H"&iHigh)
Else
toByte = toByte & chrB(AscB(c))
End If
Next
End function
End Class

Class FileInfo
dim FormName,FileName,FilePath,FileSize,FileStart
Private Sub Class_Initialize
FileName = ""
FilePath = ""
FileSize = 0
FileStart= 0
FormName = ""
End Sub

Public function SaveAs(FullPath)
dim dr,ErrorChar,i
SaveAs=1
if trim(fullpath)="" or FileSize=0 or FileStart=0 or FileName="" then exit function
if FileStart=0 or right(fullpath,1)="/" then exit function
set dr=CreateObject("Adodb.Stream")
dr.Mode=3
dr.Type=1
dr.Open
upfile_5xSoft_Stream.position=FileStart-1
upfile_5xSoft_Stream.copyto dr,FileSize
dr.SaveToFile fullpath,2
dr.Close
set dr=nothing
SaveAs=0
end function
End Class
</SCRIPT>
=========