Question

asp只能用一个IP登陆代码 着急~~~~~~~~在线等

本人想做一个网站,登录后台时只可根据我在数据库里设定的IP访问.如何在在登录的时候验证其访问IP,与数据库里对比.有则通过.无则返回

Answer 1

给你几个我自己写的函数，好好看看就知道怎么用了，很强大哦。
如果你想简单判断单个IP（假设是202.106.18.52）可以这么写:
Dim uIP,OK
uIP = getUserFullIP()
OK = checkIP(uIP, "202.106.18.52")

'*******************************************
' 检测IP的合法性，仅支持ipv4，宽容度很高
'*******************************************
Function isIP(ip)
Dim result
Dim RegExpObj
Set RegExpObj=new RegExp
RegExpObj.Pattern="^\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}$"
result=RegExpObj.test(ip)
Set RegExpObj=nothing
isIP=result
End Function
'*******************************************
' 获得用户IP
'*******************************************
Function getUserIP()
Dim u
u = getUserFullIP()
'隐藏最后一位
if u<>"" then
u = Left(u, InStrRev(u,"."))&"*"
else
u = "*.*.*.*"
end if
getUserIP = u
End Function
Function getUserFullIP()
Dim u
u = Request.ServerVariables("http_x_forwarded_for")
if not isIP(u) then
u = Request.ServerVariables("REMOTE_ADDR")
end if
getUserFullIP = u
End Function
Function getAgentIP()
Dim a
a = ""
if Request.ServerVariables("http_x_forwarded_for")<>"" then
a = Request.ServerVariables("REMOTE_ADDR")
end if
getAgentIP = a
End Function
'**************************************************
' 检查IP是否在指定IP范围内
' IP范围表示方法
' 1、独立ip
' 2、ip段，中间用~连接
' 3、模式，支持?*两种模糊匹配符
' 4、取反符号^，可以搭配前三种模式使用
' 例如： 192.168.0.1,192.168.0.3~192.168.0.5,192.168.1.*,^192.168.1.1
'***************************************************
Function checkIP(aIP, ipRange)
Dim ips, isNeg, hit, i, n, ipArr, check
ipArr = Split(ipRange, ",")
n = Ubound(ipArr)
hit = false
for i=0 to n
'逻辑允许或不允许
ips = ipArr(i)
isNeg = false
if Left(ips,1)="^" then
isNeg = true
ips = Mid(ips, 2)
end if
' 命中之后，只检测非允许字段
if (hit and isNeg) OR not hit then
check = checkIPRange(aIP, ips)
if check and not isNeg then
hit = true
elseif check and isNeg then
checkIP = false
Exit Function
end if
end if
next
checkIP = hit
End Function
'**********************
' 检测IP段/模式
' 无组合模式，无取反模式
'**********************
Function checkIPRange(aIP, ipRange)
Dim mode, tArr, sIP, eIP, iIP, ipRegTxt, RegExpObj, ok
mode = 1
if Instr(ipRange,"~")>0 then mode=2
Select Case mode
Case 1:
ipRegTxt = Replace(Replace(Replace(ipRange, "?", "\d"), "*", "\d*"), ".", "\.")
Set RegExpObj = new RegExp
RegExpObj.Pattern= ipRegTxt
RegExpObj.IgnoreCase = True
ok = RegExpObj.Test(aIP)
Set RegExpObj = nothing
Case 2:
tArr = Split(ipRange, "~", 2)
sIP = IP2Num(tArr(0))
eIP = IP2Num(tArr(1))
iIP = IP2Num(aIP)
ok = false
if (sIP-iIP)*(eIP-iIP)<=0 then ok = true
End Select
checkIPRange = ok
End Function
'**********************
' 将IP转化为数字
'**********************
Function IP2Num(ByVal aIP)
Dim num, i, ipArr
ipArr = Split(aIP, ".", 4)
num = 0
For i = 0 To 3
num = num + Cint(ipArr(i)) * (256 ^ (3 - i))
Next
IP2Num = num
End Function
'**********************
' 将数字转化为IP
'**********************
Function Num2IP(ByVal num)
Dim aIP, temp, i
aIP = ""
For i = 3 To 0 Step -1
temp = Int(num / (256 ^ i))
aIP = aIP & temp & "."
num = num - (temp * (256 ^ i))
Next
Num2IP = Left(aIP, Len(aIP) - 1)
End Function

Answer 2

Function GetRealIP()
GetRealIP = Request.ServerVariables("HTTP_X_FORWARDED_FOR")
IF(GetRealIP = "")THEN GetRealIP = Request.ServerVariables("REMOTE_ADDR")
End Function