Question

批处理添加网络打印机

我把本机配好打印机，导出了打印机的端口注册表，批处理执行时提示端口未知，有知道怎么回事的吗
Windows Registry Editor Version 5.00

[HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Monitors\Standard TCP/IP Port\Ports\10.45.34.13]
"Protocol"=dword:00000001
"Version"=dword:00000002
"HostName"="10.45.34.13"
"IPAddress"=""
"HWAddress"=""
"PortNumber"=dword:0000238c
"SNMP Community"="public"
"SNMP Enabled"=dword:00000001
"SNMP Index"=dword:00000001
"PortMonMibPortIndex"=dword:00000001

然后以下是批处理内容：
net stop spooler
net stop spooler
rundll32 printui.dll,PrintUIEntry /if /b "财务RICOH MP C2003 PCL 6" /f G:\MP2003\X86\DRIVERS\PCL6\XP_VISTA\MUI\disk1\OEMSETUP.inf /r "IP_10.45.34.13" /m "RICOH MP C2003 PCL 6" /z
第二个是net start ，写错了

Answer 1

1、安装tcp/ip打印机网络端口
新建一文件叫addport.reg,内容如下：
Windows Registry Editor Version 5.00
[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Print\Monitors\Standard TCP/IP Port\Ports]
"StatusUpdateInterval"=dword:0000000a
"StatusUpdateEnabled"=dword:00000001
[HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_10.103.2.3]
"Protocol"=dword:00000002
"Version"=dword:00000002
"HostName"="10.103.2.3"
"IPAddress"=""
"HWAddress"=""
"PortNumber"=dword:00000203
"SNMP Community"="public"
"SNMP Enabled"=dword:00000001
"SNMP Index"=dword:00000001
"PortMonMibPortIndex"=dword:00000001
"Queue"="print"
"Double Spool"=dword:00000000
[HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Monitors\Standard TCP/IP Port\Ports]
"StatusUpdateInterval"=dword:0000000a
"StatusUpdateEnabled"=dword:00000001
[HKEY_LOCAL_MACHINE\SYSTEM\ControlSet001\Control\Print\Monitors\Standard TCP/IP Port\Ports\IP_10.103.2.3]
"Protocol"=dword:00000002
"Version"=dword:00000002
"HostName"="10.103.2.3"
"IPAddress"=""
"HWAddress"=""
"PortNumber"=dword:00000203
"SNMP Community"="public"
"SNMP Enabled"=dword:00000001
"SNMP Index"=dword:00000001
"PortMonMibPortIndex"=dword:00000001
"Queue"="print"
"Double Spool"=dword:00000000
2、安装打印机驱动
新建一个installprint.bat文件，内容如下：
@echo off
title 保利置业打印机自动安装程序
echo 正在安装32楼大打印机，请稍等……
echo.
echo 如果运行本程序出现异常或者程序运行后未能安装打印机，请联系管理员
echo.
echo.
rem 自动判断电脑是32位还是64位
if /i "%PROCESSOR_IDENTIFIER:~0,3%"=="X86" (goto 32bit) ELSE (goto 64bit)
:64bit
echo 正在为您安装64位打印机驱动
echo.
rem 导入添加端口的注册表文件
reg import addport.reg
if errorlevel 0 echo 网络打印机端口安装成功
echo.
echo 正在重启打印服务,请稍等……
echo.
rem 必须重启打印服务才能成功添加端口
net stop spooler>nul
net start spooler>nul
if errorlevel 0 echo 打印服务重启成功
echo ..............................................
echo ..............................................
echo 删除已经存在的同名打印机
rundll32 printui.dll,PrintUIEntry /dl /n "KONICA MINOLTA 423SeriesPCL" /q
echo.
echo 安装KONICA MINOLTA 423SeriesPCL打印机......
echo.
rundll32 printui.dll,PrintUIEntry /if /b "KONICA MINOLTA 423SeriesPCL" /f CN\win_x64\KOAYXJ__.INF /r "IP_10.103.2.3" /m "KONICA MINOLTA 423SeriesPCL" /z
if errorlevel 0 echo 打印机安装成功
echo.
rem 安装好打印机后，也可以在批处理文件最后加一行命令，把这个打印机设置为默认。
echo.
echo 将这个打印机设置为默认打印机
rundll32 printui.dll,PrintUIEntry /y /n "KONICA MINOLTA 423SeriesPCL"
goto end
:32bit
echo 正在为您安装32位打印机驱动
echo.
reg import addport.reg
if errorlevel 0 echo 网络打印机端口安装成功
echo.
echo 正在重启打印服务,请稍等……
echo.
net stop spooler>nul
net start spooler>nul
if errorlevel 0 echo 打印服务重启成功
echo ..............................................
echo ..............................................
echo 删除已经存在的同名打印机
rundll32 printui.dll,PrintUIEntry /dl /n "KONICA MINOLTA 423SeriesPCL" /q
echo.
echo 安装KONICA MINOLTA 423SeriesPCL打印机......
echo.
rundll32 printui.dll,PrintUIEntry /if /b "KONICA MINOLTA 423SeriesPCL" /f CN\win_x32\KOAYXJ__.INF /r "IP_10.103.2.3" /m "KONICA MINOLTA 423SeriesPCL" /z
if errorlevel 0 echo 打印机安装成功
echo.
echo.
echo 将这个打印机设置为默认打印机
rundll32 printui.dll,PrintUIEntry /y /n "KONICA MINOLTA 423SeriesPCL"
:end
echo 请按任意键退出
pause>nul
REM #*********************************************************************************
REM #
REM # /ia 用 inf 文件安装打印机驱动程序
REM # /if 用 inf 文件安装打印机
REM # /b[name] 基本打印机名
REM # /c[name] 如果操作在远程机器上，unc 机器名
REM # /dl 删除本地打印机
REM # /dn 删除网络打印机连接
REM # /dd 删除打印机驱动程序
REM # /f[file] inf 文件或输出文件
REM # /h[arch] 驱动程序体系结构，为下列之一: Alpha | Intel | IA64
REM # /m[model] 打印机驱动程序型号名
REM # /n[name] 打印机名
REM # /v[version] 驱动程序版本属于下列中的一个: Windows 95、98 和 ME | Windows NT 4.0 | Windows NT 4.0 或 2000 | Windows 2000 或 XP| Windows XP
REM # /q 安静模式，不显示错误信息
REM # /r[port] 端口名
REM # /y 将打印机设为默认打印机
REM # /z 不要自动共享这台打印机
REM # /Z 共享这台打印机，只能跟 /if 选项一起使用
REM #其中/m参数后面的打印机驱动程序型号名为inf文件中用于指明驱动的打印机名称，一般在使用向导安装的时候在选定inf文件后出来的所有驱动名称中你自己需要的那个。
REM #
REM # 更多的帮助请使用rundll32 printui.dll,PrintUIEntry /?
REM #
REM #********************************************************************************

追问

我试过了，还是未知端口的问题，名字用的inf里的直接驱动又不对名字又不对的，

帮忙看看有没有简洁点的排错方法，不整这么多语句