Question

易语言怎么做像tencent://?的东西

Answer 1

.版本 2
.程序集 窗口程序集_启动窗口
.子程序 __启动窗口_创建完毕
编辑框1.内容 ＝ 取URL协议命令 ()

.子程序 取URL协议命令, 文本型, 公开, 成功返回协议传递的命令文本，失败返回空文本。
.局部变量 C, 文本型, , "0"
.局部变量 n, 整数型
.局部变量 B, 文本型
取命令行 (C)
.计次循环首 (取数组成员数 (C), n)
    B ＝ B ＋ C [n] ＋ #换行符
.计次循环尾 ()
返回 (B)

.子程序 注册URL协议, 逻辑型, 公开, 成功返回真，失败返回假。注：有时失败是因为没有管理员权限。
.参数 协议名, 文本型, , 触发程序的协议头，例如："Tencent://Message/"其中的 Tencent
.参数 程序路径, 文本型, , 被协议头触发的程序的路径，例如：E:\QQ.exe
.如果真 (写注册项 (#根类, 协议名 ＋ “\”, 协议名 ＋ “ Protocol”) ＝ 假)
    返回 (假)
.如果真结束
.如果真 (写注册项 (#根类, 协议名 ＋ “\URL Protocol”, 程序路径) ＝ 假)
    返回 (假)
.如果真结束
.如果真 (写注册项 (#根类, 协议名 ＋ “\Shell\Open\Command\”, #引号 ＋ 程序路径 ＋ #引号 ＋ “ ” ＋ #引号 ＋ “%1” ＋ #引号) ＝ 假)
    返回 (假)
.如果真结束
返回 (真)
.子程序 注销URL协议, 逻辑型, 公开, 成功返回真，失败返回假。注：有时失败是因为没有管理员权限。
.参数 协议名, 文本型, , 触发程序的协议头，例如："Tencent://Message/"其中的 Tencent
.如果真 (删除注册项 (#根类, 协议名 ＋ “\Shell\Open\Command”) ＝ 假)
    返回 (假)
.如果真结束
.如果真 (删除注册项 (#根类, 协议名 ＋ “\Shell\Open”) ＝ 假)
    返回 (假)
.如果真结束
.如果真 (删除注册项 (#根类, 协议名 ＋ “\Shell”) ＝ 假)
    返回 (假)
.如果真结束
.如果真 (删除注册项 (#根类, 协议名) ＝ 假)
    返回 (假)
.如果真结束
返回 (真)
.子程序 _按钮1_被单击
注册URL协议 (“Benhao”, 取运行目录 () ＋ “\” ＋ 取执行文件名 ())

.子程序 _按钮2_被单击
注销URL协议 (“Benhao”)