Question

易语言 挂机锁 谁有好点的源码 用组合键可以破的不要

我用易语言写了个挂机锁,但以用Alt+f4或组合键或 进程关闭 谁有好点的源码 严重加分

Answer 1

.版本 2

.程序集 窗口程序集1
.程序集变量 输入的密码, 文本型
.程序集变量 设置的密码, 文本型
.程序集变量 第一次运行, 逻辑型

.子程序 __启动窗口_创建完毕

锁键 (97, 1, 0, 0)
设置的密码 ＝ 取文本注册表项 (“SYSTEMSET”, “SET”, “PMM”, “”)
是否隐藏窗口 ＝ 取数值注册表项 (“SYSTEMSET”, “SET”, “DESK”, 1)
.如果 (设置的密码 ＝ “”)
第一次运行 ＝ 真
总在最前 ＝ 假
解锁按钮.禁止 ＝ 真
退出按钮.禁止 ＝ 假
设置按钮.禁止 ＝ 假
设置按钮.获取焦点 ()
信息框 (“本程序还未进行设置，请按下设置钮对本程序进行初始设置！”, #信息图标, “信息：”)
.否则
.如果真 (是否隐藏窗口 ＝ 1)
位置 ＝ 3
.如果真结束
设置鼠标位置 ()
.如果结束

.子程序 _密码框_内容被改变

输入的密码 ＝ 密码框.内容

.子程序 _解锁按钮_被单击

.如果 (输入的密码 ＝ 设置的密码)
退出按钮.禁止 ＝ 假
设置按钮.禁止 ＝ 假
总在最前 ＝ 假
锁键 (97, 0, 0, 0)
取消鼠标限制 (0)
退出按钮.获取焦点 ()
.否则
密码框.获取焦点 ()
.如果结束

.子程序 _设置按钮_被单击

载入 (设置窗口, _启动窗口, 真)

.子程序 _退出按钮_被单击

结束 ()

.子程序 设置鼠标位置
.局部变量 RECT, 矩形区域

RECT.Left ＝ _启动窗口.左边
RECT.Top ＝ _启动窗口.顶边 ＋ 30
RECT.Right ＝ _启动窗口.左边 ＋ 135
RECT.Bottom ＝ _启动窗口.顶边 ＋ 128
限制鼠标 (RECT)

.版本 2

.程序集 窗口程序集2
.程序集变量 密码1, 文本型
.程序集变量 密码2, 文本型
.程序集变量 是否开机运行, 整数型, , , 0为否，1为是
.程序集变量 设置的密码, 文本型

.子程序 _设置窗口_创建完毕

设置的密码 ＝ 取文本注册表项 (“SYSTEMSET”, “SET”, “PMM”, “”)
是否开机运行 ＝ 取数值注册表项 (“SYSTEMSET”, “SET”, “BEGIN”, 0)
密码编辑框1.内容 ＝ 设置的密码
密码编辑框2.内容 ＝ 设置的密码
.如果 (是否隐藏窗口 ＝ 1)
桌面选择框.选中 ＝ 真
.否则
桌面选择框.选中 ＝ 假
.如果结束
.如果 (是否开机运行 ＝ 1)
运行选择框.选中 ＝ 真
.否则
运行选择框.选中 ＝ 假
.如果结束

.子程序 _密码编辑框1_内容被改变

密码1 ＝ 密码编辑框1.内容

.子程序 _密码编辑框2_内容被改变

密码2 ＝ 密码编辑框2.内容

.子程序 _桌面选择框_被单击

.如果 (是否隐藏窗口 ＝ 0)
桌面选择框.选中 ＝ 真
是否隐藏窗口 ＝ 1
.否则
桌面选择框.选中 ＝ 假
是否隐藏窗口 ＝ 0
.如果结束

.子程序 _运行选择框_被单击

.如果 (是否开机运行 ＝ 0)
运行选择框.选中 ＝ 真
是否开机运行 ＝ 1
.否则
运行选择框.选中 ＝ 假
是否开机运行 ＝ 0
.如果结束

.子程序 _保存按钮_被单击

.如果 (密码1 ＝ 密码2)
写注册表项 (“SYSTEMSET”, “SET”, “PMM”, 密码1)
写注册表项 (“SYSTEMSET”, “SET”, “DESK”, 是否隐藏窗口)
写注册表项 (“SYSTEMSET”, “SET”, “BEGIN”, 是否开机运行)
.如果 (是否开机运行 ＝ 1)
写注册项 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\systemkey”, 取运行目录 () ＋ “\” ＋ 取执行文件名 ())
.否则
删除注册项 (4, “SOFTWARE\Microsoft\Windows\CurrentVersion\Run\systemkey”)
.如果结束
销毁 ()
.否则
信息框 (“确认密码不符！”, #警告图标, “密码错误！”)
密码编辑框2.获取焦点 ()
.如果结束

.子程序 _取消按钮_被单击

销毁 ()

.版本 2

.数据类型 矩形区域
.成员 Left, 整数型
.成员 Top, 整数型
.成员 Right, 整数型
.成员 Bottom, 整数型

Answer 2

禁止Alt+F4关闭

.子程序 __启动窗口_可否被关闭, 逻辑型

返回 (假)

禁止任务管理器可以用“打开文件”共享方式选择#禁止读写