Question

易语言写配置项和读配置项的具体做法是什么？

Answer 1

.版本 2
.子程序 读用户配置
' 配置文件名, "“\USERSYS.ini”", , 用户配置文件
' 系统风格节, "“系统风格”", , 系统配置XP风格
' 风格, "“XP风格”", , 界面使用XP风格样式
' 窗口位置左, "“左边”"
' 窗口位置顶, "“顶边”"
' 窗口宽, "“宽度”"
' 窗口高, "“高度”"
' 用户配色节, "“自定义颜色”", , 用户自定义的配置
' 窗口色项, "“窗口背景”"
' 编辑框底色, "“文字背景”"
' 文字色项, "“文字颜色”"
' 文字大小, "“字号”"
' 文字字体, "“字体”"
' 用户信息节, "“用户信息”", , 用户的信息
' 名项, "“用户名”"
' 址项, "“用户公司”"
' 最近文件节, "“最近打开”", , 使用的文件
' 上次文件, "“上次打开”"
' 自动打开, "“自动打开”"
上次文件.标题 ＝ “”
.如果 (读配置项 (配置路径, #最近文件节, #自动打开, ) ＝ “YES”)
自动打开.选中 ＝ 真
.如果真 (文件是否存在 (读配置项 (配置路径, #最近文件节, #上次文件, )))
上次文件.标题 ＝ 读配置项 (配置路径, #最近文件节, #上次文件, )
上次文件.可视 ＝ 上次文件.标题 ≠ “”
_上次文件_被选择 ()
.如果真结束
.否则
自动打开.选中 ＝ 假
上次文件.可视 ＝ 假
.如果结束
.如果 (读配置项 (配置路径, #系统风格节, #最大化, ) ≠ “YES”)
_启动窗口.移动 (到数值 (读配置项 (配置路径, #系统风格节, #窗口位置左, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口位置顶, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口宽, “400”)), 到数值 (读配置项 (配置路径, #系统风格节, #窗口高, “300”)))
.否则
_启动窗口.位置 ＝ 3
.如果结束
总是最前.选中 ＝ 读配置项 (配置路径, #系统风格节, #总在最前, ) ＝ “1”
_启动窗口.总在最前 ＝ 总是最前.选中
编辑框1.字体.字体大小 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #文字大小, “9”))
编辑框1.字体.字体名称 ＝ 读配置项 (配置路径, #用户配色节, #文字字体, “宋体”)
读配色 ()
读用户 ()
读风格 ()

.版本 2
.子程序 读配色
_启动窗口.底色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #窗口色项, 到文本 (#默认色)))
编辑框1.背景颜色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #编辑框底色, 到文本 (#白色)))
编辑框1.文本颜色 ＝ 到数值 (读配置项 (配置路径, #用户配色节, #文字色项, 到文本 (#黑色)))

.版本 2
.支持库 xplib
.子程序 读风格
.局部变量 KK, 整数型
连续赋值 (假, 无风格.禁止, 蓝色风格.禁止, 绿色风格.禁止, 银色风格.禁止)
KK ＝ 到数值 (读配置项 (配置路径, #系统风格节, #风格, “0”))
XP风格 (KK)
.判断开始 (KK ＝ 0)
无风格.禁止 ＝ 真
.判断 (KK ＝ 1)
蓝色风格.禁止 ＝ 真
.判断 (KK ＝ 2)
绿色风格.禁止 ＝ 真
.判断 (KK ＝ 3)
银色风格.禁止 ＝ 真
.默认
.判断结束

.版本 2
.子程序 读用户
_启动窗口.标题 ＝ 读配置项 (配置路径, #用户信息节, #名项, “大强”) ＋ “记事本”

.版本 2
.子程序 __启动窗口_尺寸被改变
.如果真 (_启动窗口.宽度 ≤ 200)

_启动窗口.宽度 ＝ 200
.如果真结束
.如果真 (_启动窗口.高度 ≤ 300)
_启动窗口.高度 ＝ 300
.如果真结束
.如果真 (_启动窗口.位置 ≠ 3)
写配置项 (配置路径, #系统风格节, #窗口位置左, 到文本 (_启动窗口.左边))
写配置项 (配置路径, #系统风格节, #窗口位置顶, 到文本 (_启动窗口.顶边))
写配置项 (配置路径, #系统风格节, #窗口宽, 到文本 (_启动窗口.宽度))
写配置项 (配置路径, #系统风格节, #窗口高, 到文本 (_启动窗口.高度))
_启动窗口.移动 (到数值 (读配置项 (配置路径, #系统风格节, #窗口位置左, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口位置顶, )), 到数值 (读配置项 (配置路径, #系统风格节, #窗口宽, “400”)), 到数值 (读配置项 (配置路径, #系统风格节, #窗口高, “300”)))
.如果真结束
编辑框1.移动 (5, 5, _启动窗口.取用户区宽度 () － 10, _启动窗口.取用户区高度 () － 10)

这是我的程序中的代码，你也可以到易语言资源网去下载这个程序的源码。

Answer 2

文件名称 update.ini

测试内容

[1]
1-1=V1-1
1-2=V1-2
1-3=V1-3
1-4=V1-4
1-5=V1-5
1-6=V1-6
[2]
2-1=V2-1
2-2=V2-2
2-3=V2-3
2-4=V2-4
2-5=V2-5
2-6=V2-6

测试代码

.版本 2
.支持库 spec

.局部变量 配置文件名, 文本型
.局部变量 节计数器1, 整数型
.局部变量 配置项计数器1, 整数型

配置文件名 ＝ 取运行目录 () ＋ “\server\update.ini”
.变量循环首 (1, 2, 1, 节计数器1)
.变量循环首 (1, 6, 1, 配置项计数器1)
调试输出 (读配置项 (配置文件名, 到文本 (节计数器1), 到文本 (节计数器1) ＋ “-” ＋ 到文本 (配置项计数器1), “”))
.变量循环尾 ()
.变量循环尾 ()

既然能输出来所有的数据，怎么利用这个更新文件其实很简单

1-文件更新肯定要先知道服务器上的配置文件目录和文件，这个直接写在程序路径就OK

2-获取要更新文件的数量，格式嘛，就按照我这里大概的思路了，节名称[1] 代表第一个文件，以此类推

获取1-1 这个可以存储需要更新的列表文件名称  1-2 可以存储 配置项名称 1-3 存储 配置项对应的 val值 

用于本地INI的配置高还原和灵活性

本地的ini被整理出来的格式

文件名称：V1-1 -> update.ini

V1-2 ->[节名称1]

V1-3->配置项名称

V1-4->配置项值

。

。

。

这个方法自己总结的，效果还不错，应对大批量，要使用同一个文件名称不同更新的问题，这个就很好解决的方案