Question

易语言滚动字怎么写?求源码

就如小球刷点 公告栏那字 谁有源码 加分
还有就是下面那友情链接那字 源码 谢谢
有的发给我 我邮箱：jmswangzh@126.com
加分 谢谢

Answer 1

.版本 2

.子程序 __启动窗口_创建完毕

超级链接框1.类型 ＝ 1
超级链接框1.标题 ＝ “这里就是你想要的滚动文字,你可以自己修改成自己的” ' 你可以改为用HTTP读文件来自动读取网络文字,下面的地址也一样可以.
超级链接框1.Internet地址 ＝ “http://www.baidu.com”
时钟1.时钟周期 ＝ 100 ' 这里的时间能控制速度

.子程序 _时钟1_周期事件

超级链接框1.左边 ＝ 超级链接框1.左边 － 50 ' 这里的50可以修改为你想要的效果
.如果真 (超级链接框1.左边 ＜ －_启动窗口.左边)
超级链接框1.左边 ＝ _启动窗口.左边
.如果真结束

另外在帮你写一个鼠标停留在公告上时公告停止滚动的代码:

.版本 2

.子程序 _超级链接框1_鼠标位置被移动, 逻辑型
.参数 横向位置, 整数型
.参数 纵向位置, 整数型
.参数 功能键状态, 整数型
.局部变量 超级链接坐标, 坐标_
.局部变量 鼠标坐标, 坐标_

取鼠标位置_ (鼠标坐标)
超级链接坐标.横向位置 ＝ 0
超级链接坐标.纵向位置 ＝ 0
取窗口区域位置_ (超级链接框1.取窗口句柄 (), 超级链接坐标)
.判断开始 (鼠标坐标.横向位置 ＜ 超级链接坐标.横向位置 ＋ 超级链接框1.宽度 且 鼠标坐标.横向位置 ＞ 超级链接坐标.横向位置)
.判断开始 (鼠标坐标.纵向位置 ＜ 超级链接坐标.纵向位置 ＋ 超级链接框1.高度 且 鼠标坐标.纵向位置 ＞ 超级链接坐标.纵向位置)
时钟1.时钟周期 ＝ 0
.默认
时钟1.时钟周期 ＝ 500
.判断结束

.默认
时钟1.时钟周期 ＝ 500
.判断结束

.版本 2

.DLL命令 取鼠标位置_, 整数型, "user32", "GetCursorPos", , ,
.参数 位置, 坐标_

.DLL命令 取窗口区域位置_, 整数型, "user32.dll", "ClientToScreen", , , 非零表示成功，零表示失败
.参数 窗口句柄, 整数型, , hwnd，要取出区域坐标的窗口句柄
.参数 位置变量, 坐标_, , lpPoint，参见相关帮助
.版本 2

.数据类型 坐标_, , , POINTAPI
.成员 横向位置, 整数型, , , x，横向位置
.成员 纵向位置, 整数型, , , y，纵向位置

Answer 2

楼上正解 带走2分