Question

flash 3.0 怎样拖动一个元件到指定位置，如果拖动到了，就放下，没到就回到原位？是3.0代码！谢谢！

Answer 1

/*
*1、新建flash ActionScript 3.0文档
*2、选择“矩形工具（R）”，在舞台上随意拉出一个矩形
*3、选择“选择工具(V)”，双击矩形，右击->选择“转换成元件”，元件名默认，确定
*4、在元件属性中（默认在软件窗口的左边，如无法看见，则按Ctrl+F3显示，这个是默认的快捷显示属性窗口），填写元件实例名为 mc_a
*5、按住Ctrl，在舞台中，将元件mc_a拉到任意一位置（元件mc_a被复制出来了），右击复制出来的元件->直接复制元件，双击元件进入，修改矩形的颜色以区分元件
*6、命名复制出来的元件实例名为 mc_b，方法同第4步
*7、将以下代码放到舞台第一帧，按Ctrl+Enter测试（默认快捷键）
*PS：以上提到的元件实例名，都可以自定，但下面的代码出现到的元件名都要修改成你自定义的
*/

import flash.events.Event;
import flash.geom.Point;
import flash.events.MouseEvent;
import flash.display.MovieClip;

this.loaderInfo.addEventListener(Event.COMPLETE,completeFun); //添加加载完成事件
var point:Point;
var drag_x:Number;
var drag_y:Number;

function completeFun(e:Event):void{
point = new Point(this.mc_a.x,this.mc_a.x); //初始化时，获取拖动的元件，以方便还原位置
mc_a.buttonMode = true; //设置拖动元件鼠标移上去时是否显示手指,true为显示
mc_a.addEventListener(MouseEvent.MOUSE_DOWN,mouseDownFun); //添加拖动的鼠标按下事件
}

/**
*
*点中拖动的元件
*/
function mouseDownFun(e:MouseEvent):void{
var mc:MovieClip = e.currentTarget as MovieClip;
if(!mc.enabled){ //如果元件禁止启用，则不会执行下面操作
return;
}

drag_x = this.mouseX - mc.x; //获取当前鼠标与元件注册点的相对位置
drag_y = this.mouseY - mc.y; //获取当前鼠标与元件注册点的相对位置

this.stage.addEventListener(MouseEvent.MOUSE_MOVE,mouseMoveFun); //添加鼠标移动事件
this.stage.addEventListener(MouseEvent.MOUSE_UP,mouseUpFun); //添加鼠标释放事件

//PS:这里是舞台添加事件而不是拖动元件本身，是因为防止鼠标拉太快，超出元件范围而中断拖动的情况
}

/**
*
*拖动元件
*/
function mouseMoveFun(e:MouseEvent):void{

mc_a.x = this.mouseX - drag_x; //设置元件的位置
mc_a.y = this.mouseY - drag_y; //设置元件的位置

//PS:此计算公式，是上面点击里获取相对位置的公式的一个置换
}

/**
*
*释放拖动的元件
*/
function mouseUpFun(e:MouseEvent):void{
this.stage.removeEventListener(MouseEvent.MOUSE_MOVE,mouseMoveFun); //删除鼠标移动事件
this.stage.removeEventListener(MouseEvent.MOUSE_UP,mouseUpFun); //删除鼠标释放事件

if(mc_b.hitTestPoint(this.mouseX,this.mouseY,true)){ //判断鼠标是否点中放置的元件
//点中放置的元件，则将拖动元件的坐标设置成放置元件的坐标
mc_a.x = mc_b.x;
mc_a.y = mc_b.y;
}else{
//否则，还原到初始位置
mc_a.x = point.x;
mc_a.y = point.y;
}
}

Answer 2

你可以复制那个元件。然后在指定位置粘贴