Question

VBA中 可否实现 让txt中的文档内容，替换到word的标签中去

如果可以实现，可否举个例子

Answer 1

下面是代码是我应用中的一个过程，可以作为例子供你参考：

'★★★★自动生成提示书文件★★★★
Sub 生成提示书WORD文件()
  '变量定义
  Dim i, j, h, p, n, st
  Set st = GetSheet("提示书用表")
  If st Is Nothing Then Exit Sub
  st.Activate
  h = 9 '标题行
  n = Trim(st.Cells(3, 2).Value)
  If Not FileExist(n) Then
    MsgBox "模板文件（" & n & "）不存在！"
    Exit Sub
  End If
  p = InStrRev(n, "\")
  If p = 0 Then p = "" Else p = Left(n, p)
  Dim WordApp As Object
  '开始启动WORD进程
  Set WordApp = CreateObject("Word.Application")
  i = h + 1
  While st.Cells(i, 1) <> ""
    WordApp.Documents.Add
    WordApp.Selection.InsertFile Filename:=n
    For j = 1 To st.UsedRange.Columns.Count
    If st.Cells(h, j) <> "" Then
      With WordApp.Selection.Find
        .Text = "<<" & st.Cells(h, j) & ">>"
        .Replacement.Text = st.Cells(i, j).Text
        .Forward = True
        .Format = False
        .MatchCase = False
        .MatchWholeWord = False
        .MatchByte = True
        .MatchWildcards = False
        .MatchSoundsLike = False
        .MatchAllWordForms = False
        .Wrap = 1 'wdFindContinue
        .Execute Replace:=2 'wdReplaceAll
      End With
    End If
    Next j
    WordApp.ActiveDocument.SaveAs Filename:=p & st.Cells(i, 1).Text & ".doc", FileFormat:=0 'wdFormatDocument
    WordApp.ActiveDocument.Close
    i = i + 1
  Wend
  WordApp.Quit '退出
  Set WordApp = Nothing '取消变量
  MsgBox "全部文件生成完毕（" & p & "）！"
End Sub

此代码是EXCEL中的VBA，打开一个WORD模板文件，把里面所有的标签按表格内容进行替换，然后生成表格里面指定的名字的文件。

追问

。。。。。
我的意思是 把1.txt文档中的内容 复制到 word标签中，excel的我参考不了。。。

追答

你说说你遇到的具体问题是什么吧，1.txt文件内容取出来会不会（提示使用FSO）？内容插入到WORD里面或者替换标签会不会（可以录制宏来参考）？

追问

就是全选1.txt 中的内容，然后讲内容替换到word标签中去。
把excel中的数值 替换到word标签中去 我会，但是txt我就不会了
FSO 表示不会用。。。

追答

VBA利用FSO读取TXT文件的例子代码：

    Dim strLine, FileObj, TextObj
    Set FileObj = CreateObject("Scripting.FileSystemObject")
    Set TextObj = FileObj.OpenTextFile("1.txt", 1, False) '1=ForReading, false=不创建文件
    While Not TextObj.AtEndOfStream
        strLine = TextObj.ReadLine '读一行
        msgbox strLine
    WEnd
    TextObj.Close