Question

易语言怎么能提取文本中的某段

编辑框1中有很长一段网址
比如：http://ptlogin2.qq.com/jump_to_open_music?uin=100000&clientkey=1234A6901FDD320702335841245EFC9251B9A75AF9A035CC&aid=music.bfq.sfw.3

后面都一样

我想在编辑框2里得到另外1个网址
http://ptlogin2.qq.com/sl?clientuin=100000&clientkey=1234A6901FDD320702335841245EFC9251B9A75AF9A035CC

我只想要中间的一段，其他的部分要替换成其他的，我该怎么写语法呢

Answer 1

给你讲一下我的思路，将编辑框1.内容用“？”分割,然后将分割出来的？后面的网址再用&分割，然后循环分割，用“=”分割，将固定的值设好，找到的话就添加到变量里，最后把得到的值再拼凑到编辑框2里面，代码如下

.版本 2

.程序集 窗口程序集1

.子程序 _按钮1_被单击

.局部变量 待处理文本, 文本型

.局部变量 临时文本数组, 文本型, , "0"

.局部变量 n, 整数型

.局部变量 uin, 文本型

.局部变量 临时文本数组2, 文本型, , "0"

.局部变量 clientkey, 文本型

待处理文本 ＝ 编辑框1.内容

临时文本数组 ＝ 分割文本 (待处理文本, “?”, )

.如果真 (取数组成员数 (临时文本数组) ＜ 2)

    返回 ()

.如果真结束

待处理文本 ＝ 临时文本数组 [2]

临时文本数组 ＝ 分割文本 (待处理文本, “&”, )

.计次循环首 (取数组成员数 (临时文本数组), n)

    临时文本数组2 ＝ 分割文本 (临时文本数组 [n], “=”, )

    .如果真 (取数组成员数 (临时文本数组2) ＞ 1)

        .如果真 (临时文本数组2 [1] ＝ “uin”)

            uin ＝ 临时文本数组2 [2]

        .如果真结束

        .如果真 (临时文本数组2 [1] ＝ “clientkey”)

            clientkey ＝ 临时文本数组2 [2]

        .如果真结束

    .如果真结束

.计次循环尾 ()

编辑框2.内容 ＝ “http://ptlogin2.qq.com/sl?clientuin=” ＋ uin ＋ “&clientkey=” ＋ clientkey

Answer 2

很简答啊。实现的方法有多种。
可以使用分割文本。然后取段拼凑。两次分割就得到结果了。
第一次用 uid= 进行分割。取数组[2]
第二次用&aid 进行分割，取数组[1]
然后用加在一起。
或者用取文本中间。两次寻找文本就可以了

Answer 3

寻找文本（）
取文本中间（）
取文本左边（）
取文本右边（）