Question

vb 在图片上添加文字后保存 高分求！

如何给picture box中的图片，自动添加文字，然后保存图片，保存后的图片需要有文字在上面！
同时还希望能给文字添加一个底色块！请高人指点，谢谢！ 如果Picture Box中实现不了，用其他方法也可以， 另外不保存后的图片尺寸是原来。

Answer 1

Private Sub Command1_Click()
Picture1.AutoRedraw = True
Picture1.AutoSize = True
Picture1.Picture = LoadPicture("f:\1.jpg")   '调入图片，自己改
Picture1.Line (90, 90)-(990, 300), vbRed, BF  '文字底色块（红）
Picture1.CurrentX = 105  '文字位置
Picture1.CurrentY = 105
Picture1.ForeColor = vbWhite  '文字颜色（白）
Picture1.FontSize = 9  '字号
Picture1.Print "hi，你好！"  '添加文字
SavePicture Picture1.Image, "f:\2.bmp"  '保存图片，只能存为bmp
End Sub

Answer 2

Private Sub DarwText(ByVal PictBox As PictureBox, ByVal Text As String, ByVal Left As Long, ByVal Top As Long, Optional BackColor As Long = -1, _
Optional FontSize As Long = 9, Optional FontColor As Long = 0, Optional FontBold As Boolean = False)
'必选参数PictBox   要绘制文字的PictureBox
'必选参数Text      要绘制的文字
'必选参数Left      要绘制文字的坐标
'必选参数Top       要绘制文字的坐标
'可选参数BackColor 要绘制文字的背景色小于0不绘制  默认值-1不绘制
'可选参数FontSize  要绘制文字字号大小 此处默认9 可以把9改成你最经常用的字号
'可选参数FontColor 要绘制文字颜色  默认黑色
'可选参数FontBold  要绘制文字粗细  默认不加粗
PictBox.AutoRedraw = True: PictBox.AutoSize = True: PictBox.BorderStyle = 0
PictBox.Font.Size = FontSize: PictBox.Font.Bold = FontBold: PictBox.ForeColor = FontColor                      '设置字体格式
If BackColor >= 0 Then
    Me.Font.Size = FontSize: Me.Font.Bold = FontBold: PictBox.CurrentX = Left: PictBox.CurrentY = Top
    PictBox.Line -Step(TextWidth(Text), TextHeight(Text)), BackColor, BF                                       '绘制背景色块
End If
PictBox.CurrentX = Left: PictBox.CurrentY = Top                                                                '设置文本位置
PictBox.Print Text                                                                                             '绘制文本
PictBox.Refresh
End Sub

Private Sub Command1_Click()                     '加载图片
Picture1.Picture = LoadPicture(Text1.Text)
End Sub

Private Sub Command2_Click()                     '添加文字
If Check1.Value = 0 Then
DarwText Picture1, Text2.Text, 500, 100, , 20, RGB(250, 250, 250)  '无背景色
Else
DarwText Picture1, Text2.Text, 500, 100, RGB(100, 150, 100), 20, RGB(250, 250, 250)  '有背景色
End If
End Sub

Private Sub Command3_Click()                     '保存图片
SavePicture Picture1.Image, Text3.Text
End Sub

源文件已上传  http://pan.baidu.com/s/1i3Cpw5B