系统文件夹无法隐藏。有高分求助!!!!!

用完360急救箱就成这样了。试过在文件夹选项中隐藏过了。可以没用。求解。。。下图是XP系统的。我windows7中也有两个文件夹这样了。隐藏键一直灰色。求解。有加分!如果... 用完360急救箱就成这样了。试过在文件夹选项中隐藏过了。可以没用。求解。。。下图是XP系统的。我windows 7 中也有两个文件夹这样了。隐藏键一直灰色。求解。有加分!如果可以的话请留下QQ。谢谢。
XP的有效。WIN7无效!我试了半天也米用啊!!!!
展开
 我来答
yangleihunan
2010-07-23 · TA获得超过349个赞
知道小有建树答主
回答量:190
采纳率:100%
帮助的人:173万
展开全部
这是因为如果他们有系统属性就无法右键属性设置他们的隐藏属性.

我写的这个批处理可以修改磁盘或文件或文件夹内所有文件的系统属性和隐藏属性,很方便的.

将以下内容复制到记事本,另存为"修改系统属性和隐藏属性.bat"(注意加引号).

用的时候,把要修改属性的磁盘或文件或文件夹,拖到批处理文件的图标上(可以拖很多),然后按提示操作就行了.

注意:请把要更改属性的磁盘或文件或文件夹拖到批处理文件图标内,不要双击运行此批理.

@echo off
setlocal enabledelayedexpansion
title 修改系统属性和隐藏属性
color f0
mode con: cols=50 lines=25
if "%~1"=="" (
echo 你没有拖入任何磁盘或文件或文件夹
echo 请把要处理的磁盘或文件或文件夹拖到批处理文件图标
echo 不要双击启动批处理
pause
)
:loop
cls
if "%~1"=="" goto :eof
if not exist "%~1" (echo 路径不存在)&pause&shift&goto loop
echo 当前处理的磁盘或文件或文件夹:
echo %~1
echo.
echo 请选择要进行的操作,然后按回车
echo.
echo 加系统和隐藏属性……………………………1
echo 减系统和隐藏属性……………………………2
echo 不处理…………………………………………3
echo.
set /p "c1=选择 (1,2,3) (不输入为!c1!,默认为2):"
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-"
set "a=%~a1"
if /i "!a:~0,1!"=="d" (
echo.
echo 这是一个文件夹,请选择要进行的操作,然后按回车
echo.
echo 只对该文件夹本身……………………………1
echo 只对该文件夹中的文件夹和文件……………2
echo 对该目录下的一切的文件夹和文件…………3
echo.
set /p "c2=选择 (1,2,3) (不输入为!c2!,默认为1):"
if "!c2!"=="2" (
pushd "%~1"
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i"
popd
) else if "!c2!"=="3" (
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i"
) else (
attrib.exe !d!s !d!h "%~1"
)
) else (
attrib.exe !d!s !d!h "%~1"
)
pause&shift&goto loop
百度网友c6131b5
2010-07-23 · TA获得超过373个赞
知道小有建树答主
回答量:201
采纳率:0%
帮助的人:61.9万
展开全部
这个一般可以通过修改注册表实现 ,不过 使用批处理也可以达到效果 ,但是呢 ,楼主的这个例子举的不凑巧,boot是系统启动的相关配置文件,一般是隐藏的 ,不允许用户修改 ,所以就不能修改属性了 ,
@echo off
setlocal enabledelayedexpansion
title 修改系统属性和隐藏属性
color f0
mode con: cols=50 lines=25
if "%~1"=="" (
echo 你没有拖入任何磁盘或文件或文件夹
echo 请把要处理的磁盘或文件或文件夹拖到批处理文件图标
echo 不要双击启动批处理
pause
)
:loop
cls
if "%~1"=="" goto :eof
if not exist "%~1" (echo 路径不存在)&pause&shift&goto loop
echo 当前处理的磁盘或文件或文件夹:
echo %~1
echo.
echo 请选择要进行的操作,然后按回车
echo.
echo 加系统和隐藏属性……………………………1
echo 减系统和隐藏属性……………………………2
echo 不处理…………………………………………3
echo.
set /p "c1=选择 (1,2,3) (不输入为!c1!,默认为2):"
if "!c1!"=="1" (set "d=+") else if "!c1!"=="3" (pause&shift&goto loop) else set "d=-"
set "a=%~a1"
if /i "!a:~0,1!"=="d" (
echo.
echo 这是一个文件夹,请选择要进行的操作,然后按回车
echo.
echo 只对该文件夹本身……………………………1
echo 只对该文件夹中的文件夹和文件……………2
echo 对该目录下的一切的文件夹和文件…………3
echo.
set /p "c2=选择 (1,2,3) (不输入为!c2!,默认为1):"
if "!c2!"=="2" (
pushd "%~1"
for /f "delims=" %%i in ('dir /a /b "%~1"') do attrib.exe !d!s !d!h "%%i"
popd
) else if "!c2!"=="3" (
for /f "delims=" %%i in ('dir /a /b /s "%~1"') do attrib.exe !d!s !d!h "%%i"
) else (
attrib.exe !d!s !d!h "%~1"
)
) else (
attrib.exe !d!s !d!h "%~1"
)
pause&shift&goto loop
已赞过 已踩过<
你对这个回答的评价是?
评论 收起
推荐律师服务: 若未解决您的问题,请您详细描述您的问题,通过百度律临进行免费专业咨询

为你推荐:

下载百度知道APP,抢鲜体验
使用百度知道APP,立即抢鲜体验。你的手机镜头里或许有别人想知道的答案。
扫描二维码下载
×

类别

我们会通过消息、邮箱等方式尽快将举报结果通知您。

说明

0/200

提交
取消

辅 助

模 式