Question

Excel的vba函数，参数是range时，如何获得满足特定条件的值?

假设一个函数名是fun，然后函数有三个参数都是range，
假设参数分别是rga，rgb，rgc，都是range，
然后开始循环，如果rga的第k个值满足一定条件，并且rgb的第k个值满足一定条件，
那么就输出结果为rgc的第k个值，并且中断循环，k从最小0开始循环，
我只知道流程图这么写，但是不知道具体的vba如何操作，
其中rga，rgb，rgc的第k个值都在同一行，
为了简化问题，不如假设第一列的条件是rga中的值大于11，第二列的rgb中的值大于22，
只要满足这个条件，然后就中断循环，然后输出rgc中对应的值，
用vba函数应该如何写？

Answer 1

Function test(Rng1 As Range, Rng2 As Range, Rng3 As Range)
    Dim iR&, ic%, arr, brr, crr
    arr = Rng1
    brr = Rng2
    crr = Rng3
    '--------------------------------------------------
    iR = UBound(arr)
    For i = 1 To iR
        If arr(i, 1) > 11 Then
            If brr(i, 1) > 22 Then
                test = crr(i, 1)
                Exit Function
            End If
        End If
    Next i
End Function

追问

经过我的测试，你的回答是正确的

Answer 2

使用Range.Cells属性，例如：

Function fun(rga as Range, rgb as Range, rgc as Range)
    Dim i
    For i=1 to rga.Cells.Count
        If rga.Cells(i)=rgb.Cells(i) Then '这里的条件需要你自行完善
            fun = rgc.Cells(i)
            Exit Function
        End If
    Next i
End Function