Question

你好，我正在做一个ANSYS的压电仿真的瞬态分析，我的问题是怎么在耦合的电极上加载正弦电压载荷？

我的命令流：/filename,fengming
/prep7
et,1,plane42,,,1

et,2,plane13,7,,1
MP,ex,1,9.8e10 !黄铜
MP,nuxy,1,.32
MP,dens,1,7500

mp,dens,2,7750 !PZT材料密度
mp,perx,2,919 !介电常数
mp,pery,2,826
mp,perz,2,919
tb,piez,2 !压电常数
tbdata,2,-5.3512
tbdata,5,15.784
tbdata,8,-5.3512
tbdata,10,12.295
tbdata,15,12.295
tb,anel,2,,,0 !弹性常数
tbdata,1,1.2035e11,7.509e10,7.5179e10
tbdata,7,1.1087e11,7.509e10
tbdata,12,1.2035e11
tbdata,16,2.1053e10
tbdata,19,2.1053e10
tbdata,21,2.2584e10

k,1,0,0 !建模
k,2,1e-2,0
k,3,1.5e-2,0
k,4,1.5e-2,1e-4
k,5,1e-2,1e-4
k,6,1e-2,2e-4
k,7,0,2e-4
k,8,0,1e-4
l,1,2
l,2,3
l,3,4
l,4,5
l,5,6
l,6,7
l,7,8
l,8,5
l,8,1
l,5,2
al,1,10,8,9
al,2,3,4,10
al,5,6,7,8

type,1
mat,1
mshape,0,2D
mshkey,1
amesh,1,2
type,2
mat,2
mshape,0,2D
mshkey,1
amesh,3

nsel,s,loc,x,1.5e-2 !位移约束
d,all,ux,0
d,all,uy,0
/solu !瞬态分析
antype,trans
trnopt,full
tintp,,0.25,0.5,0.5
outpr,all,all
outres,all,all
kbc,1
nsel,s,loc,y,1e-4 !耦合电压
cp,1,volt,all
d,all,volt,0

*do,i,1,50,1
t=i/400000
time,t
nsubst,1
v=40*sin(2*3.14159*42881*t)
nsel,s,loc,y,2e-4
cp,2,volt,all
d,all,volt,v
solve
*enddo
finish
这样加载问题在哪里，对不对？谢谢

Answer 1

我先看看然后晚上回复你！
方法是对这呢，不过在写程序的过程出现了一些小游侍祥失误
你看下我这样改下可以不？与你表达的意思是一致的，只是后面的神搏东西谈胡有些改正，前面的材料以及模型尺寸楼主你就自己拿捏一些精度与单位就可以了

allsel,all
finish
/solu !瞬态分析
antype,trans
trnopt,full
tintp,,0.25,0.5,0.5
outpr,all,all
outres,all,all
kbc,1

nsel,s,loc,y,1e-4 !耦合电压
cp,1,volt,all

nsel,s,loc,y,2e-4
cp,2,volt,all

nsel,s,loc,y,1e-4
d,all,volt,0
allsel,all

*do,i,1,50,1
t=i/400000
time,t
nsubst,1
v=40*sin(2*3.14159*42881*t)

nsel,s,loc,y,2e-4
d,all,volt,v

allsel,all
solve
*enddo

finish