Question

flash 中如何用AS把库中的影片剪辑或者按钮放到舞台

能不能用for循环放10个，每个影片剪辑在创建时都赋予不同的实例名，以及放置在不同位置上

Answer 1

我用flash8制作了一个例子，供参考

制作方法是：

制作影片剪辑，库面板内右键点击选择连接，然后选中为AS导出 设置标识符为 star

代码如下：

for(i=1;i<=10;i++){

attachMovie("star","star"+i,i)

this["star"+i]._x=50+30*i

this["star"+i]._y=50+5*i

}

Answer 2

比较简单，你能不能详细描述一下，最好截图看看

追问

就是我用for循环放置十个影片剪辑或者按钮到舞台上
它们在舞台的位置不同就是XY坐标不同，而且要有对应的实例名供以后调用
已经说得很清楚啊

追答

好吧，如果你要放10个相同的mc进入场景

我用cc版本做了一个简单的演示

注意AS链接处，我写的是McBtn

然后在第一帧加入代码如下代码：

import flash.display.Sprite;
import flash.events.MouseEvent;

var btnBoard:Sprite = new Sprite();//放置按钮的容器

addChild(btnBoard);//容器放入舞台

for(var i:int = 0 ; i < 10 ; i ++)
{
var btn:McBtn = new McBtn();
btnBoard.addChild(btn);//生成库中的剪辑，并放入容器
btn.name = "btn" + i.toString();//给它命名（依靠这个可以在以后找到它）
btn.x = 70 * (i % 5) + 20;
btn.y = 40 * int(i / 5) + 20;//放置位置
}

//给第三个剪辑加一个点击侦听，如果它播放，就让它停下来看，反之继续播放
btnBoard.getChildByName("btn2").addEventListener(MouseEvent.CLICK, clickHandler);

function clickHandler(evt:MouseEvent):void
{
if(evt.target.isPlaying)
{
evt.target.stop();
}
else
{
evt.target.play();
}
}

追问

加点击侦听有啥用，还有以后调用怎么调用啊，比如我要修改第一个创建出来的XY坐标，而且你的代码好像在外部类不能用哈。

追答

加点击侦听有啥用？？？以后怎么调用？

我加点击侦听是让你知道，当我想调用第三个按钮的时候可以用代码

btnBoard.getChildByName("btn2")找到它！

例如你要改变第一个的位置，直接就

btnBoard.getChildByName("btn0").x = xxx;

btnBoard.getChildByName("btn0").y = xxx;

按照我上面的图做一个库中的元件，AS链接为McBtn

文档类如下：

package  
{
import flash.display.Sprite;
import flash.events.MouseEvent;

public class Main extends Sprite
{
public function Main() 
{
var btnBoard:Sprite = new Sprite();//放置按钮的容器
 
addChild(btnBoard);//容器放入舞台
 
for(var i:int = 0 ; i < 10 ; i ++)
{
var btn:McBtn = new McBtn();
btnBoard.addChild(btn);//生成库中的剪辑，并放入容器
btn.name = "btn" + i.toString();//给它命名（依靠这个可以在以后找到它）
btn.x = 70 * (i % 5) + 20;
btn.y = 40 * int(i / 5) + 20;//放置位置
}
 
//给第三个剪辑加一个点击侦听，如果它播放，就让它停下来看，反之继续播放
btnBoard.getChildByName("btn2").addEventListener(MouseEvent.CLICK, clickHandler);
}
private function clickHandler(evt:MouseEvent):void
{
if(evt.target.isPlaying)
{
evt.target.stop();
}
else
{
evt.target.play();
}
}
}
}

 不知道百度知道怎么搞的，我的附件始终上传不了，。。。