Question

Excel 如何用VBA得到第几列的列号

Answer 1

有如下两种操作，目前还不知你要选择哪种。

A. 已知字母序号，求列数（数字表示）

使用如下公式，括号内为该列字母序号

columns("AZ").column

返回值为52.

B.已知列数，求字母序号列

使用如下公式，括号内为单元格地址（行，列）。

cells(1,52).address

返回值为$AZ$1，可再利用mid()公式提取2、3位字符。

具体操作如下：

alt+F11，打开VBA编辑器

alt+G，立即窗口

输入如下代码：

?columns("AZ").column

回车

Answer 2

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 获取列名 2019-01-01
',,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
Function GetColName(ByVal colN As Long) As String
Dim tryBase As Long, tryPow As Long, colC As Long
Dim colNameTbl As String, tempColN As String

'colNameTbl = "A,B,C,D,E,F,G,H,I,J,K,L,M,N,O,P,Q,R,S,T,U,V,W,X,Y,Z"

' 数值异常，按第一列输出
If colN <= 0 Then
GetColName = "A"
Exit Function
End If

'colName = Split(colNameTbl, ",")

' 列名编号和取值范围
' A- Z: 1-26
' AA- ZZ: 26+(1-26*26)
' AAA-ZZZ: 26+26*26+(1-26*26*26)
' ...
' 实际上最新的EXCEL只能支持16384列：XFD，但程序可以触及到任何 long 值上限
' 确定需要几个字母来表示列号
tryBase = 0: tryPow = 1: colC = colN - 1
Do While tryBase + tryPow * 26 <= colC
tryBase = tryBase + tryPow * 26
tryPow = tryPow * 26
Loop

' 根据字母数生成列名
colC = colC - tryBase: tempColN = ""
Do While tryPow > 0
tempColN = Chr(65 + (colC Mod 26)) & tempColN
colC = Int(colC / 26): tryPow = Int(tryPow / 26)
Loop
GetColName = tempColN
End Function
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' 获取列号 2019-01-03
',,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,,
Function GetColNum(ByVal colName As String) As Long
Dim tryBase As Long, tryPow As Long, colNum As Long
Dim colNameTbl As String, tempColN As String

' 数值异常，按第一列输出
If colName = "" Or colName Like "*[!a-zA-Z]*" Then
GetColNum = 1
Exit Function
End If

colName = UCase(colName)

' 列名编号和取值范围
' A- Z: 1-26
' AA- ZZ: 26+(1-26*26)
' AAA-ZZZ: 26+26*26+(1-26*26*26)
' ...
' 实际上最新的EXCEL只能支持16384列：XFD，但程序可以触及到任何 long 值上限
' 确定编号的base值
tryBase = 0: tryPow = 1
For i = 1 To Len(colName) - 1
tryBase = tryBase + tryPow * 26
tryPow = tryPow * 26
Next i

' 按序号求最终行号
tryPow = 1: colNum = 1
For i = Len(colName) To 1 Step -1
colNum = colNum + (Asc(Mid(colName, i, 1)) - 65) * tryPow
tryPow = tryPow * 26
Next i

GetColNum = colNum + tryBase

End Function