Question

如何将ASP网页生成HTML网页？

如题
希望有成熟的代码可以供我参考

Answer 1

以下代码就是将一个ASP的动态页面生成一个HTML的静态页面，注释我已经加上了，自己看吧。

FileName = "Index"&Item_Classid&".htm"
FilePath = Server.MapPath("/")&"\"&FileName
Html_Temp = Html_Temp&FilePath&"</LI>"
以上代码是在建立最终生成静态文件的名称和路径。

Do_Url = "http://"
Do_Url = Do_Url&Request.ServerVariables("SERVER_NAME")&"/detail.asp"
Do_Url = Do_Url&"?Item_Classid="&Item_Classid
strUrl = Do_Url
以上代码是通过拼写Do_Url字符串来获得你所传递过来的文件路径和参数，并最终附值到strUrl变量中。

dim objXmlHttp
set objXmlHttp = Server.CreateObject("Microsoft.XMLHTTP")
objXmlHttp.open "GET",strUrl,false
objXmlHttp.send()
以上这段代码是在通过你所传递过来的strUrl解析该页面中的HTML代码；关键是这句（objXmlHttp.open "GET",strUrl,false ）。

Dim binFileData
binFileData = objXmlHttp.responseBody
以上代码是将解析好的HTML代码附到binFileData中

Dim objAdoStream
set objAdoStream = Server.CreateObject("ADODB.Stream")
objAdoStream.Type = 1
objAdoStream.Open()
objAdoStream.Write(binFileData)
objAdoStream.SaveToFile FilePath,2
objAdoStream.Close()

以上这段代码是建立一个文件对象，将所拥有HTML代码的变量binFileData写到该文件中。

Html_Temp = Html_Temp&"<UL>"
Response.Write Html_Temp
Response.Write ( "<BR>" )
Response.Write ( "成功生成文件：" )
以上几句就不用我解释了。。。。：）

其实上面这个做法并不是很科学，还可以将代码更完善些。建议你将这个步骤封装到两个FUNCTION中，这样比较清晰并且方便重复调用，

CreateFile：用于建立生成的静态文件，其中调用GetUrlText进行脚本解析。

Function CreateFile(fileName，url)
Dim fs,fname
Set fs = Server.CreateObject("Scripting.FileSystemObject")
Set fname = fs.CreateTextFile(FileName, True)
fname.Write GetUrlText(url)
fname.Close
Set fname = Nothing
Set fs = Nothing
End Function

GetUrlText：用语解析传递回来的ASP页面

Function GetUrlText(url)
Dim xmlHttp
Set xmlHttp = server.createobject("MSXML2.ServerXMLHTTP")
xmlHttp.setTimeouts 10000,10000,10000,30000
xmlHttp.Open "GET",url, False
xmlhttp.setRequestHeader "CONTENT-TYPE", "text/xml"
xmlHttp.Send
If xmlHttp.ReadyState = 4 Then
GetUrlText = xmlHttp.responseText
Else
GetUrlText = ""
End If
End Function

里面URL就是你传递过来的地址，而FileName就是生成文件的地址，你在调用时直接调用CreateFile，将FileName和URL传递过去就可以了，怎么样，是不是比上面的看起来清晰很多：）