Question

易语言错误(10044): 不能将“文本型”数据转换到“整数型”数据。

求找错他说下载地址 ＝ 取文本中间 (, “地址：”, “</p>”)不能将“文本型”数据转换到“整数型”数据。
.版本 2
.支持库 downlib
.支持库 internet

.程序集 窗口程序集_窗口_升级
.程序集变量 下载服务器, 文本型
.程序集变量 下载参数, 任务参数
.程序集变量 下载任务, 下载对象
.程序集变量 下载状态, 整数型
.程序集变量 下载信息, 字节集
.程序集变量 文件大小, 双精度小数型

.子程序 _窗口_升级_创建完毕
.局部变量 下载地址, 文本型

下载服务器 ＝ 到文本 (HTTP读文件 (“http:网址))

下载地址 ＝ 取文本中间 (, “地址：”, “</p>”)
下载参数.类型 ＝ #传送常量.下载
下载参数.文件地址 ＝ 下载地址
下载参数.线程等待超时 ＝ 1000
下载参数.默认线程数 ＝ 5
下载参数.本地文件路径 ＝ 取当前目录 () ＋ “\FZZQMD5.exe.tmp”
下载参数.连接超时 ＝ 5000
下载参数.发送超时 ＝ 5000
下载参数.接收超时 ＝ 10000
下载参数.接收大小 ＝ 10240
下载参数.交互回调函数 ＝ &交互回调函数
下载任务.增加新任务 (下载参数)

Answer 1

取文本中间()不能这么用
调用格式： 〈文本型〉 取文本中间 （文本型 欲取其部分的文本，整数型 起始取出位置，整数型 欲取出字符的数目） - 系统核心支持库->文本操作
英文名称：mid
返回一个文本，其中包含指定文本中从指定位置算起指定数量的字符。本命令为初级命令。
参数<1>的名称为“欲取其部分的文本”，类型为“文本型（text）”。
参数<2>的名称为“起始取出位置”，类型为“整数型（int）”。1为首位置，2为第2个位置，如此类推。
参数<3>的名称为“欲取出字符的数目”，类型为“整数型（int）”。

用这个替代

.版本 2
.子程序 文本_取中间, 文本型, 公开, 比如：欲取全文本为“12345”,现在要取出“3”，<3>的前面为“2”，<3>的后面为“4”，
.参数 欲取文本, 文本型, , 比如：欲取全文本为 12345
.参数 前文本, 文本型, , 3的前面为“2”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 后文本, 文本型, , 3的后面为“4”，引号直接用 #引号，如："<font color=#引号red#引号>"
.参数 起始搜寻位置, 整数型, 可空, 可空,这里是指搜寻 参数二 前面文本 的开始位置
.参数 是否不区分大小写, 逻辑型, 可空, 为真不区分大小写，为假区分。
.局部变量 T前面文本位置, 整数型
.局部变量 T_后面文本位置, 整数型
.局部变量 T_前面文本, 文本型
.局部变量 T_后面文本, 文本型
T_前面文本 ＝ 子文本替换 (前文本, “#引号”, #引号, , , 真)
T_后面文本 ＝ 子文本替换 (后文本, “#引号”, #引号, , , 真)
T前面文本位置 ＝ 寻找文本 (欲取文本, T_前面文本, 起始搜寻位置, 是否不区分大小写)
.如果真 (T前面文本位置 ≠ -1)
T前面文本位置 ＝ T前面文本位置 ＋ 取文本长度 (T_前面文本)
.如果真结束
T_后面文本位置 ＝ 寻找文本 (欲取文本, T_后面文本, T前面文本位置, 是否不区分大小写)
.如果真 (T前面文本位置 ＝ -1 或 T_后面文本位置 ＝ -1)
返回 (“”)
.如果真结束
返回 (取文本中间 (欲取文本, T前面文本位置, T_后面文本位置 － T前面文本位置))

Answer 2

取文本中间 这个命令使用错误，第二个参数不能是“地址”文本型的，必须是整数型，是数字

Answer 3

电脑要求的是整数，你输入的是文本，怎么能不出错