Question

加急，cmd批处理if语句问题（应该是）

加急，cmd批处理if语句问题（应该是）不加里面嵌套的if的时候（只有最外层那三个判断）可以正常跑，加了那俩嵌套的就跑不动了，死在第一个if那

Answer 1

@echo off
setlocal enabledelayedexpansion

echo,
echo 本地请输1，远程请输2，自定义请输3
echo,
set /p fir=请输入链接目标：

if "!fir!"=="3" (
    goto Custom
) else (
    if "!fir!"=="1" (
        echo,
        echo 无密码输1，带密码输2
        echo,
        set /p lo=选择版本：
        if "!lo!"=="1" (
            cd /d E:\phpstudy\www\redis
            redis-cli -h localhost -p 6379
        ) else (
            cd /d E:\phpstudy\www\redis
            redis-cli -h localhost -p 6379 -a 12345
        )
    ) else (
        if "!fir!"=="2" (
            echo,
            echo 无密码输1，带密码输2
            echo,
            set /p re=选择版本：
            if "!re!"=="1" (
                cd /d E:\phpstudy\www\redis
                redis-cli -h 192.168.1.1 -p 6379
            ) else (
                cd /d E:\phpstudy\www\redis
                redis-cli -h 192.168.1.1 -p 6379 -a 12345
            )
        )
    )
)

exit

:Custom
::以下写选择自定义输入后执行的代码

这是修正并优化去除了一些多余命令后的代码。

再来一个继续缩减代码优化的：

@echo off
setlocal enabledelayedexpansion

echo,
echo 本地请输1，远程请输2，自定义请输3
echo,
set /p fir=请输入链接目标：

if "!fir!"=="3" (
    goto Custom
) else (
    if "!fir!"=="1" (
        set host=localhost
        set pass=12345
        goto Select
    ) else (
        if "!fir!"=="2" (
            set host=192.168.1.1
            set pass=12345
            goto Select
        )
    )
)
exit

:Select
echo,
echo 无密码输1，带密码输2
echo,
set /p Select=选择版本：
if "!Select!"=="1" (
    cd /d E:\phpstudy\www\redis
    redis-cli -h !host! -p 6379
) else (
    cd /d E:\phpstudy\www\redis
    redis-cli -h !host! -p 6379 -a !pass!
)
exit

:Custom
::以下写选择自定义输入后执行的代码

追问

😂😂大佬呀，我没用过cmd，就是在开redis的时候不想那么麻烦，所以你看上面的改的话怎么改，你说的那种优化看不懂。。

追答

上面有两个版本的代码，您只需更改一下远程IP地址和密码，就可以直接使用了。

追问

这是为啥？改成了感叹号判断进不去。。

追答

请直接使用我给您写的。
那个代码已经直接按照您的要求写了。

您只需修改一下代码中的IP地址和密码即可。

至于自定义输入的代码直接添加到脚本底部。

通过网页端查看我的回答，可以看见两个版本的代码。

您的代码无法正常执行，那是因为套嵌中的变量设置您没有开启环境变量延迟导致的执行错误。

追问

可否问一下之前那个为啥不行呀

哦哦，看到了。谢谢啊

追答

上面不是说了吗？套嵌中设置变量，需要开启环境变量延迟，否则变量无效。

这时候您里层的那些if因为没有变量值就会变成if ==1 (这样的错误代码，所以会直接终止。

以后记住套嵌循环设置变量时必须开启环境变量延迟，并把变量百分号换成感叹号。
同时为了避免错误，if ==这样的比较，双等于号前后的值请用双引号括起来。

Answer 2

你把最外层三个判断分开就完事了
IF %FIR%=="1"
IF %FIR%=="2"
IF %FIR%=="3"
或者是
for %%i in ( 1 2 3 ) do (
set /p fir="请输入:"
if "%FIR%"=="%%i" (
goto select%i%
)
else exit
)
:select1

xxxx
:select2
xxxx
:selet3
xxxxx