Question

asp中如何去掉一段字符串中的标签？

在页面上获得一段字符串，里面包含大量的标签（如<DIV>、<b>、<u>、<font>等），如何才能用最简单的方法就将这些标签去掉？
是完全去掉，不是光去掉<和>。

Answer 1

使用正则表达式替换

html = RemoveTags(html)

public function RemoveTags(byval str)
dim re
set re = new RegExp
re.IgnoreCase = true
re.Global = true
re.Pattern = "(\<\/?[^\<]*\>)"
RemoveTags = re.Replace(str, "")
set re = nothing
end function

Answer 2

这种的话，就用DW里的替换吧，这样就是最快速 的了。

Answer 3

<%
Function RemoveHTML(strHTML)
Dim objRegExp, Match, Matches
Set objRegExp = New Regexp
objRegExp.IgnoreCase = True
objRegExp.Global = True
'取闭合的<>
objRegExp.Pattern = "<.+?>"
'进行匹配
Set Matches = objRegExp.Execute(strHTML)
' 遍历匹配集合，并替换掉匹配的项目
For Each Match in Matches
strHtml=Replace(strHTML,Match.Value,"")
Next
RemoveHTML=strHTML
Set objRegExp = Nothing
End Function
'调用
str=RemoveHTML(str)
%>

本文来自CSDN博客，转载请标明出处：http://blog.csdn.net/qingflyer/archive/2009/03/20/4007901.aspx

Answer 4

'移除字符串的HTML代码
Public Function RemoveHTML(strHTML)
Dim objRegExp, Match, Matches
Set objRegExp = New Regexp

objRegExp.IgnoreCase = True
objRegExp.Global = True
'取闭合的<>
objRegExp.Pattern = "<.+?>"
'进行匹配
Set Matches = objRegExp.Execute(strHTML)

' 遍历匹配集合，并替换掉匹配的项目
For Each Match in Matches
strHtml=Replace(strHTML,Match.Value,"")
Next
RemoveHTML=trim(Replace(strHTML,VbCrLf,""))
Set objRegExp = Nothing
End Function