Question

批处理运行程序弹出对话框

安装很多补丁，都下好了的，不想一个一个点，求一批处理，在安装的时候能按要求解决弹出的对话框。安装，稍后重启计算机

Answer 1

=======================这里开始=========================
@echo off
::好像OFFICE的补丁打不上。修改2010年2月1日 10:50:48
::把本程序放到补丁目录运行就可以了。
title 安装所有补丁 By 狐狸不摔跤
::启动延缓环境变量扩展（不开启延迟变量的话，在FOR里面set=%num%+1就无效了）
setlocal enabledelayedexpansion
::::::::::::::::::::::::::::::::::::::::::::::::::::
:: 补丁选项说明 ::
:: /quiet 安静模式（没有用户交互操作或显示） ::
:: /norestart 安装完成后不要重新启动 ::
:: /nobackup 不备份卸载需要的文件 ::
::::::::::::::::::::::::::::::::::::::::::::::::::::
set num=0
echo.
echo.
echo 正在安装补丁，切记不要关闭本窗口！
echo.
echo 安装所有补丁可能需要一点时间，请耐心等待。
::补丁总数
for /f "delims=" %%i in ('dir /b *.exe') do (
set /a a+=1
)
::开始安装补丁
FOR %%X IN (*.exe) DO (
echo.
set /a num+=1
::echo !num!
echo 共 !a! 个补丁,正在安装第 !num! 个补丁: %%X
start /wait %%X /quiet /norestart /nobackup
)
echo.
echo 安装完毕,按任意键退出.&&pause 1>nul 2>nul&&exit

=======================这里结束=========================
你们看着自己修改吧，还有很多不足之处。

Answer 2

打补丁嘛
只要这几句就是
在补丁文件夹运行

@echo off
for %%i in (*.exe) do start /wait %%i /passive /norestart
shutdown -r -t 60 -c "运行shutdown -a可取消关机"

Answer 3

好东西拿出来一起分享嘛