Question

怎样用VB编写简单的计算器程序？？

Answer 1

其实比较简单啦,用一个窗体就可以实现啦!
我自己写的,你可以看看
Option Explicit
Dim strNumber As String
Dim strPoint As String
Dim dblNum1 As Double
Dim intOperator As Integer
'清除结果
Private Sub cmdGT_Click()
txtDisplay.Text = "0."
strNumber = ""
strPoint = "."
intOperator = 7
End Sub
'输入数字
Private Sub cmdNumber_Click(Index As Integer)
strNumber = strNumber & cmdNumber(Index).Caption
txtDisplay.Text = strNumber & strPoint
End Sub

Private Sub cmdOnOff_Click()
End
End Sub
'运算过程
Private Sub cmdOperator_Click(Index As Integer)
Dim dblnum2 As Double
'是第一次单击运算符时，将输入的值先赋给第一个数，否则赋值给第二个数进行运算
If intOperator = 7 Then
dblNum1 = CDbl(txtDisplay.Text)
Else
dblnum2 = CDbl(Val(txtDisplay.Text))
'根据输入的符号进行运算
'求普通运算
Select Case intOperator
Case 0
dblNum1 = dblNum1 + dblnum2
Case 1
dblNum1 = dblNum1 - dblnum2
Case 2
dblNum1 = dblNum1 * dblnum2
Case 3
If dblnum2 <> 0 Then
dblNum1 = dblNum1 / dblnum2
Else
MsgBox "除数不能为“0”！请重新输入除数。", vbOKOnly + vbInformation, "除零错误"
Index = intOperator
End If
Case 6
dblNum1 = dblNum1 * dblnum2 / 100
End Select
End If

'取得当前输入的运算符，以做下次运算
intOperator = Index
strNumber = ""
txtDisplay = CStr(dblNum1)
'判断是否为文本框中的数字加点
If Not txtDisplay Like "*.*" Then
txtDisplay.Text = txtDisplay.Text & "."
End If
End Sub

Private Sub cmdOtherOper_Click(Index As Integer)
Dim dblNum As Double
'求平方根，平方，
dblNum = CDbl(Val(txtDisplay.Text))

Select Case Index
Case 0
'验证数据是否有效
If dblNum >= 0 Then
txtDisplay.Text = CStr(Sqr(dblNum))
Else
MsgBox "负数不能开平方根！", _
vbOKOnly + vbCritical, "开平方根错误"
End If
Case 1
txtDisplay.Text = CStr(dblNum ^ 2)
End Select
'判断是否为文本框中的数字加点
If Not txtDisplay Like "*.*" Then
txtDisplay.Text = txtDisplay.Text & "."
End If
End Sub

Private Sub cmdPoint_Click()
strNumber = strNumber & strPoint
strPoint = ""
End Sub

Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
'使被按下的数字键的对应按钮取得焦点
Select Case KeyCode
Case 48 To 57
cmdNumber(KeyCode - 48).SetFocus
Case 96 To 105
cmdNumber(KeyCode - 96).SetFocus
Case Else
'使按下的符号键对应的按钮取得焦点
If KeyCode = 107 Or (Shift = vbShiftMask And KeyCode = 187) Then
cmdOperator(0).SetFocus
cmdOperator_Click (0)
ElseIf KeyCode = 109 Or KeyCode = 189 Then
cmdOperator(1).SetFocus
cmdOperator_Click (1)
ElseIf KeyCode = 106 Or (Shift = vbShiftMask And KeyCode = 56) Then
cmdOperator(2).SetFocus
cmdOperator_Click (2)
ElseIf KeyCode = 111 Or KeyCode = 191 Then
cmdOperator(3).SetFocus
cmdOperator_Click (3)
ElseIf KeyCode = 13 Then
cmdOperator(7).SetFocus
cmdOperator_Click (7)
ElseIf KeyCode = 8 Then
cmdGT.SetFocus
Call cmdGT_Click
End If
End Select
End Sub
Private Sub Form_KeyPress(KeyAscii As Integer)
'将合法的数据输入到文本框
Select Case KeyAscii
Case 48 To 58
'调用数字键点击处理程序
cmdNumber_Click KeyAscii - 48
KeyAscii = 0
Case 46
'调用小数点输入
cmdPoint_Click
KeyAscii = 0
Case 13
'当敲击回车时，不能触发Form的 KeyUp 事件，因此在这里设置文本框的焦点
txtDisplay.SetFocus
Case Else
KeyAscii = 0
End Select
End Sub

Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
txtDisplay.SetFocus
End Sub

Private Sub Form_Load()
strNumber = ""
strPoint = "."
intOperator = 7
End Sub

Answer 2

组成包括
Label控件
2个，其中一个用来显示数字，一个在那个显示数字的上方空白显示，纯属修饰作用
按钮19个，分别为10个数字0~9，
小数点
，
四则运算
按钮，
正负号
按钮，求倒数按钮，等号按钮，清零按钮，C和CE有啥区别我还真不知道。。所以就写了C了。

Answer 3

不知道你想要哪种，偶是新手，只会最简单的
首先拖出三个text，再拖出4个Command按钮
caption分别为+
-
*
/
这样就准备就绪了
先讲一下简单用法，第一个text是第一个加数/被减数/因数/被除数，而第二个text是第二个加数/减数/因数/除数，第三个text是和/差/积/商，在text1输入一个数，text2输入一个，然后分别点击command“+
-
*
/”text3就会出现结果
然后随便单击一个窗口，把里面的文字删去，再写上：
Private
Sub
Command1_Click()
Text3.Text
=
Str$(Val(Text1.Text)
+
Val(Text2.Text))
End
Sub
Private
Sub
Command2_Click()
Text3.Text
=
Str$(Val(Text1.Text)
-
Val(Text2.Text))
End
Sub
Private
Sub
Command3_Click()
Text3.Text
=
Str$(Val(Text1.Text)
*
Val(Text2.Text))
End
Sub
Private
Sub
Command4_Click()
Text3.Text
=
Str$(Val(Text1.Text)
/
Val(Text2.Text))
End
Sub
然后运行，应该就可以了

Answer 4

打开vb新建一个exe；画上4个按钮控件表示加减乘除，再画上3个文本控件表示两个数与和数，再画一个标签控件加入“=”号。当然，界面可以自己发挥；画好之后，就可以把控件进行命名，注意是属性栏的caption项命名，以便运行的时候方便识别；现在可以进行最重要的代码编写啦。双击对应的按钮控件，进入代码编写界面。text3.text
=
val(text1.text)
+
val(text2.text)，其实代码很简单，就这一句只要更换把‘+’分别换成‘-’‘*’‘/’即可；现在可以点击运行或者f5键运行，即可得到第一个简单的计算器程序。