Question

代码问题 希望高手指点！请详细具体一点，我可以说是一点都不懂得，如果把我讲懂了，加分

这是第一个代码：（是关于flash中下雨的制作的，代码是对的，请讲解一下）
duplicateMovieClip("mi", i, i);
setProperty(i, _x, random(600));
setProperty(i, _y, random(400));
setProperty(i, _alpha, random(50)+50);
tint = random(40)+40;
eval(i)._xscale = tint;
eval(i)._yscale = tint;
i = i+1;
if (i == 150) {
gotoAndPlay(1);
}

第二个代码：
onClipEvent (enterFrame) {
if (this._x<=_parent.w) {
this._x += speed;
} else {
_x = 0;
_y = random(_parent.h);
speed = random(10)+2;
_xscale = 50+speed*4;
_yscale = 50+speed*4;
this.gotoAndPlay(int(random(this._totalFrames+1)));
this.l.gotoAndStop(int(random(4)));
}
}
这是一个风的效果展示，有花瓣在场景中飞舞的情景

第三个代码：
total = _root.getBytesTotal();
loaded = _root.getBytesLoaded();
load = int(loaded/total*100);
loadtxt = load+"%";
_root.进度条.gotoAndStop(load);
这是关于flash刚开始的loading制作的一组代码，是第一帧上面的
第二帧是：if (loaded == total) {
gotoAndStop(6);
} else {
gotoAndPlay("play");
}

以上三组代码，请详细解释一下，比如说每个英文是什么用途之类的，太简单的就不要说了。我也懂。主要是语法，还有意思。

回答的满意加分！
最好在两天之内给我答复！谢谢

自己也不是很懂得人，就不要过来了，谢谢

Answer 1

var sceneWidth =550;//定义场景的宽
var sceneHeight=400;//定义场景的高
var sideDisWidth = Stage.width/2-sceneWidth/2;//定义变量,雪花的横向位移范围
var sideDisHeight = Stage.height/2-sceneHeight/2;//定义变量,雪花的纵向位移范围
var snowNum = 150;//定义雪花的数量
var snowSpace:MovieClip = _root.createEmptyMovieClip("room", 1);//声明一个空影片剪辑snowSpace.

function addMasker() {//声明addMasker函数,执行两项工作.1是画外边框,2是画雪花景
_root.createEmptyMovieClip("masker", -2);//创建空影片剪辑masker，层深-2.任务是为舞台画外边框,并填充颜色
with (masker) {//设置masker的属性。
lineStyle(1, 0xcccccc, 100);//设置线条颜色
beginFill(0x000000, 0);//绘制矩形闭合路径，并填充灰色,透明度为0．
moveTo(sideDisWidth, sideDisHeight);//绘制起点
lineTo(sideDisWidth+sceneWidth, sideDisHeight);//绘制的右上角点的位置
lineTo(sideDisWidth+sceneWidth, sideDisHeight+sceneHeight);//绘制的右下角点的位置
lineTo(sideDisWidth, sideDisHeight+sceneHeight);//绘制的左下角点的位置
lineTo(sideDisWidth, sideDisHeight);//绘制的左上角点的位置
endFill();//结束绘制
}
createSnow();
}

function createSnow() {//定义一个匿名函数，完成声明一个雪花MC,雪花半径,循环画雪花
var n = 0;//局部变量n=0
while (n<snowNum) {//在0到150数量范围循环画雪花
var snow:MovieClip = snowSpace.createEmptyMovieClip("s"+n, n);//声明snowSpace剪辑由"s"+n个snow组成
var radius:Number = Math.random()*3;//定义雪花半径大小
drawSnow(snow, radius);//把snow, radius把参数传递给drawSnow函数
n++;
}
}

function drawSnow(snow:MovieClip, radius:Number) {//定义一个匿名函数，画一个雪花
var p = radius*.9;//局部变量P,用来定义雪花大小的坐标值
with (snow) {//设置snow这个对象的动作.画雪花圆形白色填充
colors = [0xCCCCCC, 0xFFFFFF];//设置雪花的颜色
alphas = [100, 100];//设置透明度
ratios = [0, 255];//采样处的宽度的百分比
matrix = {matrixType:"box", x:-Math.random()*2*radius, y:-Math.random()*2*radius, w:2*radius, h:2*radius, r:(90/180)*Math.PI};//一个变形矩阵
beginGradientFill("radial", colors, alphas, ratios, matrix);// 设置填充色.
curveTo(p, -p, radius, 0);//定义点坐标,画雪花
curveTo(p, p, 0, radius);
curveTo(-p, p, -radius, 0);
curveTo(-p, -p, 0, -radius);
endFill();//结束
}
snowProperty(snow, sceneWidth, sceneHeight);//把参数传递给snowProperty
}

function snowProperty(snow, w, h) {//定义一个匿名函数，一个雪花如何下降
snow._x = sideDisWidth+Math.random()*w;//根据可编辑的宽及0和1中的任意一个数乘雪花宽计算雪花的X轴起始位置
snow._y = sideDisHeight+Math.random()*h;//根据可编辑的高及0和1中的任意一个数乘雪花高计算雪花的Y轴起始位置
snow._rotation = Math.random()*120+30;//设置旋转角度.有立体感.雪花的旋转程度为0和1中的任意一个数乘120+30
snow.stepX = Math.cos((snow._rotation*Math.PI)/180);//雪花横向位移.用计算余弦(旋转角度*常数3.14)/180)
snow.stepY = Math.random()*2+1;//雪花纵向位移.为0和1中的任意一个数*2-1
setInterval(snowFall, 30, snow); //每隔0.5秒调用一次,由snowFall完成
}

function snowFall(snow) {//定义一个匿名函数，该函数为大雪花降落位移范围
snow._x += snow.stepX;//横向下落位移
snow._y += snow.stepY;//纵向下落位移
if (snow._x<sideDisWidth) {//如果横向位移不超出sideDisWidth值
snow._x = sideDisWidth+sceneWidth;//为雪花的横坐标附值
}
if (snow._x>sideDisWidth+sceneWidth) { //如果雪花的横向坐标大于所附的值
snow._x = sideDisWidth; //横向位移再回到初始点
}
if (snow._y>sideDisHeight+sceneHeight) {//如果雪花的纵向坐标大于所附的值
snow._y = sideDisHeight;//纵向位移再回到初始点
}
}
addMasker();