Question

cmd命令的输出写入到一个ini文件中，怎样换行啊？

我想要写一个bat文件，这个文件中会调用一些cmd命令，然后把这些命令的结果输入到一个ini文件中，结果遇到了一些关于换行的问题，希望高手帮帮忙：

我的bat文件内容是这样的：
echo off

echo [HgVersionInfo]>>versionInfo.ini

echo rev=>>versionInfo.ini
hg parent --template "{rev}">>versionInfo.ini

echo node=>>versionInfo.ini
hg parent --template "{node}">>versionInfo.ini

echo branch=>>versionInfo.ini
hg parent --template "{branch}">>versionInfo.ini

其中 hg parent --template "{xxxx}" 是代码管理软件hg的cmd命令，可以输出获得当前拿到的代码版本号
（不过我的问题主要是换行，这里可以忽略了）

我期望得到的结果是这样的，versionInfo.ini文件的内容会是：
[HgVersionInfo]
rev=3035
node=659772ee3df9fd0368e99
branch=default
结果却是：
[HgVersionInfo]
rev=
3035node=
659772ee3df9fd0368e99branch=
default

所以我该怎样避免echo换行和添加换行呢？

自己只有10分，都贡献出来，希望好心高手帮帮忙。。。

Answer 1

更改如下，希望可以帮助你~~

@echo off
echo [HgVersionInfo]>versionInfo.ini

for /f "delims=" %%i in ('hg parent --template "{rev}"') do (set var=%%i)
echo rev=%var%>>versionInfo.ini

for /f "delims=" %%i in ('hg parent --template "{node}"') do (set var=%%i)
echo node=%var%>>versionInfo.ini

for /f "delims=" %%i in ('hg parent --template "{branch}"') do (set var=%%i)
echo branch=%var%>>versionInfo.ini

 如果再简化一些，可以写成：

@echo off
echo [HgVersionInfo]>versionInfo.ini
for %%a in (rev,node,branch) do (
for /f "delims=" %%i in ('hg parent --template "{%%a}"') do (
echo %%a=%%i%>>versionInfo.ini))

追问

太棒了，完美解决了我的问题，真地非常感谢你！

追答

不用客气！

Answer 2

不换行，加|set /p=
换行，用echo.

举例
echo |set /p= rev=>>versionInfo.ini
hg parent --template "{rev}">>versionInfo.ini
echo. >>versionInfo.ini