Question

易语言把快捷方式托到卷帘式菜单然后可以再里面打开？？？

RT实在是想不出来了求高手帮帮忙

Answer 1

使用拖放支持库来操作，通过拖放对象得到文件路径，具体代码如下：
（建议把代码复制到易语言中再看吧）
.版本 2
.支持库 edroptarget

.程序集 窗口程序集1
.程序集变量 文件名, 文本型, , , 这个是接收到的文件的路径存放变量

.子程序 __启动窗口_创建完毕

拖放对象1.注册拖放控件 (_启动窗口.取窗口句柄 ()) ' 这里的句柄为具体需要进行操作的对象，如果是卷帘菜单，可以改成卷帘菜单句柄，一般情况可以使用_启动窗口的句柄
拖放对象1.接收文件 ＝ 真 ' 拖放对象有4个接收属性，这里我们先设接收文件为真，也可以在属性框中进行修改，为了让你看的到，我直接写成代码了

.子程序 __启动窗口_将被销毁

拖放对象1.撤消拖放控件 (_启动窗口.取窗口句柄 ()) ' 这里的句柄与注册时的句柄相同，并且一定要在窗口销毁前执行此操作

.子程序 _拖放对象1_得到文件
.参数 接收到的文件路径, 文本型

文件名 ＝ 接收到的文件路径 ' 把接收到的路径保存到变量文件名中

================================================================
另外，我不太明白你的意思，我自己的理解是你想把快捷方式拖到卷帘菜单后在菜单中的到一个项目，包括快捷方式的图标和文件名。如果我理解不错的话，以上的回答只能帮助你得到路径，下面我把获取菜单的图标和文件名的思路说一下
========================取文件名代码============================
复制以下代码到易语言，将文件路径带入子程序，返回的就是文件名了
.版本 2

.子程序 取文件名, 文本型
.参数 路径文件名, 文本型
.局部变量 新文件名, 文本型

新文件名 ＝ 取文本中间 (路径文件名, 倒找文本 (路径文件名, “\”, , 假) ＋ 1, 倒找文本 (路径文件名, “.”, , 假) － 倒找文本 (路径文件名, “\”, , 假) － 1)
返回 (新文件名)

===========================全部代码=============================
.版本 2
.支持库 iext2
.支持库 edroptarget
.支持库 iext3

.程序集 窗口程序集1
.程序集变量 图片组, 字节集
.程序集变量 文件名, 文本型

.子程序 __启动窗口_创建完毕

图片组 ＝ 建空图片组 (32, 32) ' 其中的32和32是代表32像素*32像素的图片
拖放对象1.注册拖放控件 (卷帘式菜单1.取窗口句柄 ())

.子程序 __启动窗口_将被销毁

拖放对象1.撤消拖放控件 (卷帘式菜单1.取窗口句柄 ())

.子程序 _拖放对象1_得到文件
.参数 接收到的文件路径, 文本型

文件名 ＝ 接收到的文件路径
时钟1.时钟周期 ＝ 100

.子程序 _时钟1_周期事件
.局部变量 SS, 整数型

时钟1.时钟周期 ＝ 0
SS ＝ 提取加入图片 (图片组, 文件名, , )
卷帘式菜单1.项目图标图片组 ＝ 图片组
卷帘式菜单1.加入项目 (取文件名 (文件名), 0, 卷帘式菜单1.取项目数 (0), SS, )

.子程序 取文件名, 文本型
.参数 路径文件名, 文本型
.局部变量 新文件名, 文本型

新文件名 ＝ 取文本中间 (路径文件名, 倒找文本 (路径文件名, “\”, , 假) ＋ 1, 倒找文本 (路径文件名, “.”, , 假) － 倒找文本 (路径文件名, “\”, , 假) － 1)
返回 (新文件名)

复制以上代码到易语言中,注意此方法只能针对EXE文件，快捷方式只能获得文件名无法提取图标！
==================================================================
注:以上代码需要包括3个控件:卷帘菜单、时钟、拖放对象