Question

如何实现WORD保存 文件名有日期

如何实现WORD保存 文件名有日期
就是说，你每天写同一个文档，保存后，文件名日期
应该是，保存WORD文档后，自动更新文件名里的日期信息！
如何实现！谢谢！
我知道NOTEPAD里有个小技巧“在行首增加".LOG"(引号内的字符.LOG)后，每次打开该TXT文档，系统就会记录它打开的日期和时间”

是这种形式！ ：比如今天保存是：“文档2009-09-02.doc”
如果明天保存就自动变成了：“文档2009-09-03.doc”！
（即日期信息是自动更新的，
方式①覆盖原文件的保存
方式②新建文件，文件名是文档+当前日期）

方式①吧，覆盖原文件的保存！

Answer 1

1、首先需要确保Word的宏安全性设置至少为“中”（工具-宏-安全性-中）。
2、在Word里面新建一个空白文档，给它随便取个名字（比如“我的日志”）保存一下——这个文档就是你以后日志文档的开端了！（注意，如果你用的是Word 2007的话，需要保存为启用宏的文档*.docm）
3、键入ALT+F11打开VBA编辑窗口，键入CTRL+R激活左边的“工程 – Project”面板；
4、双击工程面板中的“Project (我的日志)\Microsoft Word 对象\ThisDocument”打开代码窗口；粘贴如下代码进去：
Option Explicit
Dim oLogFileCreator As LogFileCreator
Private Sub Document_Open()
On Error Resume Next
Set oLogFileCreator = New LogFileCreator
Set oLogFileCreator.WordApplication = Application
End Sub
Private Sub Document_Close()
On Error Resume Next
Set oLogFileCreator.WordApplication = Nothing
Set oLogFileCreator = Nothing
End Sub
5、选择菜单“插入-类模块”，然后在工程面板里双击这个刚生成的“Project (我的日志)\类模块\类1”，粘贴如下代码进去：
Option Explicit
Public WithEvents WordApplication As Word.Application
' 根据需要修改下面引号中的内容作为你日子文件的默认前缀
Private Const c_strFileNamePrefix = "我的日志_"

Private Sub WordApplication_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)
On Error Resume Next
Dim fso As Object
Dim strOldName As String, strNewName As String
Set fso = CreateObject("Scripting.FileSystemObject")
strOldName = ActiveDocument.FullName
strNewName = fso.BuildPath(fso.GetParentFolderName(strOldName), Format(Now, c_strFileNamePrefix & "yyyy-mm-dd.") & fso.GetExtensionName(strOldName))
If UCase(strNewName) <> UCase(strOldName) Then
ActiveDocument.SaveAs strNewName
fso.DeleteFile strOldName
Cancel = True
End If
Set fso = Nothing
End Sub
6、可以根据需要修改代码中的日志文件名前缀。默认的日志文件名是类似 “我的日志_2009-09-12”这样的形式。
7、键入F4打开属性面板，在里面把“（名称）”从“类1”改为“LogFileCreator”。
8、键入ALT+Q关闭VBA编辑窗口返回Word文档窗口，保存，关闭。
9、再次重新打开这个文档，如果Word提示是否启用宏，选择启用。
10、现在你的这个自动按日期保存的日志就可以正常运作了。每次你做完修改后，只要你一保存，它就会根据今天的日期自动把文档保存成类似这样的形式“我的日志_2009-09-12”（前缀“我的日志”可以在上面代码中修改）。

Answer 2

请问楼主是说要把保存的文件名自动改成类似：“文档2009-09-02.doc”这样的形式吗？比如，如果明天保存就变成了：“文档2009-09-03.doc”？

还是说在文档里面有个地方会有一句话，总是显示文档的最后保存时间？——这个可以用插入域代码{SAVEDATE}实现。

还是说文档属性里面的那个日期信息？——这个是自动更新的。

________________________________
补充：
这个可能是可以做到的，需要用到VBA宏代码来响应Word保存文档的事件消息。
在Word将要保存文档前，这个代码会被调用到。然后我们就可以根据需要进行处理。

不过楼主是希望采用你提到的方式一还是方式二，也就是说，昨天的那个文档是否还需要保留？

________________________________
再补充：
做好了！请参考如下步骤操作：

1、首先需要确保Word的宏安全性设置至少为“中”（工具-宏-安全性-中）。

2、在Word里面新建一个空白文档，给它随便取个名字（比如“我的日志”）保存一下——这个文档就是你以后日志文档的开端了！（注意，如果你用的是Word 2007的话，需要保存为启用宏的文档*.docm）

3、键入ALT+F11打开VBA编辑窗口，键入CTRL+R激活左边的“工程 – Project”面板；

4、双击工程面板中的“Project (我的日志)\Microsoft Word 对象\ThisDocument”打开代码窗口；粘贴如下代码进去：
Option Explicit

Dim oLogFileCreator As LogFileCreator

Private Sub Document_Open()
On Error Resume Next

Set oLogFileCreator = New LogFileCreator
Set oLogFileCreator.WordApplication = Application
End Sub

Private Sub Document_Close()
On Error Resume Next

Set oLogFileCreator.WordApplication = Nothing
Set oLogFileCreator = Nothing
End Sub

5、选择菜单“插入-类模块”，然后在工程面板里双击这个刚生成的“Project (我的日志)\类模块\类1”，粘贴如下代码进去：
Option Explicit

Public WithEvents WordApplication As Word.Application

' 根据需要修改下面引号中的内容作为你日子文件的默认前缀
Private Const c_strFileNamePrefix = "我的日志_"

Private Sub WordApplication_DocumentBeforeSave(ByVal Doc As Document, SaveAsUI As Boolean, Cancel As Boolean)

On Error Resume Next

Dim fso As Object
Dim strOldName As String, strNewName As String

Set fso = CreateObject("Scripting.FileSystemObject")

strOldName = ActiveDocument.FullName
strNewName = fso.BuildPath(fso.GetParentFolderName(strOldName), Format(Now, c_strFileNamePrefix & "yyyy-mm-dd.") & fso.GetExtensionName(strOldName))

If UCase(strNewName) <> UCase(strOldName) Then
ActiveDocument.SaveAs strNewName
fso.DeleteFile strOldName
Cancel = True
End If

Set fso = Nothing

End Sub

6、可以根据需要修改代码中的日志文件名前缀。默认的日志文件名是类似 “我的日志_2009-09-12”这样的形式。

7、键入F4打开属性面板，在里面把“（名称）”从“类1”改为“LogFileCreator”。

8、键入ALT+Q关闭VBA编辑窗口返回Word文档窗口，保存，关闭。

9、再次重新打开这个文档，如果Word提示是否启用宏，选择启用。

10、现在你的这个自动按日期保存的日志就可以正常运作了。每次你做完修改后，只要你一保存，它就会根据今天的日期自动把文档保存成类似这样的形式“我的日志_2009-09-12”（前缀“我的日志”可以在上面代码中修改）。

如果楼主嫌上面的步骤烦琐，我可以给你发一个我按此步骤做好的空白日志给你。你就可以直接用它来开始写自己的日志了！不过上面的第一个步骤还是需要做的，而且在打开文档时仍然要选择“启用宏”。