Question

VB ，窗体最大化放大后，里面的控件不会跟着改变位置，如何才能让控件跟着变？

VB ，窗体最大化放大后，里面的控件不会跟着改变位置，如何才能让控件跟着变？
比如说一个文本框，本来是占窗体的一半的面积， 而如何 做到窗体放大后仍旧占一半面积
我用的VB6.0 ，anchor 属性？找不到

Answer 1

常用的办法是在Form_Resize()里面写代码设定喽！

如：
Private Sub Form_Resize()
On Error Resume Next
'''数字可以更改，仅供参考
text1.width=Me.width - 2 * Me.left '''文本框仍旧居中，且改变了大小
text1.Refresh '''刷新显示文本框

......
End Sub

此外，可以使用第三方控件来实现，你可以百度搜搜看有无相关免费控件下载。

Answer 2

楼主该放弃VB6啦。

用VB2008或Express吧，真正的面向对象程序设计，开发windows程序，效率比VB6高不知多少倍。

anchor就是VB2008里的一个属性，用于控制控件的上下左右位置。可通过该属性实现控件随窗口的同步缩放。

我今年刚从VB6升级到2008，经历了阵痛后现在感觉真爽。

Answer 3

设置控件有Anchor属性，让上下左右都驻在窗体上。

Answer 4

据我的经验是该在Form_Resize里写，最好在Form_Paint里再调一下，有时候Form_Resize会有些问题

Answer 5

只需要在窗体中加入如下代码：

Private FormOldWidth As Long
'原始宽度
Private FormOldHeight As Long
'原始高度

'在调用ResizeForm前先调用本函数
Public Sub ResizeInit(FormName As Form)
Dim Obj As Control
FormOldWidth = FormName.ScaleWidth
FormOldHeight = FormName.ScaleHeight
On Error Resume Next
For Each Obj In FormName
Obj.Tag = Obj.Left & " " & Obj.Top & " " & Obj.Width & " " & Obj.Height & " "
Next Obj
On Error GoTo 0
End Sub

'按比例改变表单内各元件的大小，
'在调用ReSizeForm前先调用ReSizeInit函数
Public Sub ResizeForm(FormName As Form)
Dim Pos(4) As Double
Dim i As Long, TempPos As Long, StartPos As Long
Dim Obj As Control
Dim ScaleX As Double, ScaleY As Double

ScaleX = FormName.ScaleWidth / FormOldWidth
'保存窗体宽度缩放比例
ScaleY = FormName.ScaleHeight / FormOldHeight
'保存窗体高度缩放比例
On Error Resume Next
For Each Obj In FormName
StartPos = 1
For i = 0 To 4
'读取控件的原始位置与大小

TempPos = InStr(StartPos, Obj.Tag, " ", vbTextCompare)
If TempPos > 0 Then
Pos(i) = Mid(Obj.Tag, StartPos, TempPos - StartPos)
StartPos = TempPos + 1
Else
Pos(i) = 0
End If
'根据控件的原始位置及窗体改变大小
'的比例对控件重新定位与改变大小
Obj.Move Pos(0) * ScaleX, Pos(1) * ScaleY, Pos(2) * ScaleX, Pos(3) * ScaleY
Next i
Next Obj
On Error GoTo 0
End Sub

Private Sub Form_Load()
Call ResizeInit(Me) '在装入时必须加入
End Sub

Private Sub Form_Resize()
Call ResizeForm(Me) '控件随之改变
End Sub
更多vb代码请参阅我的博客http://hi.baidu.com/zgmg/