Question

javascript如何给已经打开的excel表格赋值？

如题本人新手~

做两个按钮分别把变量输入excel单元格(1,1),(1,2)中
按钮一代码：
SUB one_onclick()
dim app
set app = createobject("Excel.Application")
app.Visible = true
dim wb
Set wb = app.Workbooks.open("D:\bb.xlsx")
dim ws
set ws = wb.worksheets("Sheet1")
ws.Cells(1,1)=“变量”
按钮一成功生成了bb.xlsx，但是按钮二按照同样的办法是生成bb.xlsx的副本，就是又生成一个excel文件，请大师帮忙，按钮二的代码如何写能能把变量赋值到按钮一生成的bb.xlsx中。简单说就是如何给已经打开的excel单元格赋值~~先谢啦~~

Answer 1

首先，你这是VBScript，不是javascript，别误导人。

其次，你的问题有两种解决办法：

一是在每个按钮修改文件后都把文件立刻关闭：

Sub one_onclick()  '按钮一
    Dim app, wb, ws
    Set app = createobject("Excel.Application")
    app.Visible = true
    Set wb = app.Workbooks.open("D:\bb.xlsx")
    Set ws = wb.worksheets("Sheet1")
    ws.Cells(1,1) = "变量1"
    wb.Save
    wb.Close
    app.Quit
    set ws = nothing
    set wb = nothing
    set app = nothing
End Sub

Sub two_onclick()  '按钮二
    Dim app, wb, ws
    Set app = createobject("Excel.Application")
    app.Visible = true
    Set wb = app.Workbooks.open("D:\bb.xlsx")
    Set ws = wb.worksheets("Sheet1")
    ws.Cells(1,2) = "变量2"
    wb.Save
    wb.Close
    app.Quit
    set ws = nothing
    set wb = nothing
    set app = nothing
End Sub

二是用一个按钮打开文件，然后在文件修改期间不保存也不关闭，最后用一个按钮保存并关闭：

Dim app, wb, ws   '对象变量要声明为全局的

Sub open_onclick()  '打开文件的按钮
    Set app = createobject("Excel.Application")
    app.Visible = true
    Set wb = app.Workbooks.open("D:\bb.xlsx")
    Set ws = wb.worksheets("Sheet1")
End Sub

Sub one_onclick()  '按钮一
    ws.Cells(1,1) = "变量1"
End Sub

Sub two_onclick()  '按钮二
    ws.Cells(1,2) = "变量2"
End Sub

Sub close_onclick()  '关闭文件的按钮
    wb.Save
    wb.Close
    app.Quit
    set ws = nothing
    set wb = nothing
    set app = nothing
End Sub