Question

vb程序设计

vb程序设计要求：①程序启动时，在左列表框中任意加入几个条目，右列表框为空，命令按
钮“<”和“<<”不可用。②在左列表框中选种1个条目，单击命令按钮“>”，则将
该条目内容移到右列表框。右列表框只要有条目，“<”和“<<”即可用。③若单击
命令按钮“>>”，则将左列表框中所有条目移到右列表框。④当左列表框中无条目
时，命令按钮“>”和“>>”不可用。⑤在右列表框中选1个条目，单击命令按钮“<”
，则将该条目内容移到左列表框,单击命令按钮“<<”，则将右列表框中的所有条目移到左列表框

Answer 1

代码：

Private Sub Command1_Click(Index As Integer)
  Select Case Index
    Case 0, 2
      Call SingleMove((Index + 1) \ 2, (Index + 1) Mod 3)
    Case 1, 3
      Call WholeMove(Index \ 3, Index Mod 3)
  End Select
  Call ButtonEffectiveness
End Sub
 
Private Sub Form_Load()
  List1(0).AddItem "赵大鹏"
  List1(0).AddItem "刘丽娟"
  List1(0).AddItem "孙宏伟"
  List1(0).AddItem "王天宇"
  List1(0).AddItem "李天华"
  List1(0).AddItem "郭晓燕"
  List1(0).AddItem "黄海燕"
  List1(0).AddItem "冯提莫"
  List1(0).AddItem "郑元畅"
  List1(0).AddItem "王佳欣"
  List1(0).AddItem "崔雪莉"
  List1(0).AddItem "徐歌阳"
  Call ButtonEffectiveness
End Sub

Private Sub SingleMove(ByVal Subscript1 As Integer, ByVal Subscript2 As Integer)
  If List1(Subscript1).ListIndex = -1 Then
    MsgBox "请选择要移动的项", vbOKOnly + vbInformation
  Else
    List1(Subscript2).AddItem List1(Subscript1).List(List1(Subscript1).ListIndex)
    List1(Subscript1).RemoveItem List1(Subscript1).ListIndex
  End If
End Sub

Private Sub WholeMove(ByVal Subscript1 As Integer, ByVal Subscript2 As Integer)
  For i = 0 To List1(Subscript1).ListCount - 1
    List1(Subscript2).AddItem List1(Subscript1).List(i)
  Next i
  List1(Subscript1).Clear
End Sub

Private Sub ButtonEffectiveness()
  For i = 0 To 1
    If List1(i).ListCount = 0 Then
      For j = 0 To 1
        Command1(j + 2 * i).Enabled = False
      Next j
    Else
      For j = 0 To 1
        Command1(j + 2 * i).Enabled = True
      Next j
    End If
  Next i
End Sub

设计界面：

运行界面：

Answer 2

界面设计如下：

试编写代码如下：

Private Sub UpdateStat()
    If List1.ListCount < 1 Then
        Command1.Enabled = False
        Command2.Enabled = False
    Else
        Command1.Enabled = True
        Command2.Enabled = True
    End If
    If List2.ListCount < 1 Then
        Command3.Enabled = False
        Command4.Enabled = False
    Else
        Command3.Enabled = True
        Command4.Enabled = True
    End If
End Sub


Private Sub Command1_Click()
    If List1.ListIndex <> -1 Then
        List2.AddItem (List1.Text)
        List1.RemoveItem (List1.ListIndex)
    End If
    UpdateStat
End Sub

Private Sub Command2_Click()
    If List1.ListCount > 0 Then
        For i = List1.ListCount - 1 To 0 Step -1
            List2.AddItem (List1.List(i))
            List1.RemoveItem (i)
        Next
    End If
    UpdateStat
End Sub

Private Sub Command3_Click()
    If List2.ListIndex <> -1 Then
        List1.AddItem (List2.Text)
        List2.RemoveItem (List2.ListIndex)
    End If
    UpdateStat
End Sub

Private Sub Command4_Click()
    If List2.ListCount > 0 Then
        For i = List2.ListCount - 1 To 0 Step -1
            List1.AddItem (List2.List(i))
            List2.RemoveItem (i)
        Next
    End If
    UpdateStat
End Sub

Answer 3

先规划好主题；然后在画ER图（搜索下你就知道什么叫ER图了），弄清楚哪些是一个模块的，哪些操作是重复可以调用的；ER图出来了就做数据库表，字段，写关系；数据库出来了就开始写代码了，如果人手够，可以分工，将功能块分开负责写！程序好了，开始测试，测试完了最后软件界面美化！