Question

ASP小偷程序的编写

小偷程序读用URL传值的网页很容易，可是URL不变，用的是INPUT传值的网页应该怎么做？？？
网页里的页数选择为列表框的，可是列表框的选择页面的参数给隐藏了，如何找出隐藏的内容

Answer 1

我最近也正在研究这个东西，楼主看看这段程序，我用这段程序成功获取了不少网站的信息。具体到不同的网站可能会有一些小的修改，我们可以一起讨论。
<%
Dim Url,Content,awbno
Url = "网址"
awbno = Request.Form("awbno")
If awbno="" Or IsNull(awbno) Then
Content = GetData(Url,1)
Else
Content = PostData(Url&"return.asp","awbno=" & awbno,1)
End If

Content = Replace(Content,"images/",Url & "images/")
Content = Replace(Content,"return.asp","")
Response.Write Content

Function GetData(GetUrl,GetMode)
Dim Http
Set Http = Server.CreateObject("msxml2.XMLHTTP")
With Http
.Open "GET",GetUrl,False
.SetRequestHeader "Referer",GetUrl
.Send
If GetMode = 0 Then
GetData = .ResponseBody
Else
GetData = BytesToBstr(.ResponseBody,"GB2312")
End If
End With
Set Http = Nothing
End Function

Function PostData(PostUrl,PostStr,PostMode)
Dim Http
Set Http = Server.CreateObject("msxml2.XMLHTTP")
With Http
.Open "POST",PostUrl,False
.SetRequestHeader "Content-Length",Len(PostStr)
.SetRequestHeader "Content-Type","application/x-www-form-urlencoded"
.SetRequestHeader "Referer",PostUrl
.Send PostStr
If PostMode=0 Then
PostData = .ResponseBody
Else
PostData = BytesToBstr(.ResponseBody,"GB2312")
End If
End With
Set Http = Nothing
End Function

Function BytesToBstr(Body,Cset)
Dim ADOS
Set ADOS = Server.CreateObject("Adodb.Stream")
With ADOS
.Type = 1
.Mode =3
.Open
.Write Body
.Position = 0
.Type = 2
.Charset = Cset
BytesToBstr = .ReadText
.Close
End With
Set ADOS = Nothing
End Function
%>

Answer 2

用 INPUT 传值的网页可以用后台 XMLHTTP 模拟一个 POST 动作完成的 ...

上面的代码是个很好的例子呢 ...

Answer 3

就跟读取其他form的变量一样的方法啊.一个一个的把变量读出来