Question

ASP 显示数据库内容

想用ASP编写一个ACC数据库显示的小程序，请高手们帮下忙
数据库：user.mdb
表：info
字段：
id 自动编号
username 文本
password 文本
sex 文本
personalinfo 文本
ntime 文本
大致功能就是将它的内容全部显示出来,万分感谢！
现在能用了，但只能显示一条，想再加一条循环语句，全部显示完

Answer 1

<%
'建立数据库连接
Dim ConnStr, Conn
ConnStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("./user.mdb")
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open ConnStr

'数据库数据查询
Dim sql, rs
sql = "Select * From info"
Set rs = Server.CreateObject("Adodb.Recordset")
rs.Open sql, Conn, 1, 1

'下面是数据输出
Response.Write("<table width='100%' border='0' cellpadding='0' cellspacing='0'>") & vbCrLf
Response.Write(" <tr>") & vbCrLf
Response.Write(" <td height='30'>id</td>") & vbCrLf
Response.Write(" <td>username</td>") & vbCrLf
Response.Write(" <td>password</td>") & vbCrLf
Response.Write(" <td>sex</td>") & vbCrLf
Response.Write(" <td>personalinfo</td>") & vbCrLf
Response.Write(" <td>ntime</td>") & vbCrLf
Response.Write(" </tr>") & vbCrLf

If rs.BOF And rs.EOF Then
Response.Write("查无数据！")
Else
Do While Not rs.EOF
Response.Write(" <tr>") & vbCrLf
Response.Write(" <td height='30'>" & rs("id") & "</td>") & vbCrLf
Response.Write(" <td>" & rs("username") & "</td>") & vbCrLf
Response.Write(" <td>" & rs("password") & "</td>") & vbCrLf
Response.Write(" <td>" & rs("sex") & "</td>") & vbCrLf
Response.Write(" <td>" & rs("personalinfo") & "</td>") & vbCrLf
Response.Write(" <td>" & rs("ntime") & "</td>") & vbCrLf
Response.Write(" </tr>") & vbCrLf
rs.MoveNext
Loop
End If
Response.Write("</table>") & vbCrLf

'关闭数据库
rs.Close
Set rs = Nothing

Conn.Close
Set Conn = Nothing
%>

这是全部代码，认真仔细的研究每一句代码，能全部理解的话 那asp基本就等于入门了 加油！：）

Answer 2

<%
'建立数据库连接
Dim ConnStr, Conn
ConnStr = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & Server.MapPath("./user.mdb")
Set Conn = Server.CreateObject("ADODB.Connection")
Conn.Open ConnStr

'数据库数据查询
Dim sql, rs
sql = "Select * From info"
Set rs = Server.CreateObject("Adodb.Recordset")
rs.Open sql, Conn, 3, 1
'判断数据集中是否存在相应数据
if not rs.eof or err then
'使用while(条件){语句块}读出数据
while not rs.eof
%>
<!--下面是数据输出-->
<table width="100%" border="0" cellpadding="0" cellspacing="0">
<tr>
<td height="30">id</td>
<td>username</td>
<td>password</td>
<td>sex</td>
<td>personalinfo</td>
<td>ntime</td>
</tr>
<tr>
<td height="30"><%=rs("id")%></td>
<td><%=rs("username")%></td>
<td><%=rs("password")%></td>
<td><%=rs("sex")%></td>
<td><%=rs("personalinfo")%></td>
<td><%=rs("ntime")%></td>
</tr>
</table>

<%
'游标下移一位
rs.movenext
wend
else
resonse.write("查无数据....")
end if
'关闭数据库
rs.Close
Set rs = Nothing

Conn.Close
Set Conn = Nothing
%>

Answer 3

<%
set conn=server.createobject("adodb.connection")
conn.open "provider=microsoft.jet.oledb.4.0;" & "data source = " & server.mappath("user.mdb")
set rs=server.createobject("adodb.recordset")
rs.open"select id,username,password,sex,personalinfo,ntime from info",conn,1,1
%>
（HTML代码）
<table><tr>
<td><%=id%></td>
<td><%=username%></td>
<td><%=password%></td>
<td><%=sex%></td>
<td><%=personalinfo%></td>
<td><%=ntime%></td>
</tr></table>
(HTML代码)
这个文件要放在和USER.MDB数据库文件一个文件夹下，如果USER.MDB在根目录，就换成server.mappath("../user.mdb")
什长的很全很对，用他的吧！
补充解释一下什长的
rs.BOF And rs.EOF
BOF和EOF是数据集的指针，作为判断数据库的表中是否还存在数据的，为假则循环while not rs.eof（当不在最后一个的后面），达到输出表中所有数据的效果

Answer 4

应该不能用do
while循环。因为do
while至少要循环一次。然后数据库里没有数据，所以会出错。
你改成while循环就好了。

Answer 5

用这样的语句就OK了~!
<%if
rs1.eof
and
rs1.bof
then%>没有数据<%else%><%=rs1("username")%><%end
if%>