Question

批处理怎样批量删除文件名前缀？

删去从起始到一个字符的全部字符

例如

1^文件(1).txt

2^文件(2).txt

……

30^文件(30).txt

修改为

文件(1).txt

文件(2).txt

……

文件(30).txt

Answer 1

@echo off
title Renamer
echo 指定一个分隔符，将文件名中第一次出现该分隔符以后的内容修改为文件名
echo 有重复名字的文件或以分隔符结尾的文件名会导致重命名失败
echo 处理当前目录下文件，暂时不支持空格或0作为分隔符
set /p input=请指定一个分隔符:
if "%input%"=="" (echo 错误：错误的指定分隔符&pause&exit)
for %%n in (^/,^\,^:,^*,^<,^>,^|,0) do (if "%input%"=="%%n" (echo 错误：错误的指定分隔符&pause&exit))
if "%input%"=="*" (echo 错误：错误的指定分隔符&pause&exit)
if "%input%"=="?" (echo 错误：错误的指定分隔符&pause&exit)
if "%input%"==" " (echo 错误：错误的指定分隔符&pause&exit)
echo on
setlocal enabledelayedexpansion
for /f %%Z in ('dir/b') do (
set fon=%%Z
for /f "tokens=1,2* delims=%input%" %%a in ("!fon:%input%=%input%0%input%!") do (
set ffn=%%c
if not "!ffn:%input%0%input%=%input%!"=="%input%0%input%=%input%" ren "%%Z" "!ffn:%input%0%input%=%input%!")
)
@echo off
cls
echo 处理完成
pause

暂时懒得优化了，应该适用于大部分情况

追问

谢谢提供这么多，多给你一些分，这个打开闪退唉，不知道什么情况

追答

啊啊啊对不起，还是我基础太不扎实了，处理^的话还会改第一个文件的名字，因为^是批处理里转义符，而且名字带空格的文件这个也处理不了，连续的几个分隔符也会被全吃掉

不过如果只是要处理你说那几个文件的话可以试试先运行这个

setlocal enabledelayedexpansion
for /f %%Z in ('dir/b') do (
set fon=%%Z
set ffn=!fon:^^=#!
ren "!fon!" "!ffn!"
)

会把目录下文件名里所有"^"改为"#"

===========以上可以全部忽略==========

真的是被我搞复杂化了，这样应该能普适了

@echo off
title Renamer
echo 指定一个分隔符，将文件名中第一次出现该分隔符以后的内容修改为文件名
echo 有重复名字的文件或只有一个分隔符且结尾的文件名会导致重命名失败
echo 处理当前目录下文件（输入多个字符会分别全部指定为分隔符）
echo 作为文件名开头的分隔符会被忽略（即#a#b.txt会被改名为b.txt）
echo 相邻的多个分隔符会被视为一个（即a###b.txt会被改名为b.txt）
set /p input=请指定一个分隔符:
if "%input%"=="" (echo 错误：未指定分隔符&pause&exit)
for %%n in (^/,^\,^:,^*,^<,^>,^|) do (echo %input% | find "%%n" >nul && (echo 错误：错误的指定分隔符"%%n"&pause&exit))
echo %input%|find "?">nul&&(echo 错误：错误的指定分隔符"?"&pause&exit)
echo %input%|find "*">nul&&(echo 错误：错误的指定分隔符"*"&pause&exit)
echo on
for /f "delims=" %%Z in ('dir/b') do (
for /f "tokens=1* delims=%input%" %%a in ("%%Z") do (
ren "%%Z" "%%b"
))
@echo off
cls
echo 处理完成
pause

Answer 2

1、在要修改文件的文件夹内新建一个TXT文本 2、打开这个txt文本，输入下面的文字 ren *_C32kbps.mp3 *.mp3 3、保存，将后缀名改成“bat” 4、双击bat文件。

Answer 3

好压有个批量重命名功能，或者网上下一个批量重命名，很简单改的

Answer 4

恢复出厂设置。所有的垃圾都清掉。

Answer 5

@echo off
set @=q&set/an=0x53b7e0b4
title Any question +%@%%@% %n%
rem 不清楚你的实际文件名，仅以问题中的样例为据
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /a-d/b^|find "^"') do (
    for /f "tokens=1* delims=^" %%i in ("%%a") do (
        echo;"%%a" --^> "%%j"
        ren "%%a" "%%j"
    )
)
echo;Any question +%@%%@% %n%
pause