Question

魔兽世界MS的常用宏(能用的)

我要MS常用的宏,要有用的!!!
要实用的,比如 打断施法用真言术.盾
要升级用的常用宏~

Answer 1

我治疗法术是可以加目标的目标的，这样有一定的优势，有时候我就看着BOSS加，OT了也方便救DPS

　　在战场更方便了，看着对方加，还可以DPS

　　举个GH的例子，快速啊，恢复啊，愈合啊，都可以这么编

　　/cast [target=target,help] 强效治疗术(等级 7)

　　/cast [target=targettarget,help] 强效治疗术(等级 7)

　　/cast [target=player] 强效治疗术(等级 7)

　　首先加目标，如果目标是敌对的，那么就加目标的目标，如果也是敌对的，那么就加自己

　　盾有时候是可以救命的，所以一定要加进去打断的宏

　　/stopcasting

　　/cast [target=target,help]真言术：盾(等级 12)

　　/cast [target=targettarget,help] 真言术：盾(等级 12)

　　/cast [target=player] 真言术：盾(等级 12)

　　我有一个救场的宏是盾和太阳水瓶一起用，盾和水瓶一起能给人加将近4000血，顶个小破釜呢

　　所以我很喜欢这个水瓶，是MS的小迅捷

　　/stopcasting

　　/cast 真言术：盾(等级 12)

　　/use 太阳之井的水瓶

　　暗影魔BB可以回蓝的，特别打JJC的时候很重要，有时候要换目标很麻烦

　　然后BB又有可能因为姿态问题不回蓝，怎么办？做个宏咯

　　/cast [target=target,harm] 暗影恶魔(等级 1)

　　/cast [target=targettarget,harm] 暗影恶魔(等级 1)

　　/petattack

　　/petdefensive

　　驱魔咯，这个宏的重要性不言而喻，FB JJC ZC都非常有用

　　我是血精灵MS，一键驱散不能用，就自己编个宏

　　/stopcasting

　　/cast [target=mouseover,exists,nodead] 驱散魔法(等级 2)

　　/cast [target=target,nodead] 驱散魔法(等级 2)

　　/cast [target=player] 驱散魔法(等级 2)

　　打断当前施法，驱散鼠标所指的目标，如果鼠标什么也没指，就驱散目标，如果目标也不存在，就驱散自己

　　喊CS的宏

　　/y 我已经给 [ %t ] 防护恐惧结界 了

　　/cast 防护恐惧结界

　　打AK啊 夜龙啊什么的都要CS的，我这个宏是放出CS喊一下给XXCS了，让MS别重复

　　最有就一个座骑的宏，能飞的地方飞，不能飞的就骑马，省格子用的

　　#showtooltip [noflyable] 迅捷紫色陆行鸟; 紫色骑乘虚空鳐

　　/dismount [mounted]

　　/use [noflyable] 迅捷紫色陆行鸟; 紫色骑乘虚空鳐

　　其他的宏大家都有，我就不贴了，献丑了，呵呵。

Answer 2

第一个：
目标是友善就用恢复术（顶级的，也就是12级的）要是目标是敌对就用吸血鬼之触（也是顶级的，3级）
第二个：
目标是友善就用快速治疗（顶级的，也就是9级的）要是目标是敌对就用心灵震爆（也是顶级的，11级）
第三个：
在不丢失当前目标的时候，补你前面锁的怪的束缚亡灵~当然也要有解除的宏
第一
/cast [help,exists] 恢复; [harm,exists] 吸血鬼之触
第二
/cast [help,exists] 快速治疗; [harm,exists] 心灵震爆

第三
当且仅当你的上一个目标是锁的目标...
/focus
/targetlasttarget
/cast 束缚亡灵
/target focus
/clearfocus

加buff：

/castsequence 真言术：韧,神圣之灵,防护暗影
战场和竞技场准备时间加buff用，按一次加一个buff。

/castsequence 真言术：韧(等级 1),神圣之灵(等级 1),防护暗影(等级 1)
开战后补buff宏，对付对方的进攻驱散保队友buff用。
慎用，珍惜公共CD。

治疗：

/cast [modifier:alt,target=player] 强效治疗术
/cast [help] 强效治疗术; [target=targettarget] 强效治疗术
无论目标是谁，按alt+对自己施放强效治疗
目标是友方时，对目标施放强效治疗
目标敌对，对目标的目标施放强效治疗

同样，可以改成快速治疗，痛苦压制等等。
/cast [modifier:alt,target=player] 快速治疗
/cast [help] 快速治疗; [target=targettarget] 快速治疗

暗影魔：

#show 暗影恶魔
/cast 暗影恶魔
/petattack
/petpassive

暗影魔召出后攻击目标，改被动模式。
这样暗影魔就不会因为别人攻击了牧师而换目标了。

能量灌注：

#show 能量灌注
/stopcasting
/cast [modifier:alt,target=player] 能量灌注
/cast [target=队友名字] 能量灌注
/cast [help] 能量灌注
按alt+对自己施放能量灌注
否则不论当前目标是谁，对事先输入名字的队友施放能量灌注
最后一行是我打战场懒得改按键了加进去的，当队友不在时对当前目标施放能量灌注
3V3贼法牧组合用这个宏相当舒服，其他场合不好用……还是点了人再加灌注吧。
或者可以改成这样：

#show 能量灌注
/stopcasting
/cast [modifier:alt,target=player] 能量灌注
/cast [modifier:shift,target=队友A] 能量灌注
/cast [modifier:ctrl,target=队友B] 能量灌注
/cast [target=队友C] 能量灌注
/cast [help] 能量灌注
按alt+给自己，按shift+给队友A，ctrl+给队友B，直接按给队友C。
驱散：

/stopcasting
/cast 群体驱散
大驱散宏，作用是避免鼠标同时多点造成的驱散范围选框消失

/cast [target=targettarget] 驱散魔法
驱散目标的目标

/cast [modifier:alt,target=player] 驱散魔法
/cast [help] 驱散魔法; [harm] 驱散魔法
经常看到求alt+驱散自己，直接按驱散目标的宏，就是这个。
其实这个宏完全没必要，设置alt+自我施法就可以了……不过既然要的人多，还是放出。

焦点相关：

#show 沉默
/stopcasting
/cast [target=focus,exists] 沉默
焦点沉默宏

#show 暗言术：灭
/stopcasting
/cast [target=focus,exists] 暗言术：灭
灭焦点宏
灭破羊，破陷阱破盲....

#show 暗言术：灭
/stopcasting
/cast [target=focus,exists,harm,nodead] 暗言术：灭;[harm,nodead]暗言术：灭
复杂一点的灭焦点宏
焦点已死就灭当前目标
如果使用系统默认动作条，为了节约动作条位置不想把灭当前目标和灭焦点设置成2个键，就这样：
#show 暗言术：灭
/stopcasting
/cast [modifier:alt,harm,nodead]暗言术：灭;[target=focus,exists,harm,nodead] 暗言术：灭;[harm,nodead]暗言术：灭
按alt灭当前目标
直接按灭焦点

不间断的鞭子:

　　/cast [nochanneling] 精神鞭笞