Question

求易语言统计内容范围000000-999999出现的次数程序源码

如标题所说,统计编辑框1.内容,每个数为6位的.如:000001,000233 ,000233,000091,单击统计按钮后编辑框2.内容为:1次:000001,000091 2次:000233.所需统计的数都是6位的,统计后次数排列就好,谢谢!

Answer 1

.版本 2
.支持库 RegEx

.子程序 _按钮_统计_被单击
.局部变量 文本组, 文本型, , "0"
.局部变量 分组内容, 文本型, , "0"
.局部变量 记录个数, 整数型, , "0"
.局部变量 是否存在, 逻辑型
.局部变量 i, 整数型
.局部变量 j, 整数型
.局部变量 文本, 文本型
.局部变量 个数, 整数型
.局部变量 正则, 正则表达式

正则.创建 (“[^0-9]+”, )
编辑框1.内容 ＝ 正则.替换 (编辑框1.内容, “,”, 1, , 真, 真)
文本组 ＝ 分割文本 (编辑框1.内容, “,”, )

.计次循环首 (取数组成员数 (文本组), i)
    是否存在 ＝ 假
    .计次循环首 (取数组成员数 (分组内容), j)
        .如果真 (分组内容 [j] ＝ 文本组 [i])
            是否存在 ＝ 真
            记录个数 [j] ＝ 记录个数 [j] ＋ 1
            跳出循环 ()
        .如果真结束

    .计次循环尾 ()
    .如果真 (是否存在 ＝ 假)
        加入成员 (记录个数, 1)
        加入成员 (分组内容, 文本组 [i])
    .如果真结束

.计次循环尾 ()
.如果真 (取数组成员数 (分组内容) ＝ 0)
    返回 ()
.如果真结束
编辑框2.内容 ＝ “”
.计次循环首 (取数组成员数 (分组内容) － 1, i)
    .变量循环首 (i ＋ 1, 取数组成员数 (分组内容), 1, j)
        .如果真 (记录个数 [i] ＞ 记录个数 [j])
            文本 ＝ 分组内容 [i]
            分组内容 [i] ＝ 分组内容 [j]
            分组内容 [j] ＝ 文本
            个数 ＝ 记录个数 [i]
            记录个数 [i] ＝ 记录个数 [j]
            记录个数 [j] ＝ 个数
        .如果真结束

    .变量循环尾 ()
    编辑框2.加入文本 (分组内容 [i] ＋ “ 出现次数：” ＋ 到文本 (记录个数 [i]) ＋ #换行符)
.计次循环尾 ()
编辑框2.加入文本 (分组内容 [i] ＋ “ 出现次数：” ＋ 到文本 (记录个数 [i]) ＋ #换行符)

Answer 2

私信我把，帮你解决