Question

bat批处理 做个在一个文件夹目录下的文件夹文件剪切到另一个地方

比如我有一个文件夹a，里面有几个文件夹（1-100文件夹，101-200文件夹，201-300文件夹），我想把这三个文件夹剪切到u盘（I:\），注意我想把这三个一个个剪切到u盘，比如先把1-100文件夹剪切到u盘后在接着剪切101-200文件夹（接下也是如此），现在想请你做这样一个bat，把a文件夹下的几个文件夹一个接着一个剪切到u盘，我想能做个直接把bat放在一个文件夹目录下，就可以把这个文件夹下面的文件夹和文件剪切到u盘，注意的是要把文件夹1-100,101-200,201-300一起剪切，我在网上看到的都是把1-100文件夹里面文件剪切并没有这个1-100文件夹也剪切，希望注意这点

Answer 1

@echo off & title 移动文件夹 By 依梦琴瑶

set /p ScrDir=请输入要处理的主路径:
echo,
set /p SavDir=请输入保存路径目的地:

for /f "delims=" %%a in ('dir /ad /b /on "%ScrDir%\*"') do (
    echo 正在移动 "%%~a" ...
    move "%ScrDir%\%%~a" "%SavDir%\"
)
pause

追问

不行，拒绝访问，什么意思，移动不了文件夹

追答

这个可能是跨盘的问题。move命令不能跨盘移动文件夹。

您脚本主要工作环境是什么？有XP吗？

追问

我的电脑系统是win7 64位系统

追答

@echo off & title 移动文件夹 By 依梦琴瑶

set /p SrD=请输入要处理的主路径:
echo,
set /p SvD=请输入保存路径目的地:

echo, & call :CheckComAndFixPath

for /f "delims=" %%a in ('dir /ad /b /on "%SrD%\*"') do (
    echo 正在移动 "%%~a" ...
    call :Cut_%Com% "%%~a"
)
echo, & pause
exit

:Cut_1
move "%SrD%\%~1" "%SvD%\"
goto :eof

:Cut_2
robocopy "%SrD%\%~1" "%SvD%\%~1" * /s /e /move
goto :eof

:Cut_3
xcopy /s /e /h /j /c "%SrD%\%~1" "%SvD%\%~1\"
rd /s /q "%SrD%\%~1"
goto :eof

:Cut_4
md "%SvD%\%~1\" 2>nul
copy "%SrD%\%~1" "%SvD%\%~1\" 2>nul
for /f "delims=" %%i in ('dir /ad/s/b "%SrD%\%~1"') do (
    set "DrP=%%~i"
    call md "%SvD%\%%DrP:%SrD%\=%%" 2>nul
    call copy "%%~i" "%SvD%\%%DrP:%SrD%\=%%\" 2>nul
)
rd /s /q "%SrD%\%~1"
goto :eof

:CheckComAndFixPath
for %%a in ("%SrD%") do set "SrD=%%~fa"
for %%a in ("%SvD%") do set "SvD=%%~fa"
if "%SrD:~,2%"=="%SvD:~,2%" (
    set Com=1
    goto :eof
)
pushd %SystemRoot%\System32
if exist robocopy.exe (
    set Com=2
) else (
    if exist xcopy.exe (
        set Com=3
    ) else (
        set Com=4
    )
)
popd
goto :eof

Answer 2

for /d %%a in (*) do  robocopy /e "%%a" "I:\%%a"
(del /f /s /q *&rd /s /q "%%~dp0")>NUL 2>NUL