Question

如何写一个批处理开机自动运行？

要求：
1、开机后自动以管理员身份运行CMD
2、在cmd里面运行C盘MF文件夹下的的MF.BAT文件
3、运行MF.BAT结束，自动删除C盘MF文件夹及里面的文件
4、所有结束以后自动删除此批处理，或者取消下次开机自动运行上述操作（意思就是第一次开机执行一次，以后开机不执行以上操作）
没有财富值，无法追问了，在此补充，第一段执行停在如下图

第二段执行如下图

3，我在打开的cmd中运行CD C:\MF
然后依次敲击SLPUtil64.exe clrmark 和SLPUtil64.exe setmark 21marker.bin都可以





Answer 1

复制这个批处理文件到 开始\程序\启动 文件夹里面，可以用以下代码将你要开机启动的批处理复制到启动文件夹：COPY "批处理的绝对路径" "%ALLUSERSPROFILE%\「开始」菜单\程序\启动\"！

Answer 2

完全自动以管理员身份运行，那个是不可能实现的，还是需要你去手动点击一下UAC窗口中的“是”按钮。
其它的倒都可以实现。需要写吗？

追问

UAC，我拉到最低了。你写下看，不行就得敲下回车

追答

UAC已经拉到最低，这就代表已经取消UAC功能了，那么貌似就没必要以管理员身份运行脚本了，不过这个提权代码我依旧写里面吧！

@echo off & title 开机运行一次指定脚本 By 依梦琴瑶

%1 echo 正在请求管理员权限。。。&&mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "RunOnceMF" /t REG_SZ /d "C:\RunOnceMF.bat" /f

(echo @echo off
echo %%1 echo 正在请求管理员权限。。。^&^&mshta vbscript:CreateObject^("Shell.Application"^).ShellExecute^("cmd.exe","/c %%~s0 ::","","runas",1^)^(window.close^)^&^&exit
echo call C:\MF\MF.BAT
echo cd /d %%~dp0
echo rd /s /q C:\MF
echo reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "RunOnceMF" /f
echo del /f /q %%0)>C:\RunOnceMF.bat
del /f /q %0

追问

此命令能开机打开CMD，但是不执行C:\MF\MF.BAT呢

追答

你的MF.BAT执行后处理了什么？
能否给一下它的代码，让我分析。

追问

SLPUtil64.exe clrmark
SLPUtil64.exe setmark 21marker.bin
MF.BAT里面就上面这2行
这些文件在C:\MF文件夹下
我手动已管理员打开CMD，能运行MF.BAT 文件

追答

OK，运行一下以下脚本代码，然后截图一下CMD窗口。

我看一下脚本的工作路径。

%1 echo 正在请求管理员权限。。。&&mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit
pause

追问

图一是第一段命令，停留位置，图二是第二段命令

追答

@echo off & title 开机运行一次指定脚本 By 依梦琴瑶

%1 echo 正在请求管理员权限。。。&&mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "RunOnceMF" /t REG_SZ /d "C:\RunOnceMF.bat" /f

(echo @echo off
echo %%1 echo 正在请求管理员权限。。。^&^&mshta vbscript:CreateObject^("Shell.Application"^).ShellExecute^("cmd.exe","/c %%~s0 ::","","runas",1^)^(window.close^)^&^&exit
echo cd /d C:\MF
echo call MF.BAT
echo cd /d %%~dp0
echo rd /s /q C:\MF
echo reg delete "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "RunOnceMF" /f
echo del /f /q %%0)>C:\RunOnceMF.bat
del /f /q %0

追问

此代码还是停在此界面

明天再弄吧

追答

我不知道你那为什么会这样，而我这边测试完全是正常的。

发现脚本在开机自动运行时不需要进行人为提权的干预，系统会自动提权，所以新的代码我只保留创建开机自启功能时的提权，以保证正常写入注册表，之后开机后的让它自己提权吧。

新的代码如下：

@echo off & title 开机运行一次指定脚本 By 依梦琴瑶

%1 echo 正在请求管理员权限。。。&&mshta vbscript:CreateObject("Shell.Application").ShellExecute("cmd.exe","/c %~s0 ::","","runas",1)(window.close)&&exit

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\RunOnce" /v "RunOnceMF" /t REG_SZ /d "%SystemRoot%\System32\cmd.exe /c \"cd /d C:\MF ^& call C:\MF\MF.BAT ^& cd /d .. ^& rd /s /q C:\MF ^& exit" /f

del /f /q %0