Question

文件夹设置了共享但是连接时提示可连接数达到最大

我是一个网吧的网管，今天发现了一个问题，我设置了一个文件夹共享以后，另一台机子连接时却提示了可连接数达到最大，但是当时只有我一台电脑再连接啊，而且也没连接上，请各位高手指点下~~

Answer 1

方法一

Windows XP Professional,最多可以连接10台计算机通过网络访问。

Windows XP Home Edition,最多可以连接5台计算机通过网络方问。

解决方法：

在命令提示符窗口中执行"net config server /autodisconnect:10"(请修

改最后的数字，此数字的单位为分钟，默认值为15。）命令即可。此

后任何一台连接到此计算机当超过10分钟还没有对此计算机执行任何

操作，那么该计算机就会被自动断开连接。此时，这个断开的会话就

可以让给别的计算机使用了。

方法二

用批处理自动断开网络共享访问的连接

适用平台：WINDOWS 2K/XP HOME/PRO
适用环境：目录共享或打印机共享，经常因达到10人的连接上限，而不能给他人正常提供文件和打印共享服务
解决方法： 1、PRO版系统，修改组策略secpol.msc/本地策略/安全选项/在挂起会话之前所需时间，改为1分钟
2、使用如下脚本，每隔30秒（或自定义间隔时间）清除访问连接

@echo off

rem 定义循环间隔时间：
set secs=30

echo.
echo ============================================
echo == 此脚本用于计算机共享访问达到上限后使用 ==
echo == 运行脚本后会自动断开一些访问连接 ==
echo == 每%secs%秒种进行查询，并执行清除命令 ==
echo ============================================
echo.
net session >nul || goto :error

:begin
set clear=0

echo.
for /f "tokens=1,2" %%i in ('net session ^| find "\"') do (
net session %%i /delete /y >nul 2>&1
set clear=1
echo %time:~0,8% 清除访问来源: %%i [%%j]
)
echo.

if %clear%==0 (echo %time:~0,8% 现无人访问此计算机, %secs%秒后继续...
) else (echo %time:~0,8% 清除完毕, %secs%秒后继续...)

ping 127.0.0.1 -n %secs% -w 0 >nul 2>&1
goto begin

:error
echo 权限不足，无法执行，请与管理员联系.
echo.
pause >nul 2>&1 |echo 请按任意键关闭...

Answer 2

1. 打开共享文件夹所在的计算机，做如下操作：

2. 查看winxp系统的版本：

3. windows XP Professional,最多可以连接10台计算机通过网络访问。

4. Windows XP Home Edition,最多可以连接5台计算机通过网络方问。

5. 解决办法：

6. 在cmd中执行"net config server /autodisconnect:10"(修

7. 改最后数字，此数字的单位为分钟，默认值为15。）命令即可。