Question

mathematica 利用哈密顿量矩阵 画三维图

这个代码作出的是一个二维图，但是现在我想画一个三维的图
y = 0;
data8 = Table[Table[Eigenvalues[ {
{0 + 1,
3.16 Exp[
I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[-I*y*1.23*Sqrt[3]]),
0.14 Exp[
I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[-I*y*1.23*Sqrt[3]]),
0.38 Exp[-I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[I*y*1.23*Sqrt[3]])},
{3.16 Exp[-I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[I*y*1.23*Sqrt[3]]), 0.022 - 1, 0.381,
0.14 Exp[
I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[-I*y*1.23*Sqrt[3]])},
{0.14 Exp[-I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[I*y*1.23*Sqrt[3]]), 0.381, 0.022 + 1,
3.16 Exp[
I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[-I*y*1.23*Sqrt[3]])},
{0.38 Exp[
I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[-I*y*1.23*Sqrt[3]]),
0.14 Exp[-I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[I*y*1.23*Sqrt[3]]),
3.16 Exp[-I*y*2.46/Sqrt[3]]*(1 +
2 Cos[1.23*x]*Exp[I*y*1.23*Sqrt[3]]), 0 - 1}
} ], {x, -2, 2, 0.005}][[All, n]], {n, 1, 4}];

ListLinePlot[data8, InterpolationOrder -> 2, AxesOrigin -> {40, 0}]

希望能够画出像这样的三维图，该图与公式不一定能对应，请帮帮忙~

Answer 1

目视这个图好像是在3维图上又加上了等高线，然后侧边好像还有投影但是光靠目测的话判不太出来画的是啥，那我就稍微仿一下：

customizedplot[data_] := 

 Show[ListPlot3D[data, PlotStyle -> None, MeshFunctions -> (#3 &), 

   BoundaryStyle -> None], 

  ListPlot3D[data, PlotStyle -> None, MeshStyle -> Red, BoundaryStyle -> Red], 

  AxesLabel -> {None, None, Rotate[Style["Energy[eV]", 16], Pi/2]}]

customizedplot@data8

追问

谢谢帮忙，这是二维图，三维图应该是有四个曲面的吧？？

追答

……可是你每一组都是个一维列表啊，这样子哪来的三维图

追问

在y不等于零的情况下，4*4的矩阵可以得到四个与x，y相关的本征值，分别对应四个曲面，应该是这样的。。谢谢你，请帮忙看看，y不等于零时候的四个曲面。。

追答

……明白你的意思了：

f = Function[{x, y}, Exp[(I y 2.46)/Sqrt[3]] (1 + 2 Cos[1.23 x] Exp[-I y 1.23 Sqrt[3]])];

data8 = Transpose[

   Table[Eigenvalues[{{0 + 1, 3.16 f[x, y], 0.14 f[x, y], 0.38 f[x, -y]}, {3.16 f[x, -y],

        0.022 - 1, 0.381, 0.14 f[x, y]}, {0.14 f[x, -y], 0.381, 0.022 + 1, 

       3.16 f[x, y]}, {0.38 f[x, y], 0.14 f[x, -y], 3.16 f[x, -y], 0 - 1}}], {x, -2, 2, 

     0.1}, {y, -2, 2, 0.1}], {2, 3, 1}];

customizedplot[data_, color_] := 

 Show[ListPlot3D[data, PlotStyle -> None, MeshFunctions -> (#3 &), 

   BoundaryStyle -> None], 

  ListPlot3D[data, PlotStyle -> None, MeshStyle -> color, BoundaryStyle -> color, 

   PlotRange -> All], AxesLabel -> {None, None, Rotate[Style["Energy[eV]", 16], Pi/2]}, 

  BoxRatios -> {1, 1, 2}]

customizedplot @@@ Transpose[{Abs@data8, {Red, Orange, Green, Blue}}] // Show

注意画图的时候取了个绝对值，你要是不要的话就去掉。代码里用了一点Transpose的高级用法，要是理解不了的话你就直接用Part换一下也可以。（这样有部分区域无图。）结果图：

Answer 2

ListPlot3D[data8]

你现在的数据就能画成这样。

追问

非常感谢！！！