Question

易语言自动喊话

易语言怎么实现自动喊话，谁教教我

Answer 1

以下是成品软件源码。 其实简单的说自动喊话也就是利用了时钟。时钟周期下使用 置剪辑板文本（） 模拟按键 这两个命令来实现的，如果你喜欢易语言，可以加入我们的菜鸟交流群。大家一起学习易语言。

.版本 2
.支持库 iext
.支持库 spec

.程序集 窗口程序集
.程序集变量 骂人文本, 文本型
.程序集变量 开始热键ID, 整数型
.程序集变量 停止热键ID, 整数型
.程序集变量 初始化骂人文本, 文本型
.程序集变量 初始化文本分割, 文本型, , "0"

.子程序 __启动窗口_创建完毕

置托盘图标 (#图标, “智软-半自动骂人”)
更换新皮肤 (16)
初始化 ()
读取真假 ()
_选择框1_被单击 ()
.如果真 (文件是否存在 (取运行目录 () ＋ “\配置”) ＝ 假)
创建目录 (取运行目录 () ＋ “\配置”)
.如果真结束
开始热键ID ＝ 窗口_热键注册 (取窗口句柄 (), , #Home键, &_按钮_开始_被单击)
停止热键ID ＝ 窗口_热键注册 (取窗口句柄 (), , #End键, &_按钮_停止_被单击)
读入骂人文本 ()
状态条1.置文本 (1, “停止”)

.子程序 _关于_被选择

载入 (窗口_关于, _启动窗口, 真)

.子程序 _自定义骂人内容_被选择
.局部变量 文件号, 整数型

信息框 (“ 自定义骂人文本须知” ＋ #换行符 ＋ “自定义骂人文本必须是每行一句骂人的话，否则程序会出错...” ＋ #换行符 ＋ “你可以通过导入骂人文本，或者修改软件目录下的‘ZRWB.ini'的内容！然后重新启动软件即可”, #信息图标, “小星提示你”)
通用对话框1.过滤器 ＝ “骂人文本.格式” ＋ #左引号 ＋ “txt” ＋ #右引号 ＋ “|*.txt”
.如果真 (通用对话框1.打开 ())
文件号 ＝ 打开文件 (通用对话框1.文件名, , )
.如果真 (文件号 ＞ 0)
骂人文本 ＝ 读入文本 (文件号, )
.如果真结束
关闭文件 (文件号)
.如果真结束
调试输出 (骂人文本)
.如果真 (骂人文本 ≠ “”)
写到文件 (取运行目录 () ＋ “\配置\ZRWB.ini”, 到字节集 (骂人文本))
.如果真结束

.子程序 _使用方法_被选择

载入 (窗口_帮助, _启动窗口, 真)

.子程序 _一_被选择

更换新皮肤 (2, )

.子程序 _还原_被选择

更换新皮肤 (16)

.子程序 _二_被选择

更换新皮肤 (4, )

.子程序 _三_被选择

更换新皮肤 (6, )

.子程序 _四_被选择

更换新皮肤 (7, )

.子程序 _五_被选择

更换新皮肤 (11)

.子程序 _选择框1_被单击

.判断开始 (选择框1.选中 ＝ 真)
_启动窗口.总在最前 ＝ 真
写到文件 (取运行目录 () ＋ “\配置\zj.ini”, 到字节集 (“真”))
.默认
_启动窗口.总在最前 ＝ 假
写到文件 (取运行目录 () ＋ “\配置\zj.ini”, 到字节集 (“假”))
.判断结束

.子程序 __启动窗口_将被销毁

窗口_热键卸载所有 ()
写到文件 (取运行目录 () ＋ “\配置\wz.ini”, 到字节集 (到文本 (_启动窗口.左边) ＋ “-” ＋ 到文本 (_启动窗口.顶边)))
_选择框1_被单击 ()

.子程序 _按钮_开始_被单击

时钟1.时钟周期 ＝ 到数值 (编辑框2.内容) × 1000 － 200
状态条1.置文本 (1, “运行中”)

.子程序 _按钮_停止_被单击

时钟1.时钟周期 ＝ 0
状态条1.置文本 (1, “停止”)

.子程序 初始化
.局部变量 文件号, 整数型
.局部变量 位置, 文本型
.局部变量 分割文本, 文本型, , "0"

文件号 ＝ 打开文件 (取运行目录 () ＋ “\配置\wz.ini”, , )
.如果真 (文件号 ＞ 0)
位置 ＝ 读入文本 (文件号, )
关闭文件 (文件号)
.如果真结束
调试输出 (位置)
分割文本 ＝ 分割文本 (位置, “-”, )
.如果真 (取数组成员数 (分割文本) ＝ 2)
_启动窗口.左边 ＝ 到数值 (分割文本 [1])
_启动窗口.顶边 ＝ 到数值 (分割文本 [2])
.如果真结束

.子程序 读取真假
.局部变量 文件号, 整数型
.局部变量 是否, 文本型

文件号 ＝ 打开文件 (取运行目录 () ＋ “\配置\真假.ini”, , )
.如果真 (文件号 ≠ 0)
是否 ＝ 读入文本 (文件号, )
关闭文件 (文件号)
.如果真结束
.如果 (是否 ＝ “真”)
选择框1.选中 ＝ 真
.否则
选择框1.选中 ＝ 假
.如果结束

.子程序 读入骂人文本
.局部变量 文件号, 整数型

文件号 ＝ 打开文件 (取运行目录 () ＋ “\配置\ZRWB.ini”, , )
.如果真 (文件号 ＝ 0)
信息框 (“对不起，您损坏了骂人数据”, 0, )
返回 ()
.如果真结束
初始化骂人文本 ＝ 读入文本 (文件号, )
初始化文本分割 ＝ 分割文本 (初始化骂人文本, #换行符, )

.子程序 _时钟1_周期事件
.局部变量 次数, 整数型, 静态
.局部变量 n, 整数型, 静态

次数 ＝ 取数组成员数 (初始化文本分割)
.如果真 (n ≥ 次数)
n ＝ 0
.如果真结束
n ＝ n ＋ 1
置剪辑板文本 (初始化文本分割 [n])
编辑框1.内容 ＝ 初始化文本分割 [n]
按键2 (#Ctrl键, #按下_, )
延迟 (100)
按键2 (#V键)
延迟 (100)
按键2 (#Ctrl键, #放开_, )
延迟 (100)
按键2 (#回车键)

.子程序 _时钟2_周期事件

状态条1.置文本 (2, 到文本 (取现行时间 ()))

.子程序 __启动窗口_托盘事件
.参数 操作类型, 整数型

.如果真 (操作类型 ＝ 2)
_启动窗口.可视 ＝ 真
.如果真结束
.如果真 (操作类型 ＝ 3)
弹出菜单 (托盘菜单, 取鼠标水平位置 (), 取鼠标垂直位置 ())
.如果真结束
.如果真 (操作类型 ＝ 1)
弹出菜单 (打开菜单, 取鼠标水平位置 (), 取鼠标垂直位置 ())
.如果真结束

.子程序 __启动窗口_可否被关闭, 逻辑型

_启动窗口.可视 ＝ 假
返回 (假)

.子程序 _退出_被选择

销毁 ()

.子程序 _打开_被选择

_启动窗口.可视 ＝ 真

Answer 2

按键精灵不是自带一个脚步么，有这功能，自己找吧

Answer 3

喊什么？