Question

高分急求一篇用汇编语言编写的大程序！！！

有没有高手帮帮忙啊。。200行左右的微机大作业，可以是画图的，音乐的，发声的。。能用就行。跪求啊。。

Answer 1

; 本程序通过编译，运行正确
; 操作说明：运行开始，首先要输入4个参数：脉冲高度、脉冲宽度、脉冲间断宽度和波线颜色。
; 各项取值范围：
; 脉冲高度：0～239
; 脉冲宽度：0～320
; 脉冲间断宽度：0～320
; 波线颜色：1～15（参见下方的颜色参数表）
; 数值位数满3位的，自动结束当前项输入，不必回车；不足3位数的，须按回车结束当前项输入
Code Segment
Assume CS:Code,DS:Code
CR EQU 000DH
LF EQU 000AH
KBBack EQU 0008H
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; Dark Colors (Foreground & Background)
; Constant Value
Black EQU 0
Blue EQU 1
Green EQU 2
Cyan EQU 3
Red EQU 4
Magenta EQU 5
Brown EQU 6
LightGray EQU 7

; Light Colors(Foreground)
; Constant Value
DarkGray EQU 8
LightBlue EQU 9
LightGreen EQU 10
LightCyan EQU 11
LightRed EQU 12
LightMagenta EQU 13
Yellow EQU 14
White EQU 15
Blinking EQU 80H
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：显示指定地址（Str_Addr）的字符串
; 入口：
; Str_Addr＝字符串地址（要求在数据段）
; 用法: Output Str_Addr
; 用法举例：Output PromptStr
Output MACRO Str_Addr
lea dx,Str_Addr
mov ah,9
int 21h
EndM
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：输出回车换行
Enter_CTLF proc Near
push ax
push dx
mov ah,02h
mov dl,0dh
int 21h
mov dl,0ah
int 21h
pop dx
pop ax
ret
Enter_CTLF endp
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：取光标位置
; 入口：无
; 出口：DH=行号，DL=列号
GetCursor Proc Near
PUSH AX
PUSH BX
PUSH CX
XOR BX,BX
MOV AH,3
INT 10H
MOV Cursor_Row,DH
MOV Cursor_Col,DL
POP CX
POP BX
POP AX
RET
Cursor_Row DB ?
Cursor_Col DB ?
GetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：置光标位置
; 入口：Cursor_Row=行坐标; Cursor_Col: 列坐标)
SetCursor Proc Near
PUSH CX
PUSH BX
PUSH AX
MOV DH,Cursor_Row
MOV DL,Cursor_Col
XOR BX,BX
MOV AH,2
INT 10H
POP AX
POP BX
POP CX
RET
SetCursor EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
; 功能：键盘输入一个N位的十进制数字，将其转换成二进制数并保存在指定的内存单元。
; 入口：N=数字位数；di=保存输入的数字首地址
; 出口：转换后的二进制数保存在di所指的单元
Input_Digit Proc Near
push dx
push cx
push bx
push di
lea di,@@Save_Tmp
push di
cld
mov cx,N
push cx
@@Input: call GetCursor ;取光标位置
mov ah,1 ;从键盘接受一个字符
int 21h
cmp al,CR ;若键入的是回车，已经键入的数字不足N位
jz @@ASC_Dec ;转去处理已经键入的数字
cmp al,KBBack
jz @@KB_Back ;若是回空键，重新输入
cmp al,'0'
jb @@KBBack ;若低于数字'0'，重新输入
cmp al,'9'
ja @@KBBack ;若低于数字'9'，重新输入
jmp @@Save_Dig
@@KB_Back: dec Cursor_Col
inc cx
dec di
@@KBBack: call SetCursor ;置光标位置
jmp @@Input
@@Save_Dig: and al,0fh ;转换成二进制数
stosb ;保存
loop @@Input ;接受下一个数字
@@ASC_Dec: mov ax,cx
pop cx
pop si
sub cx,ax ;实际输入的数字位数
xor bp,bp
xor dx,dx
xor ax,ax
jcxz @@Save_Ret ;若直接回车，没有输入任何数字，按输入'0'处理
dec cx ;实际输入的数字位数减1，准备把输入的这一串数字转换成二进制数
jcxz @@One_Digit ;若输入的数字只有一位，转去直接保存这个二进制数
mov bx,10
@@Mul_Ten: lodsb
cbw
add ax,bp
mul bx
mov bp,ax
loop @@Mul_Ten
@@One_Digit:lodsb
cbw
add ax,bp
@@Save_Ret: pop di
stosw
pop bx
pop cx
pop dx
ret
@@Save_Tmp db 16 dup(?)
Input_Digit EndP
; －－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－－
Prompt_Str1 db 'Please input pulse hight: $' ;提示输入脉冲高度
Prompt_Str2 db 'Please input pulse width: $' ;提示输入脉冲宽度
Prompt_Str3 db 'Please input pulse wait time: $' ;提示输入间断时间
Prompt_Str4 db 'Please input line colour: $' ;提示输入波线颜色
N equ 3 ;输入十进制数值位数
Hight_Pulse dw ? ;脉冲高度
Width_Pulse dw ? ;脉冲宽度
Wait_Time dw ? ;脉冲间断宽度
Colou_Pulse dw ? ;波线颜色
Start: push cs
pop ds
push cs
pop es ;使数据段、附加段与代码段同段
Output Prompt_Str1 ;提示输入脉冲高度
lea di,Hight_Pulse ;脉冲高度
call Input_Digit ;键盘输入一个3位的十进制数字，将其转换成二进制数并保存在指定的内存单元
call Enter_CTLF ;输出一个回车、换行
Output Prompt_Str2 ;提示输入脉冲宽度
lea di,Width_Pulse ;脉冲宽度
call Input_Digit
call Enter_CTLF ;输出一个回车、换行
Output Prompt_Str3 ;提示输入脉冲间断宽度
lea di,Wait_Time ;脉冲间断宽度
call Input_Digit
call Enter_CTLF ;输出一个回车、换行
Output Prompt_Str4 ;提示输入波线颜色
lea di,Colou_Pulse ;波线颜色
call Input_Digit
mov ax,12h ;设置640x480，16色图形显示方式
int 10h
; 以屏幕中间行为脉冲中间行，画一条横线
mov bp,640 ;横向点数
xor bh,bh
xor cx,cx ;横向起始点
mov dx,480 ;图形显示方式，一列480点
shr dx,1 ;纵向起始点
mov ah,0ch
mov al,byte ptr Colou_Pulse ;取像素颜色
L0: int 10h ;写一个指定颜色的像素
inc cx ;横向向右增值
dec bp
test bp,bp
jnz L0
; 从左到右、满屏画出相应的脉冲波图形。
mov bp,Hight_Pulse ;取脉冲高度
xor cx,cx ;横向起始点
mov dx,480 ;图形显示方式，一列480点
shr dx,1 ;纵向起始点
L1: int 10h ;写一个指定颜色的像素
dec dx ;纵向向上减值
dec bp
test bp,bp
jnz L1
Pulse_Wave: mov bp,Width_Pulse ;取脉冲宽度，一个脉冲周期
L2: int 10h ;写一个指定颜色的像素
inc cx ;横向向右增值
cmp cx,639
ja Pause ;若到达屏幕最右边，跳出循环，等待用户按键，结束程序
dec bp
test bp,bp
jnz L2
mov bp,Hight_Pulse ;取脉冲高度
shl bp,1
L3: int 10h ;写一个指定颜色的像素
inc dx ;纵向向下增值
dec bp
test bp,bp
jnz L3
mov bp,Wait_Time ;取脉冲间断宽度
L4: int 10h ;写一个指定颜色的像素
inc cx ;横向向右增值
cmp cx,639
ja Pause ;若到达屏幕最右边，跳出循环，等待用户按键，结束程序
dec bp
test bp,bp
jnz L4
mov bp,Hight_Pulse ;取脉冲高度
shl bp,1
L5: int 10h ;写一个指定颜色的像素
dec dx ;纵向向上减值
dec bp
test bp,bp
jnz L5
jmp Pulse_Wave ;一个脉冲周期结束，进行下一个脉冲周期
Pause: mov ah,1 ;暂停，按任意键结束程序
int 21h
mov ah,3 ;设置80x25，16色文本显示方式
int 10h
Exit_Proc: mov ah,4ch ;结束程序
int 21h
Code ENDS
END Start ;编译到此结束