Question

易语言怎样下载文件？

易语言怎样从网络上下载文件到电脑上，命令是什么？

最好有图或者源码，回答好的给加100分都行，很急！

Answer 1

易语言只自带一个bt下载支持库,直接下载没有命令,需要几个参数.图片代码在下面

组件:编辑框2个,超级按钮3个,标签3个,进度条1个,时钟1个.

代码:

.版本 2
.支持库 downlib
.支持库 iext2
.支持库 shell

.程序集 窗口程序集1
.程序集变量 下载参数, 任务参数
.程序集变量 下载任务, 下载对象
.程序集变量 下载状态, 整数型
.程序集变量 下载信息, 字节集
.程序集变量 文件大小, 双精度小数型

.子程序 __启动窗口_创建完毕



.子程序 _超级按钮_接收_被单击
.局部变量 下载地址, 文本型

.如果真 (编辑框1.内容 ＝ “”)
    信息框 (“没有输入下载地址”, 0, , )
    返回 ()
.如果真结束
.如果真 (编辑框2.内容 ＝ “”)
    信息框 (“没有选择保存途径”, 0, , )
    返回 ()
.如果真结束

下载地址 ＝ 删首尾空 (编辑框1.内容)
下载参数.类型 ＝ #传送常量.下载
下载参数.文件地址 ＝ 下载地址
下载参数.线程等待超时 ＝ 1000
下载参数.默认线程数 ＝ 3
下载参数.本地文件路径 ＝ 编辑框2.内容
下载参数.连接超时 ＝ 5000
下载参数.发送超时 ＝ 5001
下载参数.接收超时 ＝ 10000
下载参数.接收大小 ＝ 10240
下载参数.交互回调函数 ＝ &交互回调函数
超级按钮_接收.禁止 ＝ 真
下载任务.增加新任务 (下载参数)

.子程序 _超级按钮_浏览_被单击

编辑框2.内容 ＝ 浏览文件夹 (“选择本地保存途径”, )

.子程序 交互回调函数, 整数型
.参数 消息类型, 整数型
.参数 线程信息, 整数型
.参数 参数3, 整数型
.参数 参数4, 整数型
.参数 对象信息, 整数型

.判断开始 (消息类型 ＝ #传送常量.下载上传开始)
    文件大小 ＝ 参数3
.判断 (消息类型 ＝ #传送常量.下载上传结束)
    信息框 (“下载完成”, 0, )
    结束 ()
.判断 (消息类型 ＝ #传送常量.新下载线程启动)

.判断 (消息类型 ＝ #传送常量.下载线程继续下载)

.判断 (消息类型 ＝ #传送常量.线程正常结束)

.判断 (消息类型 ＝ #传送常量.线程异常结束)

.判断 (消息类型 ＝ #传送常量.存在同名文件)

.判断 (消息类型 ＝ #传送常量.收到数据)

.判断 (消息类型 ＝ #传送常量.下载数据范围)

.默认

.判断结束
返回 (0)


.子程序 _时钟_周期事件

.如果真 (超级按钮_接收.禁止 ＝ 真)
    .如果 (文件大小 ＝ 0)
        标签.标题 ＝ “已完成：0%”
    .否则
        标签.标题 ＝ “已完成：” ＋ 数值到格式文本 (下载任务.取已下载长 () ÷ 文件大小 × 100, 0, 假) ＋ “%”
    .如果结束
    进度条.位置 ＝ 四舍五入 (下载任务.取已下载长 () ÷ 文件大小 × 100, 0)
.如果真结束


.子程序 _超级按钮_取消_被单击

下载参数.类型 ＝ #传送常量.下载上传结束
超级按钮_接收.禁止 ＝ 假
进度条.位置 ＝ 0
标签.标题 ＝ “用户取消”

Answer 2

我们以百度云客户端的直链为例，提取直链中BaiduYunGuanjia_5.3.6.exe的BaiduYunGuanjia_5.3.6的文本文字。

运行易语言，进入“新建工程”文件对话框，选择“Windows窗口程序”然后点击“确定”按钮，进入“Windows窗口程序”设计界面。

在启动窗口我们添加一个编辑框和按钮，便于一会便于展示提取出来的文本。

点击按钮进入窗口程序集界面，我们先添加精易模块V3.3,然后按Ctrl+L键创建一个变量，变量名：文件名，类型：文本型。

开始写源码，如下图，使用的是精易模块里的文本_取出中间文本，我们要取出直链里的文本。

然后我们再写一个命令，把提取出来的文件名放入编辑框中，来确认下提取的是不是正确。

完成后我们直接运行，点击按钮，看，我们需要的文件名直接出现在了编辑框里。

文件名提取是为了在不改名字的情况下，把下载的文件写入电脑，然后自动执行。有很多的扩展思路。

Answer 3

楼主看你这么诚意，我就跟你说吧，你去下载一个精易模块，里面有条命令， 文件_下载（）
，这样就可以从网络说下载文件啦！~
我说完了，楼主采纳吧~~么么哒。

追问

麻烦再清楚点呗，至少给发个模块嘛

追答

模块，百度提示我发送失败，如果没有发送成功，你去百度一下【精易模块】，模块命令是

文件_下载（）

Answer 4

下载的文件可以自定义的下载文件名，
给你写个简单的，有什么问题可以继续提问 ，尽力帮你完善！

Answer 5

用HTTP下载。网上有很多例子！