Question

高手们帮忙写个IP切换批处理文件

由于经常要切换IP，请高手们帮忙写个IP切换批处理文件：
有三个IP需要常切换
1、网管1：IP:10.175.126.68 子网：255.0.0.0 网关：空
2、网管2：IP：10.178.61.183 子网：255.255.255.224 网关：10.178.61.161
3、网管3：IP:10.178.61.23 子网：255.0.0.0 网关：空

效果：执行批处理文件后，有3个选项，选择了哪一个就切换到哪一个IP上。

只有50分，求助，万分感谢！

Answer 1

效果：执行批处理文件后，有3个选项，选择了哪一个就切换到哪一个IP上。

@echo off
cls
:start
echo.
echo             ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo             请选择要进行的操作，然后按回车
echo             ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
echo.
echo    1   网管1
echo    2   网管2
echo    3   网管3
echo.
set choice=
set /p choice=   请输入选项（Enter确认）:

if /i "%choice%"=="1" goto ips1
if /i "%choice%"=="2" goto ips2
if /i "%choice%"=="3" goto ips3

:ips1
netsh interface ipv4 set address "本地连接" static 10.175.126.68 255.0.0.0
pause
Goto start


:ips2
netsh interface ipv4 set address "本地连接" static 10.178.61.183 255.255.255.224 10.178.61.161
pause
Goto start

:ips3
netsh interface ipv4 set address "本地连接" static 10.178.61.23 255.0.0.0
pause
Goto start

Answer 2

@echo off
color 5f
:main
cls
echo. 

echo               IP快捷切换助手
echo              ================
echo               制作：qop_dob

echo.
echo ※选择您需要的网络参数设置___？
echo.
echo 1、网管1——IP：10.175.126.68  子网：255.0.0.0  网关：空
echo 2、网管2——IP：10.178.61.183  子网：255.255.255.224  网关：10.178.61.161
echo 3、网管3——IP：10.178.61.23  子网：255.0.0.0  网关：空
echo.
set choice=
set /p choice=请输入[序号+回车]:
if /i '%choice%'=='1' goto main1
if /i '%choice%'=='2' goto main2
if /i '%choice%'=='3' goto main3
cls
echo “%choice%”不是有效值，请重新输入！
echo.
pause
goto main

:main1 
netsh interface ip set address "本地连接" static 10.175.126.68 255.0.0.0
goto main4

:main2 
netsh interface ip set address "本地连接" static 10.178.61.183 255.255.255.224 10.178.61.161 1
goto main4

:main3 
netsh interface ip set address "本地连接" static 10.178.61.23 255.0.0.0
goto main4

:main4
for /l %%i in (5,-1,0) do (
cls
echo 设置完毕，窗口将在倒数%%i秒后自动关闭！请稍等。。。
ping 127.1 -n 2 >nul
)
exit