Question

能否用批处理文件，批量修改 zip 文件中的 txt 文本内容

之前提问过这个问题具体见下图但是按图片中的方法，替换后，会导致 txt文本中的所有 “!” 小写的感叹号丢失是否有解决方法
例如有压缩包如下
a.zip
b.zip
c.zip
每个zip的主目录下都有一个 123.txt

如何用批处理文件，将所有压缩包中的 123.txt 文档中的 abcd 字段 替换成 efgh
用 @依梦琴瑶 的办法处理，会导致 ！丢失

Answer 1

@echo off
::此脚本放在包含所有zip文件目录下
::设置7zip路径，此脚本使用的压缩软件是7zip
set "zip=C:\Program Files\7-Zip\7z.exe"
::设置txt文件名
set "TxtFile=123.txt"

for /f %%a in ('dir /a-d /b /s *.zip') do (
"%zip%" e "%%a" "%~dp0" "%TxtFile%" -y >nul
::处理解压文件%TxtFile%
	for /f "delims=" %%i in ('type %TxtFile%') do (
	set "str=%%i"
	setlocal enabledelayedexpansion
	set "str=!str:abcd=efgh!"
	echo !str!>>temp.txt
	endlocal
	)
	move "temp.txt" "%TxtFile%">nul
	"%zip%" u "%%a" "%TxtFile%" >nul
	del /f /q %TxtFile%
)

pause

Answer 2

@echo off & title 修改压缩包内的文件内容 By 依梦琴瑶
cd /d %~dp0
 
set WinRar_Path=%ProgramFiles%\WinRAR
 
set Path=%Path%;%WinRar_Path%
 
del 123.txt 2>nul
for %%a in (*.zip) do (
    echo 正在处理 "%%~a"
    WinRAR e "%%~a" 123.txt -ibck
    (for /f "delims=" %%b in (123.txt) do (
        set "Str=%%~b"
        call echo %%Str:abcd=efgh%%
    ))>123.tmp
    move /y 123.tmp 123.txt >nul
    WinRAR m "%%~a" 123.txt -ibck
)
pause

这是修改后的。