Question

谁能帮我给这个程序加一个延时代码？

@echo off
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.log
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\
rd /s /q %windir%\temp & md %windir%\temp
del /f /q %userprofile%\cookies\
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"
echo 清除系统LJ完成！
echo. & pause

如果可以的话，最好再加一个不能强行关闭的代码，谢谢
我的意思是让该程序连同cmd的对话框同时延时打开，也就是说，当我双击它之后暂时先不启动，等过几分钟之后在自动运行。有没有办法？

Answer 1

1、暂停（Pause）、延迟（Delay）、等待（Wait）、睡眠（Sleep）

1)for+set+if，时间精度为0.01秒，适用平台为WinNT/2K/XP/2003。

利用for解析变量%time%并存为两个时间点%start%和%now%，再利用set /a计算两个时间点的时间差，最后用if判断时间差是否达到设定的暂停时间。
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

@echo off
setlocal enableextensions
echo %time%
call :ProcDelay 200
echo %time%
goto :EOF

:ProcDelay delayMSec_
setlocal enableextensions
for /f "tokens=1-4 delims=:. " %%h in ("%time%") do set start_=%%h%%i%%j%%k
:_procwaitloop
for /f "tokens=1-4 delims=:. " %%h in ("%time%") do set now_=%%h%%i%%j%%k
set /a diff_=%now_%-%start_%
if %diff_% LSS %1 goto _procwaitloop
endlocal & goto :EOF
2)VBS脚本中的sleep函数，时间精度为0.001秒，使用平台为Win9x/WinNT系列。

动态创建一个调用sleep()函数的VBS脚本，然后用Windows脚本宿主的命令行版本cscript调用它。
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

@echo off & setlocal enableextensions enabledelayedexpansion
echo WScript.Sleep 2000 > %temp%\tmp$$$.vbs
echo %time%
cscript //nologo %temp%\tmp$$$.vbs
echo %time%
for %%f in (%temp%\tmp$$$.vbs) do if exist %%f del %%f
endlocal & goto :EOF
3)ping的消息发送间隔，时间精度为1秒，使用平台为Win9x/WinNT系列。

需要你的Windows系统中正常安装了网卡的TCP/IP协议，有两种方案：

(1) 利用ping两次发送消息之间的间隔时间。ping在发送多个消息时，在得到上一次消息的回应后，它会再等待1秒的时间才发送下一次消息，而这个回应时间因机型、系统和网络配置而不同，其中IP地址尤其关键，只有本地的回送地址 127.0.0.1 因为是立即回应所以才是相对恒定的，其他地址大多会产生显著的差异。此种方法要等待更大的时间，是指定发送的消息数为等待的时间加一，因为第一个消息是不等待的，IP 地址必须是 127.0.0.1 。其等待2秒的程序如下：
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

::根据植树原则，n后的数字为暂停秒数加一
ping -n 3 127.0.0.1>nul
(2) 利用ping的最大等待时间。ping向0.0.0.1发送一次“网际消息控制协议 (ICMP)”回响请求消息，因为 0.0.0.1 是个无法响应 ping 请求的IP地址，所以默认情况下，ping会等待一定的最大响应时间——4秒后便停止等待，而-w可以改变这个每发送一次消息所等待的最大响应时间。而如果将 IP 地址改为立即响应的127.0.0.1或其他响应时间很短的IP ，那 -w 便失去了作用，因为每次发送等待时间都不会达到最大的响应时间，此时延时会缩短。此种方法要等待更大的时间，可以直接使用 -w 指定，但是需要减去 500 毫秒（原因尚未知），而且 IP 地址必须是不响应请求的地址。其等待2秒的程序如下：
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

ping -n 2 -w 500 0.0.0.1>nul
4)choice的缺省选择等待功能，时间精度为1秒，适用平台为MS-DOS/Win9x/WinNT系列。

/t:y,2 将缺省选择字符设置为y，等待时间是2秒，/n禁止[y,n]提示出现在命令行上，“rem|”的作用是禁止choice从键盘接受按键，从而暂停不会因为按下y或者其它键而被意外终止。
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

rem|choice /t:y,2 /n >nul
5)ASCII汇编代码，延迟精度为0.001秒，适用平台为MS-DOS/Win9x/WinNT。

德国人Herbert Kleebauer给出了一个通用方案，通过ASCII汇编器间接产生一个sleep.exe程序来实现延迟，这个程序分为DOS和Win两个模块，分别调用DOS系统中断服务和WindowsAPI。
CODE: [Copy to clipboard]
--------------------------------------------------------------------------------

:: Sleep.bat - Sleep/Delay/Wait n seconds
:: Herbert Kleebauer(Germany) - 2005/05/29
:: Modified by Will Sort - 2005/06/02, 07-25
@echo off
echo q | debug>nul
echo Bj@jzh`0X-`/PPPPPPa(DE(DM(DO(Dh(Ls(Lu(LX(LeZRR]EEEUYRX2Dx=>sleep.com
echo 0DxFP,0Xx.t0P,=XtGsB4o@$?PIyU WwX0GwUY Wv;ovBX2Gv0ExGIuht6>>sleep.com
echo T}{z~~@GwkBG@OEKcUt`~}@MqqBsy?seHB~_Phxr?@zAB`LrPEyoDt@Cj?>>sleep.com
echo pky_jN@QEKpEt@ij?jySjN@REKpEt@jj?jyGjN@SEKkjtlGuNw?p@pjirz>>sleep.com
echo LFvAURQ?OYLTQ@@?~QCoOL~RDU@?aU?@{QOq?@}IKuNWpe~FpeQFwH?Vkk>>sleep.com
echo _GSqoCvH{OjeOSeIQRmA@KnEFB?p??mcjNne~B?M??QhetLBgBPHexh@e=>>sleep.com
echo EsOgwTLbLK?sFU`?LDOD@@K@xO?SUudA?_FKJ@N?KD@?UA??O}HCQOQ??R>>sleep.com
echo _OQOL?CLA?CEU?_FU?UAQ?UBD?LOC?ORO?UOL?UOD?OOI?UgL?LOR@YUO?>>sleep.com
echo dsmSQswDOR[BQAQ?LUA?_L_oUNUScLOOuLOODUO?UOE@OwH?UOQ?DJTSDM>>sleep.com
echo QTqrK@kcmSULkPcLOOuLOOFUO?hwDTqOsTdbnTQrrDsdFTlnBTm`lThKcT>>sleep.com
echo @dmTkRQSoddTT~?K?OCOQp?o??Gds?wOw?PGAtaCHQvNntQv_w?A?it\EH>>sleep.com
echo {zpQpKGk?Jbs?FqokOH{T?jPvP@IQBDFAN?OHROL?Kj??pd~aN?OHROd?G>>sleep.com
echo Q??PGT~B??OC~?ipO?T?~U?p~cUo0x>>sleep.com
sleep.com>sleep.exe
echo wait %1 seconds:
sleep.exe %1000
del sleep.com
del sleep.exe

Answer 2

实现延时的话, 如果精度要求不高的话可以用ping命令
如：ping -n 3 127.0.0.1>nul大约可以停顿2秒
-n后的数字是发送包的数目，为暂停秒数加一。此法每秒有0.5%的偏差，时间精度为1秒。

补充: 我能想到的办法只有写程序实现了
用VC++新建一个Windows程序的project, 然后在winmain的实现里:

Sleep(10000); //延时10秒, 你自己可以按要求改的

//执行一个DOS批处理, 第三,第五个参数也要按你的要求改下
ShellExecute(NULL, NULL, "C:\\a.bat", NULL, "C:\\", SW_SHOW);
编译并运行这个程序应该能满足你的要求

Answer 3

恐怕不行吧，DOS程序只要点“关闭”就肯定退出了，不能强行关闭，那不就死机了。

Answer 4

病毒？？？？